# delphi-amazon_music
resource "jenkins_folder" "delphi_amazon_music" {
  name   = "delphi-slz-amazon-music-flow"
  folder = data.jenkins_folder.delphi_monorepos.id
}

resource "jenkins_folder" "delphi_amazon_music_lambdas" {
  name   = "lambdas"
  folder = jenkins_folder.delphi_amazon_music.id
}

resource "jenkins_folder" "delphi_amazon_music_tasks" {
  name   = "tasks"
  folder = jenkins_folder.delphi_amazon_music.id
}

resource "jenkins_folder" "delphi_amazon_music_stepfunctions" {
  name   = "stepfunctions"
  folder = jenkins_folder.delphi_amazon_music.id
}

locals {
  delphi_amazon_music_git_name     = "delphi-slz-amazon-music-flow"
  delphi_amazon_music_git_http_url = "https://github.com/theorchard/delphi-slz-amazon-music-flow.git"
  delphi_amazon_music_git_ssh_url  = "git@github.com:theorchard/delphi-slz-amazon-music-flow.git"
  delphi_amazon_music_jobs = {
    slz_amazon_music_scrapper = {
      name             = "slz_amazon_music_scrapper"
      folder           = jenkins_folder.delphi_amazon_music_tasks.id
      disabled         = false
      jenkinsfile_path = "task/slz_amazon_music_scrapper/Jenkinsfile"
    }
    slz_amazon_music_prepare_configuration = {
      name             = "slz_amazon_music_prepare_configuration"
      folder           = jenkins_folder.delphi_amazon_music_lambdas.id
      disabled         = false
      jenkinsfile_path = "lambda/slz_amazon_music_prepare_configuration/Jenkinsfile"
    }
    slz_amazon_music_availability_check = {
      name             = "slz_amazon_music_availability_check"
      folder           = jenkins_folder.delphi_amazon_music_lambdas.id
      disabled         = false
      jenkinsfile_path = "lambda/slz_amazon_music_availability_check/Jenkinsfile"
    }
    slz_amazon_music_clean_up = {
      name             = "slz_amazon_music_clean_up"
      folder           = jenkins_folder.delphi_amazon_music_lambdas.id
      disabled         = false
      jenkinsfile_path = "lambda/slz_amazon_music_clean_up/Jenkinsfile"
    }
    slz_amazon_music_step_function = {
      name             = "slz_amazon_music_step_function"
      folder           = jenkins_folder.delphi_amazon_music_stepfunctions.id
      disabled         = false
      jenkinsfile_path = "slz_amazon_music_step_function/Jenkinsfile"
    }
    slz-amazon-music-pipeline-manager = {
      name              = "slz-amazon-music-pipeline-manager"
      folder            = jenkins_folder.delphi_amazon_music.id
      branches_to_build = ["develop", "release", "hotfix"]
      jenkins_job_type  = "manager"
      disabled          = false
      jenkinsfile_path  = "Jenkinsfile"
    }
  }
}

module "delphi_amazon_music" {
  for_each = local.delphi_amazon_music_jobs

  source = "../../modules/jenkins/multibranch-pipeline-delphi-monorepos"

  disabled = each.value["disabled"]
  folder   = each.value["folder"]

  github_repository_name              = local.delphi_amazon_music_git_name
  github_repository_http_url          = local.delphi_amazon_music_git_http_url
  github_repository_ssh_url           = local.delphi_amazon_music_git_ssh_url
  github_repository_branches_to_build = lookup(each.value, "branches_to_build", [])
  jenkinsfile_path                    = each.value["jenkinsfile_path"]
  jenkins_job_type                    = lookup(each.value, "jenkins_job_type", "project")
  jenkins_job_name                    = each.value["name"]

  github_ssh_credentials_id = "theorchard-ci-ssh-key"
  github_credentials_id     = "orchardci-user-token"
  github_repository_owner   = "theorchard"
}