locals {
  backfill_lambda_secrets = []
}

data "aws_ecr_repository" "backfill_lambda_ecr" {
  name = "${local.project_group}/backfill-lambda"
}

resource "aws_cloudwatch_log_group" "backfill_lambda_log_group" {
  name              = "/aws/lambda/${local.name_prefix}-backfill_lambda"
  retention_in_days = 30

  tags = merge(
    local.common_tags,
    {
      project                  = "SLZ",
      service                  = "CloudWatch",
      plat_env_project_service = "${local.aggregated_tag}_SLZ_CW"
    }
  )
}

resource "aws_secretsmanager_secret" "backfill_lambda_secret" {
  for_each = toset(local.backfill_lambda_secrets)

  name       = "${local.secrets_name_prefix}/backfill_lambda/${each.value}"
  kms_key_id = data.aws_kms_key.secrets_general_key.id

  tags = merge(
    local.common_tags,
    {
      project                  = "Infrastructure",
      service                  = "Secrets Manager",
      plat_env_project_service = "${local.aggregated_tag}_INFRA_SCRT"
    }
  )
}

module "backfill_lambda_role" {
  source = "../../../modules/iam/roles/lambda_role"

  name_prefix                = local.name_prefix
  name                       = "backfill_lambda_role"
  allow_execution_inside_vpc = true

  common_tags = merge(
    local.common_tags,
    {
      project                  = "SLZ",
      service                  = "Lambda",
      plat_env_project_service = "${local.aggregated_tag}_SLZ_LMB"
    }
  )

  policies_list = [
    data.aws_iam_policy.logging.arn,
    data.aws_iam_policy.secrets-services-ro.arn,
  ]
}

resource "aws_lambda_function" "backfill_lambda_lambda" {
  function_name = "${local.name_prefix}-backfill_lambda"
  image_uri     = "${data.aws_ecr_repository.backfill_lambda_ecr.repository_url}:${local.docker_image_env_tag[local.env_prefix]}"
  package_type  = "Image"
  role          = module.backfill_lambda_role.role.arn
  description   = "Managed by Terraform."

  timeout     = 900
  memory_size = 256

  vpc_config {
    security_group_ids = [data.aws_security_group.lambda.id]
    subnet_ids         = data.aws_subnets.private_subnets.ids
  }

  environment {
    variables = {
      ENVIRONMENT                                = var.platform.prefix
      SENTRY_DSN                                 = "${local.secrets_name_prefix}/sentry_config"
      APOLLO_DB_CREDENTIALS_SECRET_NAME          = "delphi/${local.env_prefix}/slz/apollo_mysql"
      DELPHI_WORKFLOW_DB_CREDENTIALS_SECRET_NAME = "delphi/${local.env_prefix}/workflowdb/pg/user"
      DELPHI_MAIN_DB_CREDENTIALS_SECRET_NAME     = "delphi/${local.env_prefix}/api/pg/user"
    }
  }

  tags = merge(
    local.common_tags,
    {
      project                  = "SLZ",
      service                  = "Lambda",
      plat_env_project_service = "${local.aggregated_tag}_SLZ_LMB"
    }
  )

  depends_on = [
    aws_secretsmanager_secret.backfill_lambda_secret,
    aws_cloudwatch_log_group.backfill_lambda_log_group,
    module.backfill_lambda_role,
  ]

  lifecycle {
    ignore_changes = [
      image_uri
    ]
  }
}