locals {
  read_enabled        = length(var.read_arns) == 0 ? [] : ["Allow external read IAM entity"]
  upload_enabled      = length(var.upload_arns) == 0 ? [] : ["Allow external upload IAM entity"]
  delete_enabled      = length(var.delete_arns) == 0 ? [] : ["Allow external delete IAM entity"]
  full_access_enabled = length(var.full_access_arns) == 0 ? [] : ["Allow external delete IAM entity"]
}

resource "aws_s3_bucket_policy" "main" {
  bucket = var.bucket_name
  policy = data.aws_iam_policy_document.main.json
}

data "aws_iam_policy_document" "main" {
  version                 = "2012-10-17"
  policy_id               = "Resource policy for ${var.bucket_name}"
  source_policy_documents = var.encryption_in_transit ? [module.default_bucket_policy.document.json] : null

  dynamic "statement" {
    for_each = local.delete_enabled
    content {
      sid    = "Explicit allow for external delete"
      effect = "Allow"
      actions = [
        "s3:DeleteObject",
        "s3:DeleteObjectTagging",
        "s3:DeleteObjectVersion",
        "s3:DeleteObjectVersionTagging"
      ]
      resources = sort([
        "arn:aws:s3:::${var.bucket_name}/*",
        "arn:aws:s3:::${var.bucket_name}"
      ])
      principals {
        type        = "AWS"
        identifiers = sort(var.delete_arns)
      }
    }
  }

  dynamic "statement" {
    for_each = local.read_enabled
    content {
      sid    = "Explicit allow for external read"
      effect = "Allow"
      actions = sort([
        "s3:GetObject",
        "s3:ListBucket",
        "s3:GetObjectTagging",
        "s3:GetObjectVersion",
        "s3:GetObjectVersionTagging"
      ])
      resources = [
        "arn:aws:s3:::${var.bucket_name}/*",
        "arn:aws:s3:::${var.bucket_name}"
      ]
      principals {
        type        = "AWS"
        identifiers = sort(var.read_arns)
      }
    }
  }

  dynamic "statement" {
    for_each = local.upload_enabled
    content {
      sid    = "Explicit allow for external write"
      effect = "Allow"
      actions = [
        "s3:ListMultipartUploadParts",
        "s3:AbortMultipartUpload",
        "s3:ListBucketMultipartUploads",
        "s3:PutObjectVersionTagging",
        "s3:PutObjectTagging",
        "s3:PutObject",
        "s3:PutObjectAcl",
      ]
      resources = sort([
        "arn:aws:s3:::${var.bucket_name}/*",
        "arn:aws:s3:::${var.bucket_name}"
      ])
      principals {
        type        = "AWS"
        identifiers = sort(var.upload_arns)
      }
    }
  }

  dynamic "statement" {
    for_each = local.full_access_enabled
    content {
      sid    = "Explicit allow for external full access"
      effect = "Allow"
      actions = sort([
        "s3:GetObject",
        "s3:ListBucket",
        "s3:GetObjectTagging",
        "s3:GetObjectVersion",
        "s3:GetObjectVersionTagging",
        "s3:ListMultipartUploadParts",
        "s3:AbortMultipartUpload",
        "s3:ListBucketMultipartUploads",
        "s3:PutObjectVersionTagging",
        "s3:PutObjectTagging",
        "s3:PutObject",
        "s3:PutObjectAcl",
        "s3:DeleteObject",
        "s3:DeleteObjectTagging",
        "s3:DeleteObjectVersion",
        "s3:DeleteObjectVersionTagging",
      ])
      resources = sort([
        "arn:aws:s3:::${var.bucket_name}/*",
        "arn:aws:s3:::${var.bucket_name}"
      ])
      principals {
        type        = "AWS"
        identifiers = sort(var.full_access_arns)
      }
    }
  }
}

module "default_bucket_policy" {
  source              = "../default_policy_template"
  template_bucket_arn = "arn:aws:s3:::${var.bucket_name}"
}