# delphi-apple-music-charts
resource "jenkins_folder" "delphi_apple_music_charts" {
  name   = "delphi-apple-music-charts"
  folder = data.jenkins_folder.delphi_monorepos.id
}

resource "jenkins_folder" "delphi_apple_music_charts_lambdas" {
  name   = "lambdas"
  folder = jenkins_folder.delphi_apple_music_charts.id
}

resource "jenkins_folder" "delphi_apple_music_charts_tasks" {
  name   = "tasks"
  folder = jenkins_folder.delphi_apple_music_charts.id
}

resource "jenkins_folder" "delphi_apple_music_charts_stepfunctions" {
  name   = "stepfunctions"
  folder = jenkins_folder.delphi_apple_music_charts.id
}

locals {
  delphi_apple_music_charts_git_name     = "delphi-apple-music-charts"
  delphi_apple_music_charts_git_http_url = "https://github.com/theorchard/delphi-apple-music-charts.git"
  delphi_apple_music_charts_git_ssh_url  = "git@github.com:theorchard/delphi-apple-music-charts.git"
  delphi_apple_music_charts_jobs = {
    slz_apple_music_charts_scrapper = {
      name             = "slz_apple_music_charts_scrapper"
      folder           = jenkins_folder.delphi_apple_music_charts_tasks.id
      disabled         = false
      jenkinsfile_path = "src/task/slz_apple_music_charts_scrapper/Jenkinsfile"
    }
    slz_apple_music_charts_data_processor = {
      name             = "slz_apple_music_charts_data_processor"
      folder           = jenkins_folder.delphi_apple_music_charts_lambdas.id
      disabled         = false
      jenkinsfile_path = "src/lambda/slz_apple_music_charts_data_processor/Jenkinsfile"
    }
    slz_apple_music_charts_pipeline_configurator = {
      name             = "slz_apple_music_charts_pipeline_configurator"
      folder           = jenkins_folder.delphi_apple_music_charts_lambdas.id
      disabled         = false
      jenkinsfile_path = "src/lambda/slz_apple_music_charts_pipeline_configurator/Jenkinsfile"
    }
    slz_apple_music_charts_flow = {
      name             = "slz_apple_music_charts_flow"
      folder           = jenkins_folder.delphi_apple_music_charts_stepfunctions.id
      disabled         = false
      jenkinsfile_path = "src/step_function/slz_apple_music_charts_flow/Jenkinsfile"
    }
    apple-music-charts-pipeline-manager = {
      name              = "apple-music-charts-pipeline-manager"
      folder            = jenkins_folder.delphi_apple_music_charts.id
      branches_to_build = ["develop", "release", "hotfix"]
      jenkins_job_type  = "manager"
      disabled          = false
      jenkinsfile_path  = "Jenkinsfile"
    }
  }
}

module "delphi_apple_music_charts" {
  for_each = local.delphi_apple_music_charts_jobs

  source = "../../modules/jenkins/multibranch-pipeline-delphi-monorepos"

  disabled = each.value["disabled"]
  folder   = each.value["folder"]

  github_repository_name              = local.delphi_apple_music_charts_git_name
  github_repository_http_url          = local.delphi_apple_music_charts_git_http_url
  github_repository_ssh_url           = local.delphi_apple_music_charts_git_ssh_url
  github_repository_branches_to_build = lookup(each.value, "branches_to_build", [])
  jenkinsfile_path                    = each.value["jenkinsfile_path"]
  jenkins_job_type                    = lookup(each.value, "jenkins_job_type", "project")
  jenkins_job_name                    = each.value["name"]

  github_ssh_credentials_id = "theorchard-ci-ssh-key"
  github_credentials_id     = "orchardci-user-token"
  github_repository_owner   = "theorchard"
}