# ALB with whitelisting
module "private_alb" {
  source      = "../../modules/ec2/alb/alb_v2"
  name_prefix = local.name_prefix
  alb_suffix  = "-private"
  alb_security_groups = flatten([
    module.main_sg_map.alb_id,
    module.main_sg_map.ext_web_id,
    module.main_sg_map.ext_web_http_id,
    module.main_sg_map.github_security_groups[*].id,
  ])
  alb_subnets               = module.main_public_subnets.subnet_ids
  access_logs_enabled       = true
  access_logs_bucket_prefix = "${local.name_prefix}-external-private"
  access_logs_bucket_name   = data.aws_s3_bucket.security_logs.bucket
  enable_ip_blocking        = true

  common_tags = merge(
    local.common_tags,
    {
      service                  = "Load Balancing",
      plat_env_project_service = "${local.aggregated_tag}_LB"
    }
  )
}

module "private_alb_listener_http" {
  source                = "../../modules/ec2/alb/listener"
  alb_arn               = module.private_alb.alb_arn
  alb_listener_protocol = "HTTP"
}

module "private_alb_listener_https" {
  source                  = "../../modules/ec2/alb/listener"
  alb_arn                 = module.private_alb.alb_arn
  alb_listener_protocol   = "HTTPS"
  aws_acm_certificate_arn = aws_acm_certificate.delphiplatform_io_cert.arn
}

resource "aws_lb_listener_certificate" "private_apollo_stream" {
  listener_arn    = module.private_alb_listener_https.alb_listener.arn
  certificate_arn = aws_acm_certificate.apollo_stream_cert.arn
}


module "nlb_forwarder" {
  source = "../../modules/ec2/nlb_for_alb"

  name_prefix        = "${local.name_prefix}-private"
  vpc_id             = module.main_vpc.vpc_id
  alb_arn            = module.private_alb.alb_arn
  public_subnets_ids = module.main_public_subnets.subnet_ids

  security_groups = flatten([
    module.main_sg_map.alb_id,
    module.main_sg_map.ext_web_id,
    module.main_sg_map.ext_web_http_id,
    module.main_sg_map.github_security_groups[*].id,
  ])

  tags = merge(
    local.common_tags,
    {
      service                  = "Load Balancing",
      plat_env_project_service = "${local.aggregated_tag}_LB"
    }
  )
}

output "nlb_eips" {
  value = module.nlb_forwarder.nlb_eips
}