module "slzAppleMusicChartsFlow_role" {
  source      = "../../../modules/iam/roles/stepfunction_role"
  name_prefix = local.name_prefix
  name        = "slzAppleMusicChartsFlow_role"
  common_tags = merge(
    local.common_tags,
    {
      project                  = "SLZ Ingestion",
      service                  = "Step Functions",
      plat_env_project_service = "${local.aggregated_tag}_SLZI_SFU"
    }
  )
  policies_list = [
    module.iam_map.s3_env_ro.arn,
    module.iam_map.lambda_invoke.arn,
    data.aws_iam_policy.logging.arn,
    data.aws_iam_policy.secrets-services-ro.arn,
    module.iam_map.batch_jobs_sync.arn,
  ]
}

resource "aws_sfn_state_machine" "slzAppleMusicChartsFlow" {
  name       = "${local.name_prefix}-slzAppleMusicChartsFlow"
  role_arn   = module.slzAppleMusicChartsFlow_role.role.arn
  definition = <<EOF
{
  "StartAt": "Placeholder",
  "States": {
    "Placeholder": {
      "Type": "Pass",
      "End": true
    }
  }
}
EOF
  tags = merge(
    local.common_tags,
    {
      project                  = "SLZ Ingestion",
      service                  = "Step Functions",
      plat_env_project_service = "${local.aggregated_tag}_SLZI_SFU"
    }
  )
  lifecycle {
    ignore_changes = [definition]
  }
}

module "slz_apple_music_charts_data_processor" {
  source      = "../../../modules/iam/roles/lambda_role"
  name_prefix = local.name_prefix
  name        = "slz_apple_music_charts_data_processor"
  common_tags = merge(
    local.common_tags,
    {
      project                  = "SLZ Ingestion",
      service                  = "Lambda",
      plat_env_project_service = "${local.aggregated_tag}_SLZI_LMB"
    }
  )
  policies_list = [
    module.iam_map.s3_env_rw.arn,
    module.iam_map.s3_sme_data_rw.arn,
    data.aws_iam_policy.logging.arn,
    data.aws_iam_policy.secrets-services-ro.arn,
  ]

  allow_execution_inside_vpc = true
}

module "slz_apple_music_charts_pipeline_configurator" {
  source      = "../../../modules/iam/roles/lambda_role"
  name_prefix = local.name_prefix
  name        = "slz_apple_music_charts_pipeline_configurator"
  common_tags = merge(
    local.common_tags,
    {
      project                  = "SLZ Ingestion",
      service                  = "Lambda",
      plat_env_project_service = "${local.aggregated_tag}_SLZI_LMB"
    }
  )
  policies_list = [
    module.iam_map.s3_env_rw.arn,
    module.iam_map.s3_sme_data_rw.arn,
    data.aws_iam_policy.logging.arn,
    data.aws_iam_policy.secrets-services-ro.arn,
  ]

  allow_execution_inside_vpc = true
}


module "slz_ecs_apple_charts_scrapper_role" {
  source              = "../../../modules/iam/roles/ecs_task_role"
  enable_default_role = false
  name_prefix         = local.name_prefix
  name                = "slz_ecs_apple_charts_scrapper_role"
  common_tags = merge(
    local.common_tags,
    {
      project                  = "SLZ Ingestion",
      service                  = "Batch",
      plat_env_project_service = "${local.aggregated_tag}_SLZI_BTCH"
    }
  )
  policies_list = [
    module.slz_ecs_apple_music_charts_scrapper_role_merged_policy.policy.arn,
  ]
}

module "slz_ecs_apple_music_charts_scrapper_role_merged_policy" {
  source = "../../../modules/iam/policies/merged_policy"
  name   = "${local.name_prefix}-slz_apple_music_charts_scrapper_role_merged_policy"
  source_policies = [
    module.iam_map.s3_env_rw.policy,
    module.iam_map.s3_sme_data_rw.policy,
    module.iam_map.sf_worker.policy,
    data.aws_iam_policy.secrets-services-rw.policy,
    data.aws_iam_policy.logging.policy,
    module.iam_map.sqs_producer.policy,
    module.iam_map.db_rw.policy,
  ]
}

data "aws_ecr_repository" "slz-apple-music-charts-scrapper" {
  name = "${local.project_group}/slz-apple-music-charts-scrapper"
}

module "slz_apple_music_charts_scrapper_job_def" {
  source          = "../../../modules/batch/job_definition"
  env_prefix      = local.env_prefix
  project_group   = local.project_group
  project         = "slz-apple-music-charts-scrapper"
  job_role_arn    = module.slz_ecs_apple_charts_scrapper_role.role.arn
  image           = "${data.aws_ecr_repository.slz-apple-music-charts-scrapper.repository_url}:${local.docker_image_env_tag[var.platform.prefix]}"
  vcpus           = 2
  memory          = 2000
  timeout_seconds = 7200
  retry_attempts  = 1
  env_vars        = [{ name = "AWS_REGION", value = var.aws_region_id }]
}

module "batch_config_apple_music_charts_standard" {
  source                   = "../../modules/batch_run_config"
  env_prefix               = local.env_prefix
  delphi-configs           = data.aws_s3_bucket.delphi-configs.bucket
  template_name            = "batch_run_config_hasher.tmpl"
  run_config_filename      = "apple-music-charts/scrapper-batch-config-standard.json"
  batch_job_definition_arn = module.slz_apple_music_charts_scrapper_job_def.batch_job_definition.arn
  batch_job_queue_arn      = data.aws_batch_job_queue.slz_downloader_main.arn
}