locals {
  ingress-alb = [
    { from_port = 80, to_port = 80, source_sg_id = module.sg-alb.sg_id, description = "Allow inbound http from ALBs" },
    { from_port = 80, to_port = 80, source_sg_id = module.sg-win-ws.sg_id, description = "Allow inbound http from windows EC2" },
    { from_port = 80, to_port = 80, source_sg_id = module.sg-lin-ws.sg_id, description = "Allow inbound http from linux EC2" },
    { from_port = 80, to_port = 80, source_sg_id = module.sg-ecs.sg_id, description = "Allow inbound http from ECS containers" },
    { from_port = 443, to_port = 443, source_sg_id = module.sg-alb.sg_id, description = "Allow inbound https from ALBs" },
    { from_port = 443, to_port = 443, source_sg_id = module.sg-win-ws.sg_id, description = "Allow inbound https from windows EC2" },
    { from_port = 443, to_port = 443, source_sg_id = module.sg-lin-ws.sg_id, description = "Allow inbound https from linux EC2" },
    { from_port = 443, to_port = 443, source_sg_id = module.sg-ecs.sg_id, description = "Allow inbound https from ECS containers" },
    { from_port = 443, to_port = 443, source_sg_id = module.sg-lambda.sg_id, description = "Allow inboount https from Lambda" },
  ]
  ingress-docdb = [
    { from_port = 27017, to_port = 27019, source_sg_id = module.sg-docdb.sg_id, description = "Allow DocDB" },
    { from_port = 27017, to_port = 27019, source_sg_id = module.sg-ecs.sg_id, description = "Allow inbound connections from ECS" },
  ]
  ingress-win-ws = [
    { from_port = 80, to_port = 80, source_sg_id = module.sg-alb.sg_id, description = "Allow inbound http from ALBs" },
    { from_port = 80, to_port = 80, source_sg_id = module.sg-win-ws.sg_id, description = "Allow inbound http from windows EC2" }
  ]
  ingress-lin-ws = [
    { from_port = 80, to_port = 80, source_sg_id = module.sg-alb.sg_id, description = "Allow inbound http from ALBs" },
    { from_port = 80, to_port = 80, source_sg_id = module.sg-lin-ws.sg_id, description = "Allow inbound http from linux EC2" }
  ]
  ingress-ecs = [
    { from_port = 8080, to_port = 8080, source_sg_id = module.sg-alb.sg_id, description = "Allow inbound http from ALBs" },
    { from_port = 8080, to_port = 8080, source_sg_id = module.sg-ecs.sg_id, description = "Allow inbound http from ECS" },
    { from_port = 8000, to_port = 8000, source_sg_id = module.sg-alb.sg_id, description = "Allow inbound http from ALBs" },
    { from_port = 8000, to_port = 8000, source_sg_id = module.sg-ecs.sg_id, description = "Allow inbound http from ECS" }
  ]
  ingress-aurora = [
    { from_port = 3306, to_port = 3306, source_sg_id = module.sg-win-ws.sg_id, description = "Allow inbound connections from windows EC2 web-servers" },
    { from_port = 3306, to_port = 3306, source_sg_id = module.sg-lin-ws.sg_id, description = "Allow inbound connections from linux EC2 web-servers" },
    { from_port = 3306, to_port = 3306, source_sg_id = module.sg-ecs.sg_id, description = "Allow inbound connections from ECS" },
    { from_port = 3306, to_port = 3306, source_sg_id = module.sg-win-batch.sg_id, description = "Allow inbound connections from windows EC2 utility" },
    { from_port = 3306, to_port = 3306, source_sg_id = module.sg-lin-batch.sg_id, description = "Allow inbound connections from linux EC2 utility" },
    { from_port = 3306, to_port = 3306, source_sg_id = module.sg-aws-batch.sg_id, description = "Allow inbound connections from AWS Batch" },
    { from_port = 3306, to_port = 3306, source_sg_id = module.sg-lambda.sg_id, description = "Allow inbound connections from AWS Lambda" }
  ]
  ingress-win-batch = []
  ingress-lin-batch = []
  ingress-aws-batch = []
  ingress-redis = [
    { from_port = 6379, to_port = 6379, source_sg_id = module.sg-win-ws.sg_id, description = "Allow inbound connections from windows EC2 web-servers" },
    { from_port = 6379, to_port = 6379, source_sg_id = module.sg-lin-ws.sg_id, description = "Allow inbound connections from linux EC2 web-servers" },
    { from_port = 6379, to_port = 6379, source_sg_id = module.sg-win-batch.sg_id, description = "Allow inbound connections from windows EC2 utility" },
    { from_port = 6379, to_port = 6379, source_sg_id = module.sg-ecs.sg_id, description = "Allow inbound connections from ECS" },
    { from_port = 6379, to_port = 6379, source_sg_id = module.sg-lambda.sg_id, description = "Allow inbound connections from Lambda" },
  ]
  ingress-couchbase = [
    { from_port = 4369, to_port = 4369, source_sg_id = module.sg-couchbase.sg_id, description = "Allow inbound unencrypted node-to-node connections (erlang port mapper)." },
    { from_port = 9100, to_port = 9105, source_sg_id = module.sg-couchbase.sg_id, description = "Allow inbound unencrypted node-to-node connections (indexer)." },
    { from_port = 9110, to_port = 9118, source_sg_id = module.sg-couchbase.sg_id, description = "Allow inbound unencrypted node-to-node connections (Analytics)." },
    { from_port = 9120, to_port = 9122, source_sg_id = module.sg-couchbase.sg_id, description = "Allow inbound unencrypted node-to-node connections (Analytics)." },
    { from_port = 9130, to_port = 9130, source_sg_id = module.sg-couchbase.sg_id, description = "Allow inbound unencrypted node-to-node connections (gprc)." },
    { from_port = 9999, to_port = 9999, source_sg_id = module.sg-couchbase.sg_id, description = "Allow inbound unencrypted node-to-node connections (indexer)." },
    { from_port = 11209, to_port = 11210, source_sg_id = module.sg-couchbase.sg_id, description = "Allow inbound unencrypted node-to-node connections (memcached)." },
    { from_port = 21100, to_port = 21299, source_sg_id = module.sg-couchbase.sg_id, description = "Allow inbound encrypted node-to-node connections (memcached)." },
    { from_port = 8091, to_port = 8096, source_sg_id = module.sg-couchbase.sg_id, description = "Allow inbound unencrypted client connections to Couchbase." },
    { from_port = 8091, to_port = 8096, source_sg_id = module.sg-win-ws.sg_id, description = "Allow inbound unencrypted client connections to Couchbase." },
    { from_port = 18091, to_port = 18096, source_sg_id = module.sg-win-ws.sg_id, description = "Allow inbound encrypted client connections to Couchbase." },
    { from_port = 11210, to_port = 11211, source_sg_id = module.sg-win-ws.sg_id, description = "Allow inbound unencrypted client connections to Couchbase (memcached)." },
    { from_port = 11207, to_port = 11207, source_sg_id = module.sg-win-ws.sg_id, description = "Allow inbound encrypted client connections to Couchbase (memcached)." },
    { from_port = 8091, to_port = 8096, source_sg_id = module.sg-win-batch.sg_id, description = "Allow inbound unencrypted client connection to Couchbase." },
    { from_port = 18091, to_port = 18096, source_sg_id = module.sg-win-batch.sg_id, description = "Allow inbound unencrypted client connection to Couchbase." },
    { from_port = 11210, to_port = 11211, source_sg_id = module.sg-win-batch.sg_id, description = "Allow inbound unencrypted client connections to Couchbase (memcached)." },
    { from_port = 11207, to_port = 11207, source_sg_id = module.sg-win-batch.sg_id, description = "Allow inbound encrypted client connections to Couchbase (memcached)." },
  ]
  ingress-lambda = []

  whitelisted_cidrs = concat(module.ip_whitelist.whitelist_for_sg, var.projectgroup_whitelist)
  # If vpn_enabled, management and debug SG will give access to vpn cidrs instead of office IP whitelist
  vpn_cidrs = [for cidr in var.vpn_masq_cidrs : { cidr = cidr, description = "Access for VPN users" }]
  env_access_list = var.external_access_mode == "whitelist" ? local.whitelisted_cidrs : (
    var.external_access_mode == "vpn" ? local.vpn_cidrs : concat(local.vpn_cidrs, local.whitelisted_cidrs)
  )
  whitelisted_ip_sets = [for item in concat(local.env_access_list, var.external_https_access) : {
    type  = "IPV4"
    value = item["cidr"]
  }]
}

module "ip_whitelist" {
  source = "../../modules/ip_whitelist_v2"
}


# Create security group for windows web servers
module "sg-win-ws" {
  source = "../../modules/vpc/sg"

  sg_description   = "Allows HTTP connections to windows web servers"
  vpc_id           = var.vpc_id
  protocol         = "tcp"
  ingress_template = local.ingress-win-ws

  tags = merge(
    var.common_tags,
    {
      "Name" = format("%v-sg-win-ws", var.name_prefix)
    },
  )
}

# Create security group for load balancers
module "sg-alb" {
  source = "../../modules/vpc/sg"

  sg_description   = "Allows HTTP connections to ALB"
  vpc_id           = var.vpc_id
  protocol         = "tcp"
  ingress_template = local.ingress-alb

  tags = merge(
    var.common_tags,
    {
      "Name" = format("%v-sg-alb", var.name_prefix)
    },
  )
}

# Create security group for linux web servers
module "sg-docdb" {
  source = "../../modules/vpc/sg"

  sg_description   = "Allows DockDB connections"
  vpc_id           = var.vpc_id
  protocol         = "tcp"
  ingress_template = local.ingress-docdb

  tags = merge(
    var.common_tags,
    {
      "Name" = format("%v-sg-docdb", var.name_prefix)
    },
  )
}

# Create security group for linux web servers
module "sg-lin-ws" {
  source = "../../modules/vpc/sg"

  sg_description   = "Allows HTTP connections to linux web servers"
  vpc_id           = var.vpc_id
  protocol         = "tcp"
  ingress_template = local.ingress-lin-ws

  tags = merge(
    var.common_tags,
    {
      "Name" = format("%v-sg-lin-ws", var.name_prefix)
    },
  )
}

# Create security group for containers in ECS
module "sg-ecs" {
  source = "../../modules/vpc/sg"

  sg_description   = "Allows HTTP connections to ECS"
  vpc_id           = var.vpc_id
  protocol         = "tcp"
  ingress_template = local.ingress-ecs

  tags = merge(
    var.common_tags,
    {
      "Name" = format("%v-sg-ecs", var.name_prefix)
    },
  )
}

# Create security group for db access
module "sg-aurora" {
  source = "../../modules/vpc/sg"

  sg_description   = "Allows connections to Aurora db"
  vpc_id           = var.vpc_id
  protocol         = "tcp"
  ingress_template = local.ingress-aurora

  tags = merge(
    var.common_tags,
    {
      "Name" = format("%v-sg-aurora", var.name_prefix)
    },
  )
}

# Create security group for access to windows EC2 instances with batch jobs
module "sg-win-batch" {
  source = "../../modules/vpc/sg"

  sg_description   = "Allows connections to windows utility servers"
  vpc_id           = var.vpc_id
  protocol         = "tcp"
  ingress_template = local.ingress-win-batch

  tags = merge(
    var.common_tags,
    {
      "Name" = format("%v-sg-win-batch", var.name_prefix)
    },
  )
}

# Create security group for access to linux EC2 instances with batch jobs
module "sg-lin-batch" {
  source = "../../modules/vpc/sg"

  sg_description   = "Allows connections to linux utility servers"
  vpc_id           = var.vpc_id
  protocol         = "tcp"
  ingress_template = local.ingress-lin-batch

  tags = merge(
    var.common_tags,
    {
      "Name" = format("%v-sg-lin-batch", var.name_prefix)
    },
  )
}

# Create security group for access to AWS Batch compute resources with batch jobs
module "sg-aws-batch" {
  source = "../../modules/vpc/sg"

  sg_description   = "Allows connections to AWS Batch compute environment"
  vpc_id           = var.vpc_id
  protocol         = "tcp"
  ingress_template = local.ingress-aws-batch

  tags = merge(
    var.common_tags,
    {
      "Name" = format("%v-sg-aws-batch", var.name_prefix)
    },
  )
}

module "sg-redis" {
  source = "../../modules/vpc/sg"

  sg_description   = "Allows access to redis"
  vpc_id           = var.vpc_id
  protocol         = "tcp"
  ingress_template = local.ingress-redis

  tags = merge(
    var.common_tags,
    {
      "Name" = format("%v-sg-redis", var.name_prefix)
    },
  )
}

module "sg-couchbase" {
  source = "../../modules/vpc/sg"

  sg_description   = "Allows access to couchbase"
  vpc_id           = var.vpc_id
  protocol         = "tcp"
  ingress_template = local.ingress-couchbase

  tags = merge(
    var.common_tags,
    {
      "Name" = format("%v-sg-couchbase", var.name_prefix)
    },
  )
}

module "sg-lambda" {
  source = "../../modules/vpc/sg"

  sg_description   = "Allow AWS Lambda outgoing connections"
  vpc_id           = var.vpc_id
  protocol         = "tcp"
  ingress_template = local.ingress-lambda

  tags = merge(
    var.common_tags,
    {
      "Name" = format("%v-sg-lambda", var.name_prefix)
    },
  )
}

resource "aws_security_group" "remote_management_access_ssh" {
  description = "Allow connections via SSH from specified addresses"
  vpc_id      = var.vpc_id
  # SSH
  dynamic "ingress" {
    for_each = local.env_access_list
    content {
      description = ingress.value["description"]
      from_port   = 22
      to_port     = 22
      protocol    = "tcp"
      cidr_blocks = [ingress.value["cidr"]]
    }
  }

  ingress {
    description     = "Access from transit gateway"
    from_port       = 22
    to_port         = 22
    protocol        = "tcp"
    prefix_list_ids = var.managed_prefix_list_ids
  }

  egress {
    description = "Allow all outbound traffic."
    from_port   = 0
    to_port     = 0
    protocol    = "-1"
    cidr_blocks = ["0.0.0.0/0"]
  }

  tags = merge(
    var.common_tags,
    {
      "Name"           = format("%v-sg-remote-access", var.name_prefix),
      "eiso-exception" = "aws.08.30",
    },
  )
}
/*
resource "aws_security_group" "db_debug_access" {
  # Keeping this for back work compatibility
  description = "Allow connections custom db ports from specified addresses"
  vpc_id      = var.vpc_id
  tags = merge(
    var.common_tags,
    {
      "Name" = format("%v-sg-db-debug", var.name_prefix)
    },
  )
}
*/
resource "aws_security_group" "remote_management_access_rdp" {
  description = "Allow connections via RDP from specified addresses"
  vpc_id      = var.vpc_id
  # RDP
  dynamic "ingress" {
    for_each = local.env_access_list
    content {
      description = ingress.value["description"]
      from_port   = 3389
      to_port     = 3389
      protocol    = "tcp"
      cidr_blocks = [ingress.value["cidr"]]
    }
  }

  ingress {
    description     = "Access from transit gateway"
    from_port       = 3389
    to_port         = 3389
    protocol        = "tcp"
    prefix_list_ids = var.managed_prefix_list_ids
  }

  egress {
    description = "Allow all outbound traffic."
    from_port   = 0
    to_port     = 0
    protocol    = "-1"
    cidr_blocks = ["0.0.0.0/0"]
  }

  tags = merge(
    var.common_tags,
    {
      "Name"           = format("%v-sg-remote-access", var.name_prefix),
      "eiso-exception" = "aws.08.30",
    },
  )
}

resource "aws_security_group" "web_debug_access_443" {
  description = "Allow connections custom web ports from specified addresses"
  vpc_id      = var.vpc_id

  # https 443
  dynamic "ingress" {
    for_each = local.env_access_list

    content {
      description = ingress.value["description"]
      from_port   = 443
      to_port     = 443
      protocol    = "tcp"
      cidr_blocks = [ingress.value["cidr"]]
    }
  }

  ingress {
    description     = "Access from transit gateway"
    from_port       = 443
    to_port         = 443
    protocol        = "tcp"
    prefix_list_ids = var.managed_prefix_list_ids
  }

  egress {
    description = "Allow all outbound traffic."
    from_port   = 0
    to_port     = 0
    protocol    = "-1"
    cidr_blocks = ["0.0.0.0/0"]
  }

  tags = merge(
    var.common_tags,
    {
      "Name"           = format("%v-sg-web-debug-443", var.name_prefix),
      "eiso-exception" = "aws.08.30",
    },
  )
}

resource "aws_security_group" "web_debug_access_80" {
  description = "Allow connections custom web ports from specified addresses"
  vpc_id      = var.vpc_id

  # http 80
  dynamic "ingress" {
    for_each = local.env_access_list

    content {
      description = ingress.value["description"]
      from_port   = 80
      to_port     = 80
      protocol    = "tcp"
      cidr_blocks = [ingress.value["cidr"]]
    }
  }

  ingress {
    description     = "Access from transit gateway"
    from_port       = 80
    to_port         = 80
    protocol        = "tcp"
    prefix_list_ids = var.managed_prefix_list_ids
  }

  egress {
    description = "Allow all outbound traffic."
    from_port   = 0
    to_port     = 0
    protocol    = "-1"
    cidr_blocks = ["0.0.0.0/0"]
  }

  tags = merge(
    var.common_tags,
    {
      "Name"           = format("%v-sg-web-debug-80", var.name_prefix),
      "eiso-exception" = "aws.08.30",
    },
  )
}

resource "aws_security_group" "db_debug_access_msql" {
  description = "Allow connections custom db ports from specified addresses"
  vpc_id      = var.vpc_id
  # DB
  dynamic "ingress" {
    for_each = concat(var.external_mysql_access, local.env_access_list)
    content {
      description = ingress.value["description"]
      from_port   = 3306
      to_port     = 3306
      protocol    = "tcp"
      cidr_blocks = [ingress.value["cidr"]]
    }
  }

  ingress {
    description     = "Access from transit gateway"
    from_port       = 3306
    to_port         = 3306
    protocol        = "tcp"
    prefix_list_ids = var.managed_prefix_list_ids
  }

  egress {
    description = "Allow all outbound traffic."
    from_port   = 0
    to_port     = 0
    protocol    = "-1"
    cidr_blocks = ["0.0.0.0/0"]
  }
  tags = merge(
    var.common_tags,
    {
      "Name"           = format("%v-sg-msql-debug", var.name_prefix),
      "eiso-exception" = "aws.08.30",
    },
  )
}

resource "aws_security_group" "db_debug_access_mongo" {
  description = "Allow connections custom mongo db ports from specified addresses"
  vpc_id      = var.vpc_id
  # DB
  dynamic "ingress" {
    for_each = concat(var.external_mysql_access, local.env_access_list)
    content {
      description = ingress.value["description"]
      from_port   = 27017
      to_port     = 27019
      protocol    = "tcp"
      cidr_blocks = [ingress.value["cidr"]]
    }
  }

  ingress {
    description     = "Access from transit gateway"
    from_port       = 27017
    to_port         = 27017
    protocol        = "tcp"
    prefix_list_ids = var.managed_prefix_list_ids
  }

  egress {
    description = "Allow all outbound traffic."
    from_port   = 0
    to_port     = 0
    protocol    = "-1"
    cidr_blocks = ["0.0.0.0/0"]
  }
  tags = merge(
    var.common_tags,
    {
      "Name"           = format("%v-sg-mongo-debug", var.name_prefix),
      "eiso-exception" = "aws.08.30",
    },
  )
}

resource "aws_security_group" "db_debug_access_lvldb" {
  description = "Allow connections custom db ports from specified addresses"
  vpc_id      = var.vpc_id
  # leveldb
  dynamic "ingress" {
    for_each = local.env_access_list
    content {
      description = ingress.value["description"]
      from_port   = 50000
      to_port     = 50020
      protocol    = "tcp"
      cidr_blocks = [ingress.value["cidr"]]
    }
  }

  ingress {
    description     = "Access from transit gateway"
    from_port       = 50000
    to_port         = 50020
    protocol        = "tcp"
    prefix_list_ids = var.managed_prefix_list_ids
  }

  egress {
    description = "Allow all outbound traffic."
    from_port   = 0
    to_port     = 0
    protocol    = "-1"
    cidr_blocks = ["0.0.0.0/0"]
  }

  tags = merge(
    var.common_tags,
    {
      "Name"           = format("%v-sg-lvldb-debug", var.name_prefix),
      "eiso-exception" = "aws.08.30"
    },
  )
}

resource "aws_security_group" "manual_debug_access" {
  description = "Allow connections for debug purposes"
  vpc_id      = var.vpc_id

  egress {
    description = "Allow all outbound traffic."
    from_port   = 0
    to_port     = 0
    protocol    = "-1"
    cidr_blocks = ["0.0.0.0/0"]
  }

  tags = merge(
    var.common_tags,
    {
      "Name"           = format("%v-sg-manual-debug", var.name_prefix),
      "eiso-exception" = "aws.08.30",
    },
  )
}

module "auth0_ip_addresses" {
  source = "../../modules/auth0_ip_addresses"
}

resource "aws_security_group" "auth0" {
  description = "Allow connections from Auth0"
  vpc_id      = var.vpc_id

  # https
  dynamic "ingress" {
    for_each = module.auth0_ip_addresses.auth0_ip_addr
    content {
      description = ingress.value["description"]
      from_port   = 443
      to_port     = 443
      protocol    = "tcp"
      cidr_blocks = [ingress.value["cidr"]]
    }
  }

  egress {
    description = "Allow all outbound traffic."
    from_port   = 0
    to_port     = 0
    protocol    = "-1"
    cidr_blocks = ["0.0.0.0/0"]
  }

  tags = merge(
    var.common_tags,
    {
      "Name"           = format("%v-sg-auth0", var.name_prefix),
      "eiso-exception" = "aws.08.30",
    },
  )
}

resource "aws_security_group" "ext_web_sg" {
  description = "HTTPS access for list of external ip addresses"
  vpc_id      = var.vpc_id

  # https 443
  dynamic "ingress" {
    # In case VPN is enabled, add whitelisted IP addresses to the SG
    for_each = var.external_access_mode == "vpn" ? concat(var.external_https_access, local.whitelisted_cidrs) : var.external_https_access
    content {
      description = ingress.value["description"]
      from_port   = 443
      to_port     = 443
      protocol    = "tcp"
      cidr_blocks = [ingress.value["cidr"]]
    }
  }

  tags = merge(
    var.common_tags,
    {
      Name             = "${var.name_prefix}-sg-external-web",
      "eiso-exception" = "aws.08.30",
    },
  )
}

resource "aws_security_group" "public_access_sg" {
  description = "HTTP(s) public access"
  vpc_id      = var.vpc_id

  ingress {
    description = "Allow port 80 inbound traffic."
    from_port   = 80
    protocol    = "tcp"
    to_port     = 80
    cidr_blocks = ["0.0.0.0/0"]
  }

  ingress {
    description = "Allow port 80 inbound traffic."
    from_port   = 443
    protocol    = "tcp"
    to_port     = 443
    cidr_blocks = ["0.0.0.0/0"]
  }

  egress {
    description = "Allow all outbound traffic."
    from_port   = 0
    to_port     = 0
    protocol    = "-1"
    cidr_blocks = ["0.0.0.0/0"]
  }

  tags = merge(
    var.common_tags,
    {
      Name             = format("%v-sg-alb-public", var.name_prefix),
      "eiso-exception" = "aws.08.30",
    }
  )
}

resource "aws_security_group" "redis_debug_access" {
  description = "Allow connections to Redis from specified addresses"
  vpc_id      = var.vpc_id

  dynamic "ingress" {
    for_each = local.env_access_list
    content {
      description = ingress.value["description"]
      from_port   = 6379
      to_port     = 6379
      protocol    = "tcp"
      cidr_blocks = [ingress.value["cidr"]]
    }
  }

  ingress {
    description     = "Access from transit gateway"
    from_port       = 6379
    to_port         = 6379
    protocol        = "tcp"
    prefix_list_ids = var.managed_prefix_list_ids
  }

  egress {
    description = "Allow all outbound traffic."
    from_port   = 0
    to_port     = 0
    protocol    = "-1"
    cidr_blocks = ["0.0.0.0/0"]
  }

  tags = merge(
    var.common_tags,
    {
      "Name"           = format("%v-sg-remote-redis-access", var.name_prefix),
      "eiso-exception" = "aws.08.30",
    },
  )
}