# delphi-spotify-charts
resource "jenkins_folder" "delphi_spotify_charts" {
  name   = "delphi-spotify-charts"
  folder = data.jenkins_folder.delphi_monorepos.id
}

resource "jenkins_folder" "delphi_spotify_charts_lambdas" {
  name   = "lambdas"
  folder = jenkins_folder.delphi_spotify_charts.id
}

resource "jenkins_folder" "delphi_spotify_charts_stepfunctions" {
  name   = "stepfunctions"
  folder = jenkins_folder.delphi_spotify_charts.id
}

locals {
  delphi_spotify_charts_git_name     = "delphi-spotify-charts"
  delphi_spotify_charts_git_http_url = "https://github.com/theorchard/delphi-spotify-charts.git"
  delphi_spotify_charts_git_ssh_url  = "git@github.com:theorchard/delphi-spotify-charts.git"
  delphi_spotify_charts_jobs = {
    slz_spotify_charts_scraper = {
      name             = "slz_spotify_charts_scraper"
      folder           = jenkins_folder.delphi_spotify_charts_lambdas.id
      disabled         = false
      jenkinsfile_path = "src/lambda/slz_spotify_charts_scraper/Jenkinsfile"
    }
    slz_spotify_charts_data_extender = {
      name             = "slz_spotify_charts_data_extender"
      folder           = jenkins_folder.delphi_spotify_charts_lambdas.id
      disabled         = false
      jenkinsfile_path = "src/lambda/slz_spotify_charts_data_extender/Jenkinsfile"
    }
    slz_spotify_charts_clean_up = {
      name             = "slz_spotify_charts_clean_up"
      folder           = jenkins_folder.delphi_spotify_charts_lambdas.id
      disabled         = false
      jenkinsfile_path = "src/lambda/slz_spotify_charts_clean_up/Jenkinsfile"
    }
    slz_spotify_charts_scraper_step_function = {
      name             = "slz_spotify_charts_scraper_step_function"
      folder           = jenkins_folder.delphi_spotify_charts_stepfunctions.id
      disabled         = false
      jenkinsfile_path = "src/step_function/slz_spotify_charts_scraper_step_function/Jenkinsfile"
    }
    spotify-charts-pipeline-manager = {
      name              = "spotify-charts-pipeline-manager"
      folder            = jenkins_folder.delphi_spotify_charts.id
      branches_to_build = ["develop", "release", "hotfix"]
      jenkins_job_type  = "manager"
      disabled          = false
      jenkinsfile_path  = "Jenkinsfile"
    }
  }
}

module "delphi_spotify_charts" {
  for_each = local.delphi_spotify_charts_jobs

  source = "../../modules/jenkins/multibranch-pipeline-delphi-monorepos"

  disabled = each.value["disabled"]
  folder   = each.value["folder"]

  github_repository_name              = local.delphi_spotify_charts_git_name
  github_repository_http_url          = local.delphi_spotify_charts_git_http_url
  github_repository_ssh_url           = local.delphi_spotify_charts_git_ssh_url
  github_repository_branches_to_build = lookup(each.value, "branches_to_build", [])
  jenkinsfile_path                    = each.value["jenkinsfile_path"]
  jenkins_job_type                    = lookup(each.value, "jenkins_job_type", "project")
  jenkins_job_name                    = each.value["name"]

  github_ssh_credentials_id = "theorchard-ci-ssh-key"
  github_credentials_id     = "orchardci-user-token"
  github_repository_owner   = "theorchard"
}