module "slzCopyFlow_role" {
  source      = "../../../modules/iam/roles/stepfunction_role"
  name_prefix = local.name_prefix
  name        = "slzCopyFlow_role"
  common_tags = merge(
    local.common_tags,
    {
      project                  = "SLZ Ingestion",
      service                  = "Step Functions",
      plat_env_project_service = "${local.aggregated_tag}_SLZI_SFU"
    }
  )
  policies_list = [
    module.iam_map.s3_env_ro.arn,
    module.iam_map.lambda_invoke.arn,
    module.iam_map.batch_jobs_sync.arn,
    data.aws_iam_policy.logging.arn,
    data.aws_iam_policy.secrets-services-ro.arn,
  ]
}

resource "aws_sfn_state_machine" "slzCopyFlow" {
  name       = "${local.name_prefix}-slzCopyFlow"
  role_arn   = module.slzCopyFlow_role.role.arn
  definition = <<EOF
{
  "StartAt": "Placeholder",
  "States": {
    "Placeholder": {
      "Type": "Pass",
      "End": true
    }
  }
}
EOF
  tags = merge(
    local.common_tags,
    {
      project                  = "SLZ Ingestion",
      service                  = "Step Functions",
      plat_env_project_service = "${local.aggregated_tag}_SLZI_SFU"
    }
  )
  lifecycle {
    ignore_changes = [definition]
  }
}

data "aws_ecr_repository" "bulk_copy_task" {
  provider = aws.gdb-delphi-dev
  name     = "delphi/bulk-copy-task"
}

module "bulk_copy_task_role" {
  source              = "../../../modules/iam/roles/ecs_task_role"
  enable_default_role = false
  name_prefix         = local.name_prefix
  name                = "bulk_copy_task_role"
  common_tags = merge(
    local.common_tags,
    {
      project                  = "SLZ",
      service                  = "ECS",
      plat_env_project_service = "${local.aggregated_tag}_SLZI_ECS"
    }
  )
  policies_list = [
    module.iam_map.s3_env_rw.arn,
    module.iam_map.s3_sme_data_rw.arn,
    data.aws_iam_policy.secrets-services-rw.arn,
    data.aws_iam_policy.logging.arn,
    module.cross_env_s3_permissions.policy.arn,
  ]
}

module "bulk_copy_job_def" {
  source          = "../../../modules/batch/job_definition"
  env_prefix      = local.env_prefix
  project_group   = local.project_group
  project         = "bulk_copy_job"
  job_role_arn    = module.bulk_copy_task_role.role.arn
  image           = "${data.aws_ecr_repository.bulk_copy_task.repository_url}:${local.docker_image_env_tag[var.platform.prefix]}"
  vcpus           = 2
  memory          = 7500
  timeout_seconds = 5400
  retry_attempts  = 1
  env_vars        = [{ "name" = "AWS_DEFAULT_REGION", "value" = var.aws_region_id }]
}

module "batch_run_config_bulk_copy" {
  source                   = "../../modules/batch_run_config"
  env_prefix               = local.env_prefix
  delphi-configs           = data.aws_s3_bucket.delphi-configs.bucket
  template_name            = "batch_run_config_hasher.tmpl"
  run_config_filename      = "batch-run-config-bulk-copy.json"
  batch_job_definition_arn = module.bulk_copy_job_def.batch_job_definition.arn
  batch_job_queue_arn      = data.aws_batch_job_queue.decompress_queue.arn
}

module "bulk_copy_lambda_role" {
  source      = "../../../modules/iam/roles/lambda_role"
  name_prefix = local.name_prefix
  name        = "bulk_copy_lambda_role"
  common_tags = merge(
    local.common_tags,
    {
      project                  = "SLZ Ingestion",
      service                  = "Lambda",
      plat_env_project_service = "${local.aggregated_tag}_SLZI_LMB"
    }
  )
  policies_list = [
    module.iam_map.sf_execute.arn,
    data.aws_iam_policy.logging.arn,
    data.aws_iam_policy.secrets-services-ro.arn,
    module.iam_map.s3_env_ro.arn,
    module.iam_map.s3_sme_data_ro.arn,
    module.cross_env_s3_permissions.policy.arn,
  ]

  allow_execution_inside_vpc = true
}