locals {
  global_track_priorities_tracks_secrets = [
    "SENTRY_DSN",
  ]

  global_track_priorities_tracks_common_secrets = {
    DD_API_KEY     = aws_secretsmanager_secret.common_secret["DD_API_KEY"]
    MYSQL_USER     = aws_secretsmanager_secret.apollo_api_secret["MYSQL_DB_USER"]
    MYSQL_PASSWORD = aws_secretsmanager_secret.apollo_api_secret["MYSQL_DB_PASS"]
    DSPAPI_APPKEY  = aws_secretsmanager_secret.dsp_api_secret["DSPAPI_APPKEY"]
  }

  global_track_priorities_tracks_secrets_list = [
    for k, v in merge(aws_secretsmanager_secret.global_track_priorities_tracks_secret, local.global_track_priorities_tracks_common_secrets) :
    {
      name      = k,
      valueFrom = "arn:aws:secretsmanager:${var.aws_region_id}:${local.account_id}:secret:${v["name"]}"
    }
  ]
}

data "aws_ecr_repository" "global_track_priorities_tracks_ecr" {
  name = "${local.project_group}/global_track_priorities_tracks_job"
}

resource "aws_secretsmanager_secret" "global_track_priorities_tracks_secret" {
  for_each = toset(local.global_track_priorities_tracks_secrets)

  name       = "${local.secrets_name_prefix}/global_track_priorities_tracks/${each.value}"
  kms_key_id = data.aws_kms_key.secrets_general_key.id

  tags = merge(
    local.common_tags,
    {
      project                  = "Infrastructure",
      service                  = "Secrets Manager",
      plat_env_project_service = "${local.aggregated_tag}_INFRA_SCRT"
    }
  )
}

module "global_track_priorities_tracks" {
  source = "../../../modules/ecs/tasks/scheduled_task_v3"

  env_prefix         = local.env_prefix
  project_group      = local.project_group
  project            = "global_track_priorities_tracks"
  region             = var.aws_region_id
  cluster_arn        = data.aws_ecs_cluster.main.arn
  security_groups    = [data.aws_security_group.main.id]
  task_exec_role_arn = data.aws_iam_role.standard_exec.arn
  task_role_arn      = data.aws_iam_role.standard_exec.arn
  scheduler_role_arn = data.aws_iam_role.scheduler_role.arn
  subnets            = data.aws_subnets.private_subnets.ids
  secrets            = local.global_track_priorities_tracks_secrets_list
  image              = "${data.aws_ecr_repository.global_track_priorities_tracks_ecr.repository_url}:${local.docker_image_env_tag[var.platform.prefix]}"
  cpu                = 512
  memory             = 1024

  # Start on Sunday at 6 PM EST (UTC -4). Repeat every 30 min until midnight.
  # Start on Monday at 6 PM EST (UTC -4). Repeat every 30 min until midnight.
  # Start at midnight from Wednesday till Friday.
  schedule_expression = {
    sunday = {
      expression = "cron(0/30 22-23 ? * SUN *)", # 6PM EST - 8PM EST
      enabled    = false
    },
    monday = {
      expression = "cron(0/30 00-03,22-23 ? * MON *)", # 8PM EST - 12AM EST, 6PM EST - 8PM EST
      enabled    = false
    },
    tuesday = {
      expression = "cron(0/30 00-03 ? * TUE *)", # 8PM EST - 12AM EST
      enabled    = false
    },
    wed_fri = {
      expression = "cron(00 05 ? * WED-FRI *)", # 00AM EST WED - FRI
      enabled    = false
    },
  }

  env_vars = [
    {
      name  = "ENVIRONMENT",
      value = local.environment
    },
    {
      name  = "MYSQL_DATABASE",
      value = "dbSony_dbo"
    },
    {
      name  = "MYSQL_HOST",
      value = module.domains[local.env_prefix]["main-db-rw"]
    },
    {
      name  = "REDIS_HOST",
      value = data.aws_elasticache_cluster.main.cache_nodes.0.address
    },
    {
      name  = "DSPAPI_HOSTNAME",
      value = module.domains[local.env_prefix]["dsp-api"]
    },
    {
      name  = "ECS_CLUSTER",
      value = data.aws_ecs_cluster.main.cluster_name
    },
    {
      name  = "PROJECT",
      value = local.project_group
    },
    {
      name  = "ECS_SERVICE",
      value = "global_track_priorities_tracks"
    },
  ]

  common_tags = merge(
    local.common_tags,
    {
      project                  = "Portal",
      service                  = "ECS",
      plat_env_project_service = "${local.aggregated_tag}_PRL_ECS"
    }
  )
}