# VPC part
module "main_vpc" {
  source = "../../../modules/vpc/vpc_v2"

  name_prefix       = local.name_prefix
  cidr_second_octet = var.vpc["cidr_second_octet"]

  flow_logs = {
    gsirt = {
      log_destination      = "${data.aws_s3_bucket.security_logs.arn}/vpcflow/"
      log_destination_type = "s3"
      traffic_type         = "REJECT"
    }
  }

  common_tags = merge(
    local.common_tags,
    {
      project                  = "Infrastructure",
      service                  = "Networking",
      plat_env_project_service = "${local.aggregated_tag}_INFRA_NTW"
    }
  )
}

module "main_public_subnets" {
  source = "../../../modules/vpc/subnet"

  name_prefix        = local.name_prefix
  subnets            = var.public_subnets
  vpc_id             = module.main_vpc.vpc_id
  is_public          = true
  cidr_second_octet  = var.vpc["cidr_second_octet"]
  availability_zones = local.availability_zones
  common_tags = merge(
    local.common_tags,
    {
      project                  = "Infrastructure",
      service                  = "Networking",
      plat_env_project_service = "${local.aggregated_tag}_INFRA_NTW"
    }
  )
}

module "main_public_routing" {
  source      = "../../../modules/vpc/routes"
  is_public   = true
  name_prefix = local.name_prefix
  vpc_id      = module.main_vpc.vpc_id
  vpc_cidr    = module.main_vpc.vpc_cidr
  igw_id      = module.main_vpc.vpc_igw
  subnets     = module.main_public_subnets.subnet_ids
  common_tags = merge(
    local.common_tags,
    {
      project                  = "Infrastructure",
      service                  = "Networking",
      plat_env_project_service = "${local.aggregated_tag}_INFRA_NTW"
    }
  )
}

module "main_private_subnets" {
  source             = "../../../modules/vpc/subnet"
  name_prefix        = local.name_prefix
  subnets            = var.private_subnets
  vpc_id             = module.main_vpc.vpc_id
  is_public          = false
  cidr_second_octet  = var.vpc["cidr_second_octet"]
  availability_zones = local.availability_zones
  common_tags = merge(
    local.common_tags,
    {
      project                  = "Infrastructure",
      service                  = "Networking",
      plat_env_project_service = "${local.aggregated_tag}_INFRA_NTW"
    }
  )
}

module "main_nat_gateways" {
  source            = "../../../modules/vpc/nat"
  name_prefix       = local.name_prefix
  public_subnet_ids = module.main_public_subnets.subnet_ids
  common_tags = merge(
    local.common_tags,
    {
      project                  = "Infrastructure",
      service                  = "Networking",
      plat_env_project_service = "${local.aggregated_tag}_INFRA_NTW"
    }
  )
}

# One route table per availability zone with NAT gateway. Copypasted since module doesn't support count right now.
module "main_private_routing_1" {
  source         = "../../../modules/vpc/routes"
  is_public      = false
  name_prefix    = local.name_prefix
  vpc_id         = module.main_vpc.vpc_id
  vpc_cidr       = module.main_vpc.vpc_cidr
  nat_gateway_id = module.main_nat_gateways.nats[0].id
  subnets        = [module.main_private_subnets.subnet_ids[0]]
  common_tags = merge(
    local.common_tags,
    {
      project                  = "Infrastructure",
      service                  = "Networking",
      plat_env_project_service = "${local.aggregated_tag}_INFRA_NTW"
    }
  )
}

module "main_private_routing_2" {
  source         = "../../../modules/vpc/routes"
  is_public      = false
  name_prefix    = local.name_prefix
  vpc_id         = module.main_vpc.vpc_id
  vpc_cidr       = module.main_vpc.vpc_cidr
  nat_gateway_id = module.main_nat_gateways.nats[1].id
  subnets        = [module.main_private_subnets.subnet_ids[1]]
  common_tags = merge(
    local.common_tags,
    {
      project                  = "Infrastructure",
      service                  = "Networking",
      plat_env_project_service = "${local.aggregated_tag}_INFRA_NTW"
    }
  )
}

module "main_private_routing_3" {
  source         = "../../../modules/vpc/routes"
  is_public      = false
  name_prefix    = local.name_prefix
  vpc_id         = module.main_vpc.vpc_id
  vpc_cidr       = module.main_vpc.vpc_cidr
  nat_gateway_id = module.main_nat_gateways.nats[2].id
  subnets        = [module.main_private_subnets.subnet_ids[2]]
  common_tags = merge(
    local.common_tags,
    {
      project                  = "Infrastructure",
      service                  = "Networking",
      plat_env_project_service = "${local.aggregated_tag}_INFRA_NTW"
    }
  )
}

# DB subnets without internet access
module "main_private_db_subnets" {
  source             = "../../../modules/vpc/subnet"
  name_prefix        = local.name_prefix
  subnets            = var.private_db_subnets
  vpc_id             = module.main_vpc.vpc_id
  is_public          = false
  cidr_second_octet  = var.vpc["cidr_second_octet"]
  availability_zones = local.availability_zones
  custom_identifier  = "-db"
  common_tags = merge(
    local.common_tags,
    {
      project                  = "Infrastructure",
      service                  = "Networking",
      plat_env_project_service = "${local.aggregated_tag}_INFRA_NTW"
    }
  )
}

module "main_private_db_routing" {
  source                = "../../../modules/vpc/routes"
  is_public             = false
  name_prefix           = local.name_prefix
  vpc_id                = module.main_vpc.vpc_id
  vpc_cidr              = module.main_vpc.vpc_cidr
  subnets               = module.main_private_db_subnets.subnet_ids
  disable_default_route = true
  common_tags = merge(
    local.common_tags,
    {
      project                  = "Infrastructure",
      service                  = "Networking",
      plat_env_project_service = "${local.aggregated_tag}_INFRA_NTW"
    }
  )
}

module "main_sg_map" {
  source = "../../module_sg_map"

  name_prefix             = local.name_prefix
  vpc_id                  = module.main_vpc.vpc_id
  external_access_mode    = "vpn"
  vpn_masq_cidrs          = ["10.54.10.236/32", "10.54.11.94/32", "10.17.0.0/16", "10.18.0.0/16"]
  alooma_proxy_enabled    = true
  managed_prefix_list_ids = [data.aws_ec2_managed_prefix_list.vpn_ny_users.id]

  common_tags = merge(
    local.common_tags,
    {
      project                  = "Infrastructure",
      service                  = "Networking",
      plat_env_project_service = "${local.aggregated_tag}_INFRA_NTW"
    }
  )
}

# Add nat IP to ALB security group
resource "aws_security_group_rule" "alb_nat" {
  #count             = length(module.main_nat_gateways.cidrs)
  type              = "ingress"
  description       = "From nat to alb"
  protocol          = "tcp"
  security_group_id = module.main_sg_map.alb_id
  cidr_blocks       = formatlist("%v/32", module.main_nat_gateways.cidrs)
  from_port         = 443
  to_port           = 443
}

# VPC endpoints for dynamodb and s3
locals {
  all_routetables = [
    module.main_public_routing.route_table_id,
    module.main_private_db_routing.route_table_id,
    module.main_private_routing_1.route_table_id,
    module.main_private_routing_2.route_table_id,
    module.main_private_routing_3.route_table_id
  ]
}

/* Disabling since we need cross-region bucket access
module s3_endpoint {
  source        = "../../../modules/vpc/endpoint_gateway"
  common_tags   = local.common_tags
  service       = "s3"
  vpc_id        = module.main_vpc.vpc_id
  route_tables  = local.all_routetables
}*/

module "dynamodb_endpoint" {
  source       = "../../../modules/vpc/endpoint_gateway"
  service      = "dynamodb"
  vpc_id       = module.main_vpc.vpc_id
  route_tables = local.all_routetables
  common_tags = merge(
    local.common_tags,
    {
      project                  = "Infrastructure",
      service                  = "Networking",
      plat_env_project_service = "${local.aggregated_tag}_INFRA_NTW"
    }
  )
}

module "gsirt_regional_endpoints" {
  source = "../../../modules/gsirt_regional_endpoints"
}

module "gsirt_endpoint" {
  source            = "../../../modules/vpc/endpoint_gateway"
  service           = module.gsirt_regional_endpoints.regional_endpoints_service_name[var.aws_region_id]
  vpc_endpoint_type = "Interface"
  subnet_ids        = module.main_private_subnets.subnet_ids
  vpc_id            = module.main_vpc.vpc_id
  cidr_second_octet = var.vpc["cidr_second_octet"]

  common_tags = merge(
    local.common_tags,
    {
      Name                     = format("%v-gsirt-endpoint", local.name_prefix)
      project                  = "Infrastructure",
      service                  = "Networking",
      plat_env_project_service = "${local.aggregated_tag}_INFRA_NTW"
    }
  )
}

data "aws_ec2_transit_gateway" "transit_gateway" {
  filter {
    name   = "options.amazon-side-asn"
    values = ["64513"]
  }
}

data "aws_ec2_managed_prefix_list" "vpn_ny_users" {
  filter {
    name   = "prefix-list-name"
    values = ["vpn-ny-users"]
  }
}

data "aws_ec2_managed_prefix_list" "vpn_ny" {
  filter {
    name   = "prefix-list-name"
    values = ["vpn-ny"]
  }
}

data "aws_ec2_managed_prefix_list" "sme_vpn_primary" {
  filter {
    name   = "prefix-list-name"
    values = ["vpn-sme-internal-primary"]
  }
}

data "aws_ec2_managed_prefix_list" "orchard_prod_private" {
  filter {
    name   = "prefix-list-name"
    values = ["prod-orcd-private-subnet-prefix-list"]
  }
}

resource "aws_ec2_transit_gateway_vpc_attachment" "transit_gateway_attachment" {
  vpc_id             = module.main_vpc.vpc_id
  transit_gateway_id = data.aws_ec2_transit_gateway.transit_gateway.id
  subnet_ids = concat(
    module.main_private_subnets.subnet_ids,
  )
}

resource "aws_route" "ny" {
  for_each = toset([
    module.main_private_routing_1.route_table_id,
    module.main_private_routing_2.route_table_id,
    module.main_private_routing_3.route_table_id,
    module.main_private_db_routing.route_table_id,
    module.main_public_routing.route_table_id,
  ])

  route_table_id             = each.value
  destination_prefix_list_id = data.aws_ec2_managed_prefix_list.vpn_ny.id
  transit_gateway_id         = data.aws_ec2_transit_gateway.transit_gateway.id
}

resource "aws_route" "sme_vpn_primary" {
  for_each = toset([
    module.main_private_routing_1.route_table_id,
    module.main_private_routing_2.route_table_id,
    module.main_private_routing_3.route_table_id,
    module.main_private_db_routing.route_table_id,
    module.main_public_routing.route_table_id,
  ])

  route_table_id             = each.value
  destination_prefix_list_id = data.aws_ec2_managed_prefix_list.sme_vpn_primary.id
  transit_gateway_id         = data.aws_ec2_transit_gateway.transit_gateway.id
}

resource "aws_route" "orchard_prod_private" {
  for_each = toset([
    module.main_private_routing_1.route_table_id,
    module.main_private_routing_2.route_table_id,
    module.main_private_routing_3.route_table_id,
    module.main_private_db_routing.route_table_id,
  ])

  route_table_id             = each.value
  destination_prefix_list_id = data.aws_ec2_managed_prefix_list.orchard_prod_private.id
  transit_gateway_id         = data.aws_ec2_transit_gateway.transit_gateway.id
}