locals {
  update_playlist_digest_secrets = [
    "DSPAPI_APPKEY",
    "MYSQL_PASSWORD",
    "SENTRY_DSN",
  ]

  update_playlist_digest_common_secrets = {
    DD_API_KEY = aws_secretsmanager_secret.common_secret["DD_API_KEY"]
  }

  update_playlist_digest_secrets_json = jsonencode(
    [
      for k, v in merge(aws_secretsmanager_secret.update_playlist_digest_secret, local.update_playlist_digest_common_secrets) :
      {
        name      = k,
        valueFrom = "arn:aws:secretsmanager:${var.aws_region_id}:${local.account_id}:secret:${v["name"]}"
      }
    ]
  )
}

resource "aws_secretsmanager_secret" "update_playlist_digest_secret" {
  for_each = toset(local.update_playlist_digest_secrets)

  name       = "${local.secrets_name_prefix}/update_playlist_digest/${each.value}"
  kms_key_id = data.aws_kms_key.secrets_general_key.id

  tags = merge(
    local.common_tags,
    {
      project                  = "Infrastructure",
      service                  = "Secrets Manager",
      plat_env_project_service = "${local.aggregated_tag}_INFRA_SCRT"
    }
  )
}

data "aws_iam_role" "update_playlist_digest_role" {
  name = "${local.name_prefix}-update_playlist_digest_role"
}

data "aws_ecr_repository" "update_playlist_digest_ecr" {
  name = "apollo/update_playlist_digest"

  provider = aws.gdb-apollo-dev
}

module "update_playlist_digest" {
  source = "../../../modules/ecs/tasks/scheduled_task"

  env_prefix         = local.env_prefix
  project_group      = local.project_group
  project            = "update_playlist_digest"
  region             = var.aws_region_id
  cluster_arn        = data.aws_ecs_cluster.main.arn
  security_groups    = [data.aws_security_group.main.id]
  task_exec_role_arn = data.aws_iam_role.standard_exec.arn
  task_role_arn      = data.aws_iam_role.update_playlist_digest_role.arn
  scheduler_role_arn = module.ecs_scheduler_role.role.arn
  subnets            = data.aws_subnets.private_subnets.ids
  secrets            = local.update_playlist_digest_secrets_json
  image              = "${data.aws_ecr_repository.update_playlist_digest_ecr.repository_url}:${local.docker_image_env_tag[var.platform.prefix]}"
  schedule           = "rate(8 hours)"
  schedule_enabled   = false
  cpu                = 1024
  memory             = 2048

  env_vars = [
    {
      name  = "ENVIRONMENT",
      value = local.environment
    },
    {
      name  = "MYSQL_DATABASE",
      value = "dbSony_dbo"
    },
    {
      name  = "MYSQL_HOST",
      value = module.domains[local.env_prefix]["main-db-rw"]
    },
    {
      name  = "REDIS_HOST",
      value = data.aws_elasticache_cluster.main.cache_nodes.0.address
    },
    {
      name  = "S3_BUCKET",
      value = "${local.name_prefix}-update-playlist-digest"
    },
    {
      name  = "ATHENA_DATABASE",
      value = "${local.env_prefix}_apollo_update_playlist_digest"
    },
    {
      name  = "MYSQL_USER",
      value = "apollo_utph_usr"
    },
    {
      name  = "ECS_CLUSTER",
      value = data.aws_ecs_cluster.main.cluster_name
    },
    {
      name  = "PROJECT",
      value = local.project_group
    },
    {
      name  = "ECS_SERVICE",
      value = "update_playlist_digest"
    },
    {
      name  = "DSPAPI_HOSTNAME",
      value = module.domains[local.env_prefix]["dsp-api"]
    },
  ]

  common_tags = merge(
    local.common_tags,
    {
      project                  = "Portal",
      service                  = "ECS",
      plat_env_project_service = "${local.aggregated_tag}_PRL_ECS"
    }
  )
}