locals {
  cross_product_documentation_notifications_secrets = [
    "SENTRY_DSN",
    "SLACK_TOKEN",
  ]
}

data "aws_ecr_repository" "cross_product_documentation_notifications_ecr" {
  name = "infra/lambda/cross-product-documentation-notifications"
}

resource "aws_cloudwatch_log_group" "cross_product_documentation_notifications_log_group" {
  name              = "/aws/lambda/${local.name_prefix}-cross_product_documentation_notifications"
  retention_in_days = 180

  tags = merge(
    local.common_tags,
    {
      project                  = "Portal",
      service                  = "CloudWatch",
      plat_env_project_service = "${local.aggregated_tag}_PRL_CW"
    }
  )
}

resource "aws_secretsmanager_secret" "cross_product_documentation_notifications_secret" {
  for_each = toset(local.cross_product_documentation_notifications_secrets)

  name       = "${local.secrets_name_prefix}/cross_product_documentation_notifications/${each.value}"
  kms_key_id = data.aws_kms_key.secrets_general_key.id

  tags = merge(
    local.common_tags,
    {
      project                  = "Infrastructure",
      service                  = "Secrets Manager",
      plat_env_project_service = "${local.aggregated_tag}_INFRA_SCRT"
    }
  )
}

module "cross_product_documentation_notifications_role" {
  source = "../../../modules/iam/roles/lambda_role"

  name_prefix                = local.name_prefix
  name                       = "cross_product_documentation_notifications_role"
  allow_execution_inside_vpc = true

  common_tags = merge(
    local.common_tags,
    {
      project                  = "Portal",
      service                  = "Lambda",
      plat_env_project_service = "${local.aggregated_tag}_PRL_LMB"
    }
  )

  policies_list = [
    data.aws_iam_policy.logging_policy.arn,
    data.aws_iam_policy.secrets_services_ro.arn,
  ]
}

resource "aws_lambda_function" "cross_product_documentation_notifications_lambda" {
  function_name = "${local.name_prefix}-cross_product_documentation_notifications"
  image_uri     = "${data.aws_ecr_repository.cross_product_documentation_notifications_ecr.repository_url}:master"
  package_type  = "Image"
  role          = module.cross_product_documentation_notifications_role.role.arn
  description   = "Managed by Terraform."

  memory_size = 128
  timeout     = 900

  vpc_config {
    security_group_ids = [data.aws_security_group.lambda.id]
    subnet_ids         = data.aws_subnets.private_subnets.ids
  }

  environment {
    variables = {
      ENVIRONMENT = local.environment
      SENTRY_DSN  = aws_secretsmanager_secret.cross_product_documentation_notifications_secret["SENTRY_DSN"].name
      SLACK_TOKEN = aws_secretsmanager_secret.cross_product_documentation_notifications_secret["SLACK_TOKEN"].name
    }
  }

  tags = merge(
    local.common_tags,
    {
      project                  = "Portal",
      service                  = "Lambda",
      plat_env_project_service = "${local.aggregated_tag}_PRL_LMB"
    }
  )

  depends_on = [
    aws_secretsmanager_secret.cross_product_documentation_notifications_secret,
    aws_cloudwatch_log_group.cross_product_documentation_notifications_log_group,
    module.cross_product_documentation_notifications_role,
  ]

  lifecycle {
    ignore_changes = [
      image_uri
    ]
  }
}

resource "aws_lambda_permission" "cross_product_documentation_notifications_lambda_s3" {
  statement_id  = "AllowExecutionFromS3"
  action        = "lambda:InvokeFunction"
  function_name = aws_lambda_function.cross_product_documentation_notifications_lambda.arn
  principal     = "s3.amazonaws.com"
  source_arn    = module.cross_products_documentation.bucket.arn
}