# delphi-public-data-workflowdb-schema
resource "jenkins_folder" "delphi_public_data_workflowdb_schema" {
  name   = "delphi-public-data-workflowdb-schema"
  folder = data.jenkins_folder.delphi_monorepos.id
}

resource "jenkins_folder" "delphi_public_data_workflowdb_schema_liquibase" {
  name   = "liquibase"
  folder = jenkins_folder.delphi_public_data_workflowdb_schema.id
}

resource "jenkins_folder" "delphi_public_data_workflowdb_schema_models" {
  name   = "models"
  folder = jenkins_folder.delphi_public_data_workflowdb_schema.id
}

resource "jenkins_folder" "delphi_public_data_workflowdb_schema_tasks" {
  name   = "tasks"
  folder = jenkins_folder.delphi_public_data_workflowdb_schema.id
}

locals {
  delphi_public_data_workflowdb_schema_git_name     = "delphi-public-data-workflowdb-schema"
  delphi_public_data_workflowdb_schema_git_http_url = "https://github.com/theorchard/delphi-public-data-workflowdb-schema.git"
  delphi_public_data_workflowdb_schema_git_ssh_url  = "git@github.com:theorchard/delphi-public-data-workflowdb-schema.git"
  delphi_public_data_workflowdb_schema_jobs = {
    workflowdb_schema = {
      name             = "workflowdb_schema"
      folder           = jenkins_folder.delphi_public_data_workflowdb_schema_liquibase.id
      disabled         = false
      jenkinsfile_path = "liquibase/Jenkinsfile"
    }

    dapd_db_schema = {
      name             = "dapd_db_schema"
      folder           = jenkins_folder.delphi_public_data_workflowdb_schema_models.id
      disabled         = false
      jenkinsfile_path = "dapd_db_schema/Jenkinsfile"
    }

    dapd_db_seed = {
      name             = "dapd_db_seed"
      folder           = jenkins_folder.delphi_public_data_workflowdb_schema_tasks.id
      disabled         = false
      jenkinsfile_path = "dapd_db_seed/Jenkinsfile"
    }

    delphi-public-data-workflowdb-schema-pipeline-manager = {
      name              = "delphi-public-data-workflowdb-schema-pipeline-manager"
      folder            = jenkins_folder.delphi_public_data_workflowdb_schema.id
      branches_to_build = ["develop", "release", "hotfix"]
      jenkins_job_type  = "manager"
      disabled          = false
      jenkinsfile_path  = "Jenkinsfile"
    }
  }
}

module "delphi_public_data_workflowdb_schema" {
  for_each = local.delphi_public_data_workflowdb_schema_jobs

  source = "../../modules/jenkins/multibranch-pipeline-delphi-monorepos"

  disabled = each.value["disabled"]
  folder   = each.value["folder"]

  github_repository_name              = local.delphi_public_data_workflowdb_schema_git_name
  github_repository_http_url          = local.delphi_public_data_workflowdb_schema_git_http_url
  github_repository_ssh_url           = local.delphi_public_data_workflowdb_schema_git_ssh_url
  github_repository_branches_to_build = lookup(each.value, "branches_to_build", [])
  jenkinsfile_path                    = each.value["jenkinsfile_path"]
  jenkins_job_type                    = lookup(each.value, "jenkins_job_type", "project")
  jenkins_job_name                    = each.value["name"]

  github_ssh_credentials_id = "theorchard-ci-ssh-key"
  github_credentials_id     = "orchardci-user-token"
  github_repository_owner   = "theorchard"
}