String GITHUB_REPOSITORY = 'python-deployment-utils'
String ECR_ACCOUNT_ID = '086679231553'
List<String> AWS_REGIONS = ['us-east-1']
String SLACK_NOTIFICATIONS_CHANNEL = '#devops'

PROJECTS = [
    "airflow-tools": [
        dir: 'airflow',
        dockerBuildTarget: 'base',
    ],
    "docker-image-scanner": [
        dir: 'ecr_scan',
        dockerBuildTarget: 'base',
        vulnerabilitiesToIgnore: [
            // Vulnerabilities in Go runtime used by inspector-sbomgen, requires upstream fix
            "CVE-2026-39821",
            "CVE-2026-39832",
            "CVE-2026-39833",
            "CVE-2026-39834",
            "CVE-2026-42508",
            "CVE-2026-46595",
            "CVE-2026-46597",
        ]
    ],
    "fargate-tools": [
        dir: 'fargate/docker',
        dockerBuildTarget: 'deploy'
    ],
    "frontend-rollback": [
        dir: 's3',
        dockerBuildTarget: 'base'
    ]
]

@groovy.transform.Field
Map projectsToBuild = null

pipeline {
    agent any

    options {
        ansiColor('xterm')
        disableConcurrentBuilds()
        timestamps()
    }

    parameters {
        choice(name: 'PROJECT_NAME', choices: [''] + PROJECTS.keySet(), description: 'The project to build. If not specified, all modified projects will be built.')
        string(name: 'SHARED_LIBRARIES_VERSION', defaultValue: 'master', description: 'The version of the Jenkins shared libraries to use. Can be a branch, tag, Git revision or PR ref (e.g. pull/PR_NUMBER/merge).')
    }

    triggers {
        issueCommentTrigger('.*retest this please.*')
    }

    stages {
        stage('Load Shared Libraries') {
            steps {
                library "jenkins-global-libraries@${params.SHARED_LIBRARIES_VERSION}"
            }
        }
        stage('Compliance Checks') {
            steps {
                complianceChecks()
            }
        }
        stage('Unit Tests and Style Checks') {
            steps {
                script {
                    parallel(getProjectsToBuild().collectEntries { project, config ->
                        [
                            (project): {
                                dir(config['dir']) {
                                    withEcr {
                                        sh 'make ci_unit_lint'
                                    }
                                }
                            }
                        ]
                    })
                }

            }
            post {
                always {
                    script {
                        parallel(getProjectsToBuild().collectEntries { project, config ->
                            [
                                (project): {
                                    dir(config['dir']) {
                                        xunit tools: [JUnit(pattern: 'build/pyunit.xml', deleteOutputFiles: true, failIfNotNew: true, stopProcessingIfError: true)]
                                        recordCoverage(tools: [[parser: 'COBERTURA', pattern: 'build/coverage.xml']], enabledForFailure: true, failOnError: true)
                                    }
                                }
                            ]
                        })
                    }
                }
                cleanup {
                    script {
                        parallel(getProjectsToBuild().collectEntries { project, config ->
                            [
                                (project): {
                                    dir(config['dir']) {
                                        sh 'make ci_unit_lint_clean'
                                    }
                                }
                            ]
                        })
                    }
                }
            }
        }
        stage('Static Application Security Tests') {
            steps {
                script {
                    parallel(getProjectsToBuild().collectEntries { project, config ->
                        [
                            (project): {
                                sastTests(projectDir: config['dir'])
                            }
                        ]
                    })
                }
            }
        }
        stage('Sonar Scan and Analysis') {
            when {
                branch 'master'
            }
            steps {
                script {
                    echo "Running Sonar scan for ${GITHUB_REPOSITORY}"
                    sonarScan project: GITHUB_REPOSITORY, language: 'py'
                }
            }
        }
        stage('Create a Release') {
            steps {
                script {
                    parallel(getProjectsToBuild().collectEntries { project, config ->
                        [
                            (project): {
                                dockerToEcr awsRegions: AWS_REGIONS,
                                    ecrAccountId: ECR_ACCOUNT_ID,
                                    imageName: project,
                                    imageTag: env.GIT_COMMIT,
                                    dockerBuildContext: config['dir'],
                                    dockerBuildFile: "${config['dir']}/Dockerfile",
                                    dockerBuildTarget: config['dockerBuildTarget'],
                                    pushLatest: (env.BRANCH_NAME == 'master')
                            }
                        ]
                    })
                }
            }
        }
        stage('Scan Docker Image') {
            steps {
                script {
                    parallel(getProjectsToBuild().collectEntries { project, config ->
                        [
                            (project): {
                                // If we've built a new version of the docker scanner image, use that to run the scan
                                // This ensures that any changes to the config are picked up.
                                def scannerImageTag = getProjectsToBuild().keySet().contains('docker-image-scanner') ? env.GIT_COMMIT : 'latest'
                                dockerScan awsRegion: AWS_REGIONS[0],
                                    ecrAccountId: ECR_ACCOUNT_ID,
                                    imageName: project,
                                    imageTag: env.GIT_COMMIT,
                                    vulnerabilitiesToIgnore: config['vulnerabilitiesToIgnore'] ?: [],
                                    scannerImage: "${ECR_ACCOUNT_ID}.dkr.ecr.${AWS_REGIONS[0]}.amazonaws.com/docker-image-scanner:${scannerImageTag}"
                            }
                        ]
                    })
                }
            }
        }
    }

    post {
        regression {
            script {
                if (env.BRANCH_NAME == 'master') {
                    slackNotify channel: SLACK_NOTIFICATIONS_CHANNEL
                }
            }
        }
        fixed {
            script {
                if (env.BRANCH_NAME == 'master') {
                    slackNotify channel: SLACK_NOTIFICATIONS_CHANNEL
                }
            }
        }
        cleanup {
            cleanWs()
        }
    }
}

def getProjectsToBuild() {
    if (this.@projectsToBuild != null) {
        return this.@projectsToBuild
    }

    this.@projectsToBuild = [:]

    if (params.PROJECT_NAME) {
        this.@projectsToBuild << PROJECTS.find{ it.key == params.PROJECT_NAME }
    }
    else {
        def projectPaths = PROJECTS.collect{ it.value['dir'] }
        def modifiedPaths = getModifiedPaths(paths: projectPaths)
        this.@projectsToBuild << PROJECTS.findAll{modifiedPaths.contains(it.value['dir']) }
    }
    currentBuild.description = this.@projectsToBuild.keySet().join('<br>')

    return this.@projectsToBuild
}