# delphi-data-transfer-framework
resource "jenkins_folder" "delphi_data_transfer_framework" {
  name   = "delphi-data-transfer-framework"
  folder = data.jenkins_folder.delphi_monorepos.id
}

resource "jenkins_folder" "delphi_data_transfer_framework_libs" {
  name   = "libs"
  folder = jenkins_folder.delphi_data_transfer_framework.id
}

resource "jenkins_folder" "delphi_data_transfer_framework_lambdas" {
  name   = "lambdas"
  folder = jenkins_folder.delphi_data_transfer_framework.id
}

resource "jenkins_folder" "delphi_data_transfer_framework_tasks" {
  name   = "tasks"
  folder = jenkins_folder.delphi_data_transfer_framework.id
}

locals {
  delphi_data_transfer_framework_git_name     = "delphi-data-transfer-framework"
  delphi_data_transfer_framework_git_http_url = "https://github.com/theorchard/delphi-data-transfer-framework.git"
  delphi_data_transfer_framework_git_ssh_url  = "git@github.com:theorchard/delphi-data-transfer-framework.git"
  delphi_data_transfer_framework_jobs = {
    dapd_helpers = {
      name             = "dapd_helpers"
      folder           = jenkins_folder.delphi_data_transfer_framework_libs.id
      disabled         = false
      jenkinsfile_path = "src/common/dapd_helpers/Jenkinsfile"
    }

    dapd_exporter_lambda = {
      name             = "dapd_exporter_lambda"
      folder           = jenkins_folder.delphi_data_transfer_framework_lambdas.id
      disabled         = false
      jenkinsfile_path = "src/lambda/dapd_exporter_lambda/Jenkinsfile"
    }

    dapd_importer_lambda = {
      name             = "dapd_importer_lambda"
      folder           = jenkins_folder.delphi_data_transfer_framework_lambdas.id
      disabled         = false
      jenkinsfile_path = "src/lambda/dapd_importer_lambda/Jenkinsfile"
    }

    dapd_exporter = {
      name             = "dapd_exporter"
      folder           = jenkins_folder.delphi_data_transfer_framework_tasks.id
      disabled         = false
      jenkinsfile_path = "src/task/dapd_exporter/Jenkinsfile"
    }

    dapd_exporter_api = {
      name             = "dapd_exporter_api"
      folder           = jenkins_folder.delphi_data_transfer_framework_tasks.id
      disabled         = false
      jenkinsfile_path = "src/task/dapd_exporter_api/Jenkinsfile"
    }
    data-transfer-framework-pipeline-manager = {
      name              = "data-transfer-framework-pipeline-manager"
      folder            = jenkins_folder.delphi_data_transfer_framework.id
      branches_to_build = ["develop", "release", "hotfix"]
      jenkins_job_type  = "manager"
      disabled          = false
      jenkinsfile_path  = "Jenkinsfile"
    }
  }
}

module "delphi_data_transfer_framework" {
  for_each = local.delphi_data_transfer_framework_jobs

  source = "../../modules/jenkins/multibranch-pipeline-delphi-monorepos"

  disabled = each.value["disabled"]
  folder   = each.value["folder"]

  github_repository_name              = local.delphi_data_transfer_framework_git_name
  github_repository_http_url          = local.delphi_data_transfer_framework_git_http_url
  github_repository_ssh_url           = local.delphi_data_transfer_framework_git_ssh_url
  github_repository_branches_to_build = lookup(each.value, "branches_to_build", [])
  jenkinsfile_path                    = each.value["jenkinsfile_path"]
  jenkins_job_type                    = lookup(each.value, "jenkins_job_type", "project")
  jenkins_job_name                    = each.value["name"]

  github_ssh_credentials_id = "theorchard-ci-ssh-key"
  github_credentials_id     = "orchardci-user-token"
  github_repository_owner   = "theorchard"
}