#------------------------------------------------------------
# Copyright (C) 2006 RoyaltyShare, Inc.   All Rights Reserved
# $Id$
#------------------------------------------------------------
package RPS::ArtistPayee::ArtistPayeeAccount;

use Carp;
use strict;
use warnings;

use lib '/app/tools/common/lib';
use Common::Assert;
use Common::WriteXML;

use lib '/app/tools/rps/lib';
use RPS::DB::Item::ArtistPayeeAccount;
use RPS::Finance::Account;

use Common::FormObject;
use base 'Common::FormObject';


sub _init
{
    my ($self, %args) = @_;

    $self->SUPER::_init(%args);

    my %properties;
    $self->{_showPendingPaymentsOnly} = $args{showPendingPaymentsOnly};

    if ($args{_dbItem})
    {
        $self->_propertiesFromDBItem(\%properties, $args{_dbItem});
    }
    elsif ($args{artistPayeeID} && $args{payorID})
    {
        $self->_propertiesFromDB(\%properties, $args{artistPayeeID}, $args{payorID});
    }
    else
    {
        $self->_propertiesFromDefaults(\%properties, $args{artistPayeeID}, $args{payorID});
    }

    $self->_initProperties(\%properties);
    $self->_initSubs(\%properties);

    return $self;
}


sub _propertiesFromDB
{
    my ($self, $hrProperties, $artistPayeeID, $payorID) = @_;

    my $dbItem = RPS::DB::Item::ArtistPayeeAccount->Lookup(artist_payee_id => $artistPayeeID, payor_id => $payorID);

    if ($dbItem)
    {
        $self->_propertiesFromDBItem($hrProperties, $dbItem);
    }
    else
    {
        $self->_propertiesFromDefaults($hrProperties, $artistPayeeID, $payorID);
    }
}


sub _propertiesFromDBItem
{
	my ($self, $hrProperties, $dbItem) = @_;

#    assert($dbItem->finance_account_id);
    $self->{_dbItem} = $dbItem;

    $hrProperties->{artist_payee_id}  = $dbItem->artist_payee_id;
    $hrProperties->{payor_id}  = $dbItem->payor_id;
    $hrProperties->{finance_account_id} = $dbItem->finance_account_id;
    $hrProperties->{min_payment} = $dbItem->min_payment;
}


sub _propertiesFromDefaults
{
    my ($self, $hrProperties, $artistPayeeID, $payorID) = @_;

    $hrProperties->{artist_payee_id} = $artistPayeeID if $artistPayeeID;
    $hrProperties->{payor_id} = $payorID if $payorID;
}


sub _initProperties
{
    my ($self, $props) = @_;

    $self->{ArtistPayeeID}		= Common::FormObject::Scalar->new(value => $props->{artist_payee_id}, readOnly => 1);
    $self->{PayorID}		    = Common::FormObject::Scalar->new(value => $props->{payor_id}, readOnly => 1);
    $self->{FinanceAccountID}   = Common::FormObject::Scalar->new(value => $props->{finance_account_id}, readOnly => 1);
    $self->{MinPayment}         = Common::FormObject::Scalar::Decimal->new(value => $props->{min_payment}, precision => '0.2');
}


sub _initSubs
{
    my ($self, $props) = @_;

	if($self->loadSubs())
	{
		if($props->{finance_account_id})
		{
        	$self->{FinanceAccount} = RPS::Finance::Account->new
            (
                accountID => $props->{finance_account_id},
                showPendingPaymentsOnly => $self->{_showPendingPaymentsOnly},
            );
		}
        else
        {
        	$self->{FinanceAccount} = RPS::Finance::Account->new();
        }
	}
}

sub clearPayments
{
    my ($self) = @_;

    $self->{FinanceAccount}->clearPendingPayments();
}


sub setFirstPayment
{
    my ($self, $amount) = @_;

    $self->{FinanceAccount}->setFirstPendingPayment($amount);
}


sub save
{
	my ($self, $dbItem) = @_;

    if (! $self->{FinanceAccount}->Description())
    {
        $self->{FinanceAccount}->Description("account for artist payee " . $self->ArtistPayeeID() . " payor " . $self->PayorID());
    }
    if (! $self->{FinanceAccount}->TypeCode())
    {
        $self->{FinanceAccount}->TypeCode(RPS::DB::Item::FinanceAccount::kAccountTypeHoldover);
    }

    $self->{FinanceAccount}->save();
    my $financeAccountID = $self->{FinanceAccount}->AccountID();

    $dbItem = $self->{_dbItem} unless $dbItem;

    if (! $dbItem)
    {
        $dbItem = RPS::DB::Item::ArtistPayeeAccount->Create(
            finance_account_id => $financeAccountID,
        );
    }

    if ($dbItem->finance_account_id() != $financeAccountID)
    {
        $dbItem->finance_account_id($financeAccountID);
    }
    $dbItem->artist_payee_id($self->ArtistPayeeID());
    $dbItem->payor_id($self->PayorID());
    $dbItem->min_payment($self->MinPayment());

	$dbItem->save();

	# reload object state
	#
	$self->_init(_dbItem => $dbItem);
}


###
1;#
###