locals {
  retrieve_and_save_mobile_versions_secrets = [
    "SENTRY_DSN",
  ]
}

data "aws_ecr_repository" "retrieve_and_save_mobile_versions_ecr" {
  name = "${local.project_group}/lambda/retrieve-and-save-mobile-versions"
}

resource "aws_cloudwatch_log_group" "retrieve_and_save_mobile_versions_log_group" {
  name              = "/aws/lambda/${local.name_prefix}-retrieve_and_save_mobile_versions"
  retention_in_days = module.cloudwatch_logs_retention_by_env[local.env_prefix]

  tags = merge(
    local.common_tags,
    {
      project                  = "Portal",
      service                  = "CloudWatch",
      plat_env_project_service = "${local.aggregated_tag}_PRL_CW"
    }
  )
}

resource "aws_secretsmanager_secret" "retrieve_and_save_mobile_versions_secret" {
  for_each = toset(local.retrieve_and_save_mobile_versions_secrets)

  name       = "${local.secrets_name_prefix}/retrieve-and-save-mobile-versions/${each.value}"
  kms_key_id = data.aws_kms_key.secrets_general_key.id

  tags = merge(
    local.common_tags,
    {
      project                  = "Infrastructure",
      service                  = "Secrets Manager",
      plat_env_project_service = "${local.aggregated_tag}_INFRA_SCRT"
    }
  )
}

module "retrieve_and_save_mobile_versions_role" {
  source = "../../../modules/iam/roles/lambda_role"

  name_prefix                = local.name_prefix
  name                       = "retrieve_and_save_mobile_versions_role"
  allow_execution_inside_vpc = true

  common_tags = merge(
    local.common_tags,
    {
      project                  = "Portal",
      service                  = "Lambda",
      plat_env_project_service = "${local.aggregated_tag}_PRL_LMB"
    }
  )

  policies_list = [
    data.aws_iam_policy.secrets_services_ro.arn,
    data.aws_iam_policy.logging_policy.arn,
  ]
}

resource "aws_lambda_function" "retrieve_and_save_mobile_versions_lambda" {
  function_name = "${local.name_prefix}-retrieve_and_save_mobile_versions"
  image_uri     = "${data.aws_ecr_repository.retrieve_and_save_mobile_versions_ecr.repository_url}:${local.docker_image_env_tag[local.env_prefix]}"
  package_type  = "Image"
  role          = module.retrieve_and_save_mobile_versions_role.role.arn
  description   = "Managed by Terraform."

  memory_size = 128
  timeout     = 900

  vpc_config {
    security_group_ids = [data.aws_security_group.lambda.id]
    subnet_ids         = data.aws_subnets.private_subnets.ids
  }

  image_config {
    command = ["datadog_lambda.handler.handler"]
  }

  environment {
    variables = {
      ENVIRONMENT                           = local.environment
      SENTRY_DSN                            = aws_secretsmanager_secret.retrieve_and_save_mobile_versions_secret["SENTRY_DSN"].name
      MYSQL_DB_USER                         = aws_secretsmanager_secret.apollo_api_secret["MYSQL_DB_USER"].name
      MYSQL_DB_PASS                         = aws_secretsmanager_secret.apollo_api_secret["MYSQL_DB_PASS"].name
      MYSQL_DB_NAME                         = "dbSony_dbo"
      MYSQL_DB_HOST                         = module.domains[local.env_prefix]["main-db-rw"]
      REDIS_HOST                            = data.aws_elasticache_cluster.main.cache_nodes.0.address
      PLAY_MARKET_URL                       = "https://play.google.com/store/apps/details?id=com.sonymusic.apollogo"
      APP_STORE_URL                         = "https://itunes.apple.com/lookup?id=1482330393"
      APOLLO_LATEST_VERSION_KEY_PREFIX_LIST = "dev_apollo_api/apollo_go/latest_version,qa_apollo_api/apollo_go/latest_version,stg_apollo_api/apollo_go/latest_version"

      DD_API_KEY_SECRET_ARN = aws_secretsmanager_secret.common_secret["DD_API_KEY"].arn
      DD_TRACE_ENABLED      = "True"
      DD_SITE               = "datadoghq.com"
      DD_LAMBDA_HANDLER     = "retrieve_and_save_mobile_versions.lambda_handler"
    }
  }

  tags = merge(
    local.common_tags,
    {
      project                  = "Portal",
      service                  = "Lambda",
      plat_env_project_service = "${local.aggregated_tag}_PRL_LMB",
      service_name             = "apollo-retrieve-and-save-mobile-versions",
    }
  )

  depends_on = [
    aws_secretsmanager_secret.retrieve_and_save_mobile_versions_secret,
    aws_cloudwatch_log_group.retrieve_and_save_mobile_versions_log_group,
    module.retrieve_and_save_mobile_versions_role,
  ]

  lifecycle {
    ignore_changes = [
      image_uri
    ]
  }
}
/*
resource "aws_cloudwatch_event_rule" "retrieve_and_save_mobile_versions_rule" {
  name                = "${local.name_prefix}-retrieve_and_save_mobile_versions"
  description         = "Retrieve and save iOS and Android app versions."
  schedule_expression = "rate(6 hours)"

  tags = merge(
    local.common_tags,
    {
      project                  = "Portal",
      service                  = "EventBridge",
      plat_env_project_service = "${local.aggregated_tag}_PRL_EB"
    }
  )
}

resource "aws_cloudwatch_event_target" "retrieve_and_save_mobile_versions_target" {
  rule      = aws_cloudwatch_event_rule.retrieve_and_save_mobile_versions_rule.name
  target_id = "${local.name_prefix}-retrieve_and_save_mobile_versions"
  arn       = aws_lambda_function.retrieve_and_save_mobile_versions_lambda.arn
}

resource "aws_lambda_permission" "allow_cloudwatch_to_call_retrieve_and_save_mobile_versions_lambda" {
  statement_id  = "AllowExecutionFromCloudWatch"
  action        = "lambda:InvokeFunction"
  function_name = aws_lambda_function.retrieve_and_save_mobile_versions_lambda.function_name
  principal     = "events.amazonaws.com"
  source_arn    = aws_cloudwatch_event_rule.retrieve_and_save_mobile_versions_rule.arn
}
*/