locals {
  auth0_unblock_bruteforce_users_secrets = [
    "AUTH0_MANAGEMENT_CLIENT_SECRET",
    "SENTRY_DSN",
  ]
}

data "aws_ecr_repository" "auth0_unblock_bruteforce_users_ecr" {
  name = "${local.project_group}/lambda/clear-notifications"

  provider = aws.gdb-apollo-dev
}

resource "aws_cloudwatch_log_group" "auth0_unblock_bruteforce_users_log_group" {
  name              = "/aws/lambda/${local.name_prefix}-auth0_unblock_bruteforce_users"
  retention_in_days = module.cloudwatch_logs_retention_by_env[local.env_prefix]

  tags = merge(
    local.common_tags,
    {
      project                  = "Portal",
      service                  = "CloudWatch",
      plat_env_project_service = "${local.aggregated_tag}_PRL_CW"
    }
  )
}

resource "aws_secretsmanager_secret" "auth0_unblock_bruteforce_users_secret" {
  for_each = toset(local.auth0_unblock_bruteforce_users_secrets)

  name       = "${local.secrets_name_prefix}/auth0_unblock_bruteforce_users/${each.value}"
  kms_key_id = data.aws_kms_key.secrets_general_key.id

  tags = merge(
    local.common_tags,
    {
      project                  = "Infrastructure",
      service                  = "Secrets Manager",
      plat_env_project_service = "${local.aggregated_tag}_INFRA_SCRT"
    }
  )
}

module "auth0_unblock_bruteforce_users_role" {
  source = "../../../modules/iam/roles/lambda_role"

  name_prefix                = local.name_prefix
  name                       = "auth0_unblock_bruteforce_users_role"
  allow_execution_inside_vpc = true

  common_tags = merge(
    local.common_tags,
    {
      project                  = "Portal",
      service                  = "Lambda",
      plat_env_project_service = "${local.aggregated_tag}_PRL_LMB"
    }
  )

  policies_list = [
    data.aws_iam_policy.secrets_services_ro.arn,
    data.aws_iam_policy.logging_policy.arn,
  ]
}

resource "aws_lambda_function" "auth0_unblock_bruteforce_users_lambda" {
  function_name = "${local.name_prefix}-auth0_unblock_bruteforce_users"
  image_uri     = "${data.aws_ecr_repository.auth0_unblock_bruteforce_users_ecr.repository_url}:${local.docker_image_env_tag[local.env_prefix]}"
  package_type  = "Image"
  role          = module.auth0_unblock_bruteforce_users_role.role.arn
  description   = "Managed by Terraform."

  memory_size = 128
  timeout     = 900

  vpc_config {
    security_group_ids = [data.aws_security_group.lambda.id]
    subnet_ids         = data.aws_subnets.private_subnets.ids
  }

  environment {
    variables = {
      ENVIRONMENT                    = local.environment
      AUTH0_MANAGEMENT_CLIENT_ID     = "feBe1uSmKu8cnbIY7KgdXme3cEw9IAyk"
      AUTH0_MANAGEMENT_CLIENT_SECRET = aws_secretsmanager_secret.auth0_unblock_bruteforce_users_secret["AUTH0_MANAGEMENT_CLIENT_SECRET"].name
      AUTH0_DOMAIN                   = "prod-dna-apps.auth0.com"
      SENTRY_DSN                     = aws_secretsmanager_secret.auth0_unblock_bruteforce_users_secret["SENTRY_DSN"].name
    }
  }

  tags = merge(
    local.common_tags,
    {
      project                  = "Portal",
      service                  = "Lambda",
      plat_env_project_service = "${local.aggregated_tag}_PRL_LMB"
    }
  )

  depends_on = [
    aws_secretsmanager_secret.auth0_unblock_bruteforce_users_secret,
    aws_cloudwatch_log_group.auth0_unblock_bruteforce_users_log_group,
    module.auth0_unblock_bruteforce_users_role,
  ]

  lifecycle {
    ignore_changes = [
      image_uri
    ]
  }
}

resource "aws_lambda_permission" "auth0_unblock_bruteforce_users_lambda_permission" {
  statement_id  = "AllowExecutionFromCloudWatch"
  action        = "lambda:InvokeFunction"
  function_name = aws_lambda_function.auth0_unblock_bruteforce_users_lambda.function_name
  principal     = "events.amazonaws.com"
  source_arn    = aws_cloudwatch_event_rule.auth0_unblock_bruteforce_users_event_rule.arn
}

resource "aws_cloudwatch_event_rule" "auth0_unblock_bruteforce_users_event_rule" {
  name                = "${local.name_prefix}-auth0_unblock_bruteforce_users"
  schedule_expression = "rate(1 minute)"
}

resource "aws_cloudwatch_event_target" "auth0_unblock_bruteforce_users_event_target" {
  rule      = aws_cloudwatch_event_rule.auth0_unblock_bruteforce_users_event_rule.name
  target_id = "lambda"
  arn       = aws_lambda_function.auth0_unblock_bruteforce_users_lambda.arn
}