locals {
  # Concatinate list of given policies and default policy, if it is enabled
  policies_list = var.allow_execution_inside_vpc ? concat(["arn:aws:iam::aws:policy/service-role/AWSLambdaVPCAccessExecutionRole"], var.policies_list) : var.policies_list

}
data "aws_iam_policy_document" "lambda_role" {
  version = "2012-10-17"
  statement {
    actions = ["sts:AssumeRole"]
    effect  = "Allow"
    principals {
      type = "Service"
      identifiers = [
        "edgelambda.amazonaws.com",
        "events.amazonaws.com",
        "lambda.amazonaws.com",
      ]
    }
  }
  dynamic "statement" {
    for_each = length(var.additional_principals) > 0 ? ["Enabled"] : []
    content {
      actions = ["sts:AssumeRole"]
      effect  = "Allow"
      principals {
        type        = "AWS"
        identifiers = var.additional_principals
      }
    }
  }
}
resource "aws_iam_role" "lambda_role" {
  name = "${var.name_prefix}-${var.name}"

  assume_role_policy = data.aws_iam_policy_document.lambda_role.json
  tags               = var.common_tags
}

resource "aws_iam_role_policy_attachment" "attachments" {
  count      = length(local.policies_list)
  role       = aws_iam_role.lambda_role.id
  policy_arn = local.policies_list[count.index]
}