#---------------------------------------------------------------
# ____                   _ _         ____  _                    
#|  _ \ ___  _   _  __ _| | |_ _   _/ ___|| |__   __ _ _ __ ___ 
#| |_) / _ \| | | |/ _` | | __| | | \___ \| '_ \ / _` | '__/ _ \
#|  _ < (_) | |_| | (_| | | |_| |_| |___) | | | | (_| | | |  __/
#|_| \_\___/ \__, |\__,_|_|\__|\__, |____/|_| |_|\__,_|_|  \___|
#            |___/             |___/                            
#
# Copyright (C) 2009 RoyaltyShare, Inc.   All Rights Reserved
#---------------------------------------------------------------

package RPS::Import::Akuma;

use strict;

use Date::Calc qw(Days_in_Month Add_Delta_Days Decode_Month);

use lib '/app/tools/rps/lib';
use RPS::DB::Item::Client;

use lib '/app/tools/common/lib';
use Common::Consts;
use Common::Assert;
use Common::Log;

use lib '/app/tools/data_classes/lib';

use lib '/app/tools/rps/lib';
use RPS::DB::Item::MediaType;
use RPS::File::Sale;

use lib '/app/tools/rps/lib';
use RPS::Import::Importer;
use base 'RPS::Import::Importer';

my %fieldMap = (
        1 => {
            upc             => 0,
            isrc            => 1,
            service_id      => 2,
            title           => 3,
            artist          => 4,
            label           => 5,
            date            => 6,
            type            => 7,
            units           => 8,
            net_price       => 9,
            country_code    => 12,
            currency_code   => 13,
        },
);

my %gProductTypeMap = (
    'song' =>
    {
        productType => RPS::File::Sale::TYPE_TRACK,
        formatType => RPS::File::Sale::FORMAT_DOWNLOAD,
        mediaType => RPS::DB::Item::MediaType::kMediaTypeAudio,
    },
    'album' =>
    {
        productType => RPS::File::Sale::TYPE_ALBUM,
        formatType => RPS::File::Sale::FORMAT_DOWNLOAD,
        mediaType => RPS::DB::Item::MediaType::kMediaTypeAudio,
    },
);

#public methods

sub _importLines
{
	my $self = shift;
	my %args = @_;
	my $fileObj = $args{file};
    my $version = $args{file}->VersionNum();
    my $fileName = $args{file}->OrigFileName();
    my $serviceID = $args{file}->ServiceID;
    my $sheet_count = 0;

    assert(defined $args{sheets});
    assert(defined $version);

    my $offsets = $fieldMap{$version};
    my $sheet_names = $args{sheet_names};
    my $sheets = $args{sheets};
    my $linenum = 1;

    for (my $sheetIndex = 0; $sheetIndex < scalar @{$args{sheets}}; $sheetIndex++)
    {
        my $sheet = $sheets->[$sheetIndex];

        my $foundHeader = 0;
        for (my $lineIndex = 0; $lineIndex < scalar @$sheet; $lineIndex++)
        {
            $linenum = $lineIndex + 1;
            my $line = $sheet->[$lineIndex];


            if (! $foundHeader)
            {
                if ('DAY OF DOWNLOAD' eq $line->[$offsets->{date}])
                {
                    $foundHeader = 1;
                }
                next;
            }
            

            my $country = uc($line->[$offsets->{country_code}]);
            my $currencyCode = uc($line->[$offsets->{currency_code}]);

            my $productType;
            my $format;
            my $mediaType;

            my $mapping = $gProductTypeMap{ lc($line->[$offsets->{type}]) };
            if ($mapping)
            {
                $productType = $mapping->{productType};
                $format = $mapping->{formatType};
                $mediaType = $mapping->{mediaType};
            }

            my $trackTitle;
            my $albumTitle;

            if (RPS::File::Sale::TYPE_TRACK eq $productType)
            {
                $trackTitle = $line->[$offsets->{title}];
            }
            elsif (RPS::File::Sale::TYPE_ALBUM eq $productType)
            {
                $albumTitle = $line->[$offsets->{title}];
            }

            my $upc                 = $line->[$offsets->{upc}];
            my $isrc                = $line->[$offsets->{isrc}];
            my $artist              = $line->[$offsets->{artist}];
            my $serviceProductID    = $line->[$offsets->{service_id}];
            my $units               = $line->[$offsets->{units}];
            my $netPrice            = $line->[$offsets->{net_price}];
            my $label               = $line->[$offsets->{label}];


            # Probably wise to allow for blank lines...
            #
            if ($units && $artist && ($albumTitle || $trackTitle))
            {
                my ($dateBegin, $dateEnd) = $self->_getDates(date_begin => $line->[$offsets->{date}], type => 'eur');

                my $unitPrice = $netPrice / $units;

                my $sale = RPS::Import::SaleRec->new();

                $sale->mediaType($mediaType);
                $sale->productType($productType);
                $sale->formatType($format);
                $sale->dateBegin($dateBegin);
                $sale->dateEnd($dateEnd);
                $sale->labelName($label);
                $sale->trackName($trackTitle);
                $sale->albumName($albumTitle);
                $sale->artistName($artist);
                $sale->serviceProductID($serviceProductID);
                $sale->upc($upc);
                $sale->isrc($isrc);
                $sale->units($units);
                $sale->price($unitPrice);
                $sale->countryCode($country);
                $sale->currencyCode($currencyCode);
                $sale->lineNum($linenum);

                $self->_insertSale(sale => $sale);
            } 
        }
    }

	return $linenum;
}



###
1;# Play nicely.
###