locals {
  name        = "${var.env_prefix}-${var.project_group}-${var.project}"
  name_prefix = "${var.env_prefix}-${var.project_group}"

  mapping_template = <<PORTS
[
  {
    "hostPort": ${var.container_port},
    "protocol": "${var.protocol}",
    "containerPort": ${var.container_port}
  }
]
PORTS

  mount_points = <<MOUNT_POINTS
[
  {
    "containerPath": "${var.container_path}",
    "sourceVolume": "${var.volume_name}"
  }
]
MOUNT_POINTS

  port_mapping = var.port_mapping_enabled ? local.mapping_template : "[]"
}


resource "aws_cloudwatch_log_group" "main" {
  name = "/ecs/${local.name}"
  tags = var.common_tags
}

resource "aws_ecs_task_definition" "main" {
  family                   = var.task_family
  task_role_arn            = var.task_role_arn
  execution_role_arn       = var.task_exec_role_arn
  network_mode             = "awsvpc"
  requires_compatibilities = ["FARGATE"]
  cpu                      = var.cpu
  memory                   = var.memory
  tags                     = var.common_tags

  container_definitions = templatefile(
    "${path.module}/${var.containers_template}",
    {
      region         = var.region
      log_group      = aws_cloudwatch_log_group.main.name
      container_name = var.project
      docker_image   = var.image
      secrets        = var.secrets
      port_mapping   = local.port_mapping
      env_vars       = jsonencode(var.env_vars)
      extra_hosts    = "null"
      mount_points   = local.mount_points
    }
  )

  volume {
    name = var.volume_name

    efs_volume_configuration {
      file_system_id = var.file_system_id
      root_directory = var.root_directory
    }
  }

  lifecycle {
    create_before_destroy = true
  }
}