locals {
  juno_monitoring_secrets = [
    "SENTRY_DSN",
  ]
}

data "aws_ecr_repository" "juno_monitoring_ecr" {
  name = "${local.project_group}/lambda/juno-monitoring"

  provider = aws.gdb-apollo-dev
}

resource "aws_cloudwatch_log_group" "juno_monitoring_log_group" {
  name              = "/aws/lambda/${local.name_prefix}-juno_monitoring"
  retention_in_days = module.cloudwatch_logs_retention_by_env[local.env_prefix]

  tags = merge(
    local.common_tags,
    {
      project                  = "Portal",
      service                  = "CloudWatch",
      plat_env_project_service = "${local.aggregated_tag}_PRL_CW"
    }
  )
}

resource "aws_secretsmanager_secret" "juno_monitoring_secret" {
  for_each = toset(local.juno_monitoring_secrets)

  name       = "${local.secrets_name_prefix}/juno_monitoring/${each.value}"
  kms_key_id = data.aws_kms_key.secrets_general_key.id

  tags = merge(
    local.common_tags,
    {
      project                  = "Infrastructure",
      service                  = "Secrets Manager",
      plat_env_project_service = "${local.aggregated_tag}_INFRA_SCRT"
    }
  )
}

module "juno_monitoring_role" {
  source = "../../../modules/iam/roles/lambda_role"

  name_prefix                = local.name_prefix
  name                       = "juno_monitoring_role"
  allow_execution_inside_vpc = true

  common_tags = merge(
    local.common_tags,
    {
      project                  = "Portal",
      service                  = "Lambda",
      plat_env_project_service = "${local.aggregated_tag}_PRL_LMB"
    }
  )

  policies_list = [
    data.aws_iam_policy.logging_policy.arn,
    data.aws_iam_policy.secrets_services_ro.arn,
  ]
}

resource "aws_lambda_function" "juno_monitoring_lambda" {
  function_name = "${local.name_prefix}-juno_monitoring"
  image_uri     = "${data.aws_ecr_repository.juno_monitoring_ecr.repository_url}:${local.docker_image_env_tag[local.env_prefix]}"
  package_type  = "Image"
  role          = module.juno_monitoring_role.role.arn
  description   = "Managed by Terraform."

  timeout     = 900
  memory_size = 256

  vpc_config {
    security_group_ids = [data.aws_security_group.lambda.id]
    subnet_ids         = data.aws_subnets.private_subnets.ids
  }

  environment {
    variables = {
      APOLLOAPI_APPKEY     = aws_secretsmanager_secret.apollo_api_secret["AUTH_API_KEY"].name
      APOLLOAPI_HOSTNAME   = module.domains[local.env_prefix]["apollo-api"]
      DSPAPI_APPKEY        = aws_secretsmanager_secret.dsp_api_secret["DSPAPI_APPKEY"].name
      DSPAPI_HOSTNAME      = module.domains[local.env_prefix]["dsp-api"]
      ENVIRONMENT          = local.environment
      SENTRY_DSN           = aws_secretsmanager_secret.juno_monitoring_secret["SENTRY_DSN"].name
      USERDATAAPI_APPKEY   = aws_secretsmanager_secret.apollo_user_data_secret["AUTH_API_KEY"].name
      USERDATAAPI_HOSTNAME = module.domains[local.env_prefix]["user-data-api"]
    }
  }

  tags = merge(
    local.common_tags,
    {
      project                  = "Portal",
      service                  = "Lambda",
      plat_env_project_service = "${local.aggregated_tag}_PRL_LMB"
    }
  )

  depends_on = [
    aws_secretsmanager_secret.juno_monitoring_secret,
    aws_cloudwatch_log_group.juno_monitoring_log_group,
    module.juno_monitoring_role,
  ]

  lifecycle {
    ignore_changes = [
      image_uri
    ]
  }
}


resource "aws_cloudwatch_event_rule" "juno_monitoring_rule" {
  name                = "${local.name_prefix}-juno_monitoring"
  description         = "Check Juno new date available from 6 to 11 each hour."
  schedule_expression = "cron(0 5-14 * * ? *)"

  tags = merge(
    local.common_tags,
    {
      project                  = "Portal",
      service                  = "EventBridge",
      plat_env_project_service = "${local.aggregated_tag}_PRL_EB"
    }
  )
}

resource "aws_cloudwatch_event_target" "juno_monitoring_target" {
  rule      = aws_cloudwatch_event_rule.juno_monitoring_rule.name
  target_id = "${local.name_prefix}-juno_monitoring"
  arn       = aws_lambda_function.juno_monitoring_lambda.arn
}

resource "aws_lambda_permission" "allow_cloudwatch_to_call_juno_monitoring_lambda" {
  statement_id  = "AllowExecutionFromCloudWatch"
  action        = "lambda:InvokeFunction"
  function_name = aws_lambda_function.juno_monitoring_lambda.function_name
  principal     = "events.amazonaws.com"
  source_arn    = aws_cloudwatch_event_rule.juno_monitoring_rule.arn
}