locals {
  delphi_events_secrets = [
    "SENTRY_DSN",
  ]
}

data "aws_ecr_repository" "delphi_events_ecr" {
  name = "${local.project_group}/lambda/delphi-events"

  provider = aws.gdb-apollo-dev
}

resource "aws_cloudwatch_log_group" "delphi_events_log_group" {
  name              = "/aws/lambda/${local.name_prefix}-delphi_events"
  retention_in_days = module.cloudwatch_logs_retention_by_env[local.env_prefix]

  tags = merge(
    local.common_tags,
    {
      project                  = "Portal",
      service                  = "CloudWatch",
      plat_env_project_service = "${local.aggregated_tag}_PRL_CW"
    }
  )
}

resource "aws_secretsmanager_secret" "delphi_events_secret" {
  for_each = toset(local.delphi_events_secrets)

  name       = "${local.secrets_name_prefix}/delphi_events/${each.value}"
  kms_key_id = data.aws_kms_key.secrets_general_key.id

  tags = merge(
    local.common_tags,
    {
      project                  = "Infrastructure",
      service                  = "Secrets Manager",
      plat_env_project_service = "${local.aggregated_tag}_INFRA_SCRT"
    }
  )
}

module "delphi_events_role" {
  source = "../../../modules/iam/roles/lambda_role"

  name_prefix                = local.name_prefix
  name                       = "delphi_events_role"
  allow_execution_inside_vpc = true

  common_tags = merge(
    local.common_tags,
    {
      project                  = "Portal",
      service                  = "Lambda",
      plat_env_project_service = "${local.aggregated_tag}_PRL_LMB"
    }
  )

  policies_list = [
    data.aws_iam_policy.logging_policy.arn,
    data.aws_iam_policy.secrets_services_ro.arn,
    data.aws_iam_policy.delphi_notification_consumer_policy.arn,
  ]
}

resource "aws_lambda_function" "delphi_events_lambda" {
  function_name                  = "${local.name_prefix}-delphi_events"
  image_uri                      = "${data.aws_ecr_repository.delphi_events_ecr.repository_url}:${local.docker_image_env_tag[local.env_prefix]}"
  package_type                   = "Image"
  role                           = module.delphi_events_role.role.arn
  description                    = "Managed by Terraform."
  reserved_concurrent_executions = 1

  timeout     = 30
  memory_size = 256

  vpc_config {
    security_group_ids = [data.aws_security_group.lambda.id]
    subnet_ids         = data.aws_subnets.private_subnets.ids
  }

  image_config {
    command = ["datadog_lambda.handler.handler"]
  }

  environment {
    variables = {
      ENVIRONMENT        = local.environment
      SENTRY_DSN         = aws_secretsmanager_secret.delphi_events_secret["SENTRY_DSN"].name
      USERDATAAPI_APIKEY = aws_secretsmanager_secret.apollo_user_data_secret["AUTH_API_KEY"].name
      USERDATAAPI_HOST   = module.domains[local.env_prefix]["user-data-api"]
      USERDATAAPI_SCHEMA = "https"


      DD_API_KEY_SECRET_ARN = aws_secretsmanager_secret.common_secret["DD_API_KEY"].arn
      DD_TRACE_ENABLED      = "true"
      DD_SITE               = "datadoghq.com"
      DD_LAMBDA_HANDLER     = "apollo_delphi_events.service.lambda_handler"
    }
  }

  tags = merge(
    local.common_tags,
    {
      project                  = "Portal",
      service                  = "Lambda",
      plat_env_project_service = "${local.aggregated_tag}_PRL_LMB"
    }
  )

  depends_on = [
    aws_secretsmanager_secret.delphi_events_secret,
    aws_cloudwatch_log_group.delphi_events_log_group,
    module.delphi_events_role,
  ]

  lifecycle {
    ignore_changes = [
      image_uri
    ]
  }
}

resource "aws_lambda_event_source_mapping" "delphi_events_lambda_sqs" {
  event_source_arn                   = data.aws_sqs_queue.delphi_notification_queue.arn
  function_name                      = aws_lambda_function.delphi_events_lambda.arn
  batch_size                         = 50
  maximum_batching_window_in_seconds = 60
}