locals {
  track_visit_events_handling_secrets = [
    "SENTRY_DSN",
  ]
}

data "aws_ecr_repository" "track_visit_events_handling_ecr" {
  name = "${local.project_group}/lambda/track-visit-events-handling"

  provider = aws.gdb-apollo-dev
}

resource "aws_cloudwatch_log_group" "track_visit_events_handling_log_group" {
  name              = "/aws/lambda/${local.name_prefix}-track_visit_events_handling"
  retention_in_days = module.cloudwatch_logs_retention_by_env[local.env_prefix]

  tags = merge(
    local.common_tags,
    {
      project                  = "Portal",
      service                  = "CloudWatch",
      plat_env_project_service = "${local.aggregated_tag}_PRL_CW"
    }
  )
}

resource "aws_secretsmanager_secret" "track_visit_events_handling_secret" {
  for_each = toset(local.track_visit_events_handling_secrets)

  name       = "${local.secrets_name_prefix}/track_visit_events_handling/${each.value}"
  kms_key_id = data.aws_kms_key.secrets_general_key.id

  tags = merge(
    local.common_tags,
    {
      project                  = "Infrastructure",
      service                  = "Secrets Manager",
      plat_env_project_service = "${local.aggregated_tag}_INFRA_SCRT"
    }
  )
}

module "track_visit_events_handling_role" {
  source = "../../../modules/iam/roles/lambda_role"

  name_prefix                = local.name_prefix
  name                       = "track_visit_events_handling_role"
  allow_execution_inside_vpc = true

  common_tags = merge(
    local.common_tags,
    {
      project                  = "Portal",
      service                  = "Lambda",
      plat_env_project_service = "${local.aggregated_tag}_PRL_LMB"
    }
  )

  policies_list = [
    data.aws_iam_policy.logging_policy.arn,
    data.aws_iam_policy.secrets_services_ro.arn,
    data.aws_iam_policy.track_visit_consumer_policy.arn,
  ]
}

resource "aws_lambda_function" "track_visit_events_handling_lambda" {
  function_name = "${local.name_prefix}-track_visit_events_handling"
  image_uri     = "${data.aws_ecr_repository.track_visit_events_handling_ecr.repository_url}:${local.docker_image_env_tag[local.env_prefix]}"
  package_type  = "Image"
  role          = module.track_visit_events_handling_role.role.arn
  description   = "Managed by Terraform."

  memory_size = 128
  timeout     = 120

  vpc_config {
    security_group_ids = [data.aws_security_group.lambda.id]
    subnet_ids         = data.aws_subnets.private_subnets.ids
  }

  environment {
    variables = {
      ENVIRONMENT   = local.environment
      SENTRY_DSN    = aws_secretsmanager_secret.track_visit_events_handling_secret["SENTRY_DSN"].name
      MYSQL_DB_USER = aws_secretsmanager_secret.apollo_api_secret["MYSQL_DB_USER"].name
      MYSQL_DB_PASS = aws_secretsmanager_secret.apollo_api_secret["MYSQL_DB_PASS"].name
      MYSQL_DB_NAME = "dbSony_dbo"
      MYSQL_DB_HOST = module.domains.prod["main-db-rw"]
    }
  }

  tags = merge(
    local.common_tags,
    {
      project                  = "Portal",
      service                  = "Lambda",
      plat_env_project_service = "${local.aggregated_tag}_PRL_LMB",
      service_name             = "apollo-track-visit-events-handling",
    }
  )

  depends_on = [
    aws_secretsmanager_secret.track_visit_events_handling_secret,
    aws_cloudwatch_log_group.track_visit_events_handling_log_group,
    module.track_visit_events_handling_role,
  ]

  lifecycle {
    ignore_changes = [
      image_uri
    ]
  }
}

resource "aws_lambda_event_source_mapping" "track_visit_events_handling_lambda_sqs" {
  event_source_arn = data.aws_sqs_queue.track_visit_queue.arn
  function_name    = aws_lambda_function.track_visit_events_handling_lambda.arn
  batch_size       = 10
}