locals {
  apple_top_playlists_aggregation_secrets = [
    "SENTRY_DSN",
  ]
}

data "aws_ecr_repository" "apple_top_playlists_aggregation_ecr" {
  name = "${local.project_group}/lambda/apple-top-playlists-aggregation"

  provider = aws.gdb-apollo-dev
}

resource "aws_cloudwatch_log_group" "apple_top_playlists_aggregation_log_group" {
  name              = "/aws/lambda/${local.name_prefix}-apple_top_playlists_aggregation"
  retention_in_days = module.cloudwatch_logs_retention_by_env[local.env_prefix]

  tags = merge(
    local.common_tags,
    {
      project                  = "Portal",
      service                  = "CloudWatch",
      plat_env_project_service = "${local.aggregated_tag}_PRL_CW"
    }
  )
}

resource "aws_secretsmanager_secret" "apple_top_playlists_aggregation_secret" {
  for_each = toset(local.apple_top_playlists_aggregation_secrets)

  name       = "${local.secrets_name_prefix}/apple_top_playlists_aggregation/${each.value}"
  kms_key_id = data.aws_kms_key.secrets_general_key.id

  tags = merge(
    local.common_tags,
    {
      project                  = "Infrastructure",
      service                  = "Secrets Manager",
      plat_env_project_service = "${local.aggregated_tag}_INFRA_SCRT"
    }
  )
}

module "apple_top_playlists_aggregation_role" {
  source = "../../../modules/iam/roles/lambda_role"

  name_prefix                = local.name_prefix
  name                       = "apple_top_playlists_aggregation_role"
  allow_execution_inside_vpc = true

  common_tags = merge(
    local.common_tags,
    {
      project                  = "Portal",
      service                  = "Lambda",
      plat_env_project_service = "${local.aggregated_tag}_PRL_LMB"
    }
  )

  policies_list = [
    data.aws_iam_policy.secrets_services_ro.arn,
    data.aws_iam_policy.logging_policy.arn,
  ]
}

resource "aws_lambda_function" "apple_top_playlists_aggregation_lambda" {
  function_name = "${local.name_prefix}-apple_top_playlists_aggregation"
  image_uri     = "${data.aws_ecr_repository.apple_top_playlists_aggregation_ecr.repository_url}:${local.docker_image_env_tag[local.env_prefix]}"
  package_type  = "Image"
  role          = module.apple_top_playlists_aggregation_role.role.arn
  description   = "Managed by Terraform."

  memory_size = 128
  timeout     = 900

  vpc_config {
    security_group_ids = [data.aws_security_group.lambda.id]
    subnet_ids         = data.aws_subnets.private_subnets.ids
  }

  environment {
    variables = {
      ENVIRONMENT   = local.environment
      SENTRY_DSN    = aws_secretsmanager_secret.apple_top_playlists_aggregation_secret["SENTRY_DSN"].name
      MYSQL_DB_USER = aws_secretsmanager_secret.apollo_api_secret["MYSQL_DB_USER"].name
      MYSQL_DB_PASS = aws_secretsmanager_secret.apollo_api_secret["MYSQL_DB_PASS"].name
      MYSQL_DB_NAME = "dbSony_dbo"
      MYSQL_DB_HOST = module.domains[local.env_prefix]["main-db-rw"]
    }
  }

  tags = merge(
    local.common_tags,
    {
      project                  = "Portal",
      service                  = "Lambda",
      plat_env_project_service = "${local.aggregated_tag}_PRL_LMB",
      service_name             = "apollo-apple-top-playlists-aggregation"
    }
  )

  depends_on = [
    aws_secretsmanager_secret.apple_top_playlists_aggregation_secret,
    aws_cloudwatch_log_group.apple_top_playlists_aggregation_log_group,
    module.apple_top_playlists_aggregation_role,
  ]

  lifecycle {
    ignore_changes = [
      image_uri
    ]
  }
}

resource "aws_lambda_permission" "apple_top_playlists_aggregation_lambda_permission" {
  statement_id  = "AllowExecutionFromCloudWatch"
  action        = "lambda:InvokeFunction"
  function_name = aws_lambda_function.apple_top_playlists_aggregation_lambda.function_name
  principal     = "events.amazonaws.com"
  source_arn    = aws_cloudwatch_event_rule.apple_top_playlists_aggregation_event_rule.arn
}

resource "aws_cloudwatch_event_rule" "apple_top_playlists_aggregation_event_rule" {
  name                = "${local.name_prefix}-apple_top_playlists_aggregation"
  schedule_expression = "rate(3 hours)"
}

resource "aws_cloudwatch_event_target" "apple_top_playlists_aggregation_event_target" {
  rule      = aws_cloudwatch_event_rule.apple_top_playlists_aggregation_event_rule.name
  target_id = "lambda"
  arn       = aws_lambda_function.apple_top_playlists_aggregation_lambda.arn
}