locals {
  messages_views_secrets = [
    "SENTRY_DSN",
  ]
  message_views_env_vars = {
    ENVIRONMENT        = local.environment
    SENTRY_DSN         = aws_secretsmanager_secret.messages_views_secret["SENTRY_DSN"].name
    USERDATAAPI_APIKEY = aws_secretsmanager_secret.apollo_user_data_secret["AUTH_API_KEY"].name
    USERDATAAPI_HOST   = module.domains[local.env_prefix]["user-data-api"]
    USERDATAAPI_SCHEMA = "https"

    DD_API_KEY_SECRET_ARN = aws_secretsmanager_secret.common_secret["DD_API_KEY"].arn
    DD_TRACE_ENABLED      = "true"
    DD_SITE               = "datadoghq.com"
    DD_LAMBDA_HANDLER     = "apollo_messages_views.service.lambda_handler"
  }
}

data "aws_ecr_repository" "messages_views_ecr" {
  name = "${local.project_group}/lambda/messages-views"
}

resource "aws_cloudwatch_log_group" "messages_views_log_group" {
  for_each = toset(["basic_messages_views", "feed_messages_views"])

  name              = "/aws/lambda/${local.name_prefix}-${each.key}"
  retention_in_days = module.cloudwatch_logs_retention_by_env[local.env_prefix]

  tags = merge(
    local.common_tags,
    {
      project                  = "Portal",
      service                  = "CloudWatch",
      plat_env_project_service = "${local.aggregated_tag}_PRL_CW"
    }
  )
}

resource "aws_secretsmanager_secret" "messages_views_secret" {
  for_each = toset(local.messages_views_secrets)

  name       = "${local.secrets_name_prefix}/messages_views/${each.value}"
  kms_key_id = data.aws_kms_key.secrets_general_key.id

  tags = merge(
    local.common_tags,
    {
      project                  = "Infrastructure",
      service                  = "Secrets Manager",
      plat_env_project_service = "${local.aggregated_tag}_INFRA_SCRT"
    }
  )
}

module "messages_views_role" {
  source = "../../../modules/iam/roles/lambda_role"

  name_prefix                = local.name_prefix
  name                       = "messages_views_role"
  allow_execution_inside_vpc = true

  common_tags = merge(
    local.common_tags,
    {
      project                  = "Portal",
      service                  = "Lambda",
      plat_env_project_service = "${local.aggregated_tag}_PRL_LMB"
    }
  )

  policies_list = [
    data.aws_iam_policy.logging_policy.arn,
    data.aws_iam_policy.secrets_services_ro.arn,
    data.aws_iam_policy.basic_messages_consumer_policy.arn,
    data.aws_iam_policy.feed_messages_consumer_policy.arn,
  ]
}

resource "aws_lambda_function" "basic_messages_views_lambda" {
  function_name                  = "${local.name_prefix}-basic_messages_views"
  image_uri                      = "${data.aws_ecr_repository.messages_views_ecr.repository_url}:${local.docker_image_env_tag[local.env_prefix]}"
  package_type                   = "Image"
  role                           = module.messages_views_role.role.arn
  description                    = "Managed by Terraform."
  reserved_concurrent_executions = 1

  timeout     = 900
  memory_size = 256

  vpc_config {
    security_group_ids = [data.aws_security_group.lambda.id]
    subnet_ids         = data.aws_subnets.private_subnets.ids
  }

  image_config {
    command = ["datadog_lambda.handler.handler"]
  }

  environment {
    variables = merge(
      local.message_views_env_vars,
      {
        EVENT_VIEW     = "feed_messages"
        MESSAGE_PREFIX = "dev"
      }
    )
  }

  tags = merge(
    local.common_tags,
    {
      project                  = "Portal",
      service                  = "Lambda",
      plat_env_project_service = "${local.aggregated_tag}_PRL_LMB",
      service_name             = "apollo-basic-messages-views"
    }
  )

  depends_on = [
    aws_secretsmanager_secret.messages_views_secret,
    aws_cloudwatch_log_group.messages_views_log_group,
    module.messages_views_role,
  ]

  lifecycle {
    ignore_changes = [
      image_uri
    ]
  }
}

resource "aws_lambda_event_source_mapping" "basic_messages_views_lambda_sqs" {
  event_source_arn                   = data.aws_sqs_queue.basic_messages_queue.arn
  function_name                      = aws_lambda_function.basic_messages_views_lambda.arn
  batch_size                         = 50
  maximum_batching_window_in_seconds = 60
}

resource "aws_lambda_function" "feed_messages_views_lambda" {
  function_name                  = "${local.name_prefix}-feed_messages_views"
  image_uri                      = "${data.aws_ecr_repository.messages_views_ecr.repository_url}:${local.docker_image_env_tag[local.env_prefix]}"
  package_type                   = "Image"
  role                           = module.messages_views_role.role.arn
  description                    = "Managed by Terraform."
  reserved_concurrent_executions = 1

  timeout     = 900
  memory_size = 256

  vpc_config {
    security_group_ids = [data.aws_security_group.lambda.id]
    subnet_ids         = data.aws_subnets.private_subnets.ids
  }

  image_config {
    command = ["datadog_lambda.handler.handler"]
  }

  environment {
    variables = merge(
      local.message_views_env_vars,
      {
        EVENT_VIEW     = "push_messages"
        MESSAGE_PREFIX = "dev"
      }
    )
  }

  tags = merge(
    local.common_tags,
    {
      project                  = "Portal",
      service                  = "Lambda",
      plat_env_project_service = "${local.aggregated_tag}_PRL_LMB",
      service_name             = "apollo-feed-messages-views"
    }
  )

  depends_on = [
    aws_secretsmanager_secret.messages_views_secret,
    aws_cloudwatch_log_group.messages_views_log_group,
    module.messages_views_role,
  ]

  lifecycle {
    ignore_changes = [
      image_uri
    ]
  }
}
/*
resource "aws_lambda_event_source_mapping" "feed_messages_views_lambda_sqs" {
  event_source_arn                   = data.aws_sqs_queue.feed_messages_queue.arn
  function_name                      = aws_lambda_function.feed_messages_views_lambda.arn
  batch_size                         = 50
  maximum_batching_window_in_seconds = 60
}
*/