package RPS::Import::Ampd;

use strict;


use Date::Calc qw(Days_in_Month);

use lib '/app/tools/common/lib';
use Common::Util qw(normalize_upc normalize_isrc);

use lib '/app/tools/data_classes/lib';

use lib '/app/tools/rps/lib';
use RPS::Import::Importer;
use RPS::File::Sale;
use base 'RPS::Import::Importer';

my %field_map = (
    1 => {
        track     => 0,
        artist    => 1,
        isrc      => 2,
        retail    => 3,
        units     => 4,
        price     => 5,
        date_row  => 2,
        date_col  => 1,
    },
    2 => {
        track     => 0,
        artist    => 1,
        isrc      => 2,
        units     => 3,
        retail    => 4,
        price     => 5,
        date_row  => 2,
        date_col  => 1,
    },
    3 => {
        track     => 0,
        artist    => 1,
        isrc      => 2,
        retail    => 3,
        price     => 4,
        units     => 5,
        date_row  => 2,
        date_col  => 1,
    },
    4 => {
        track     => 0,
        artist    => 1,
        isrc      => 2,
        units     => 3,
        retail    => 4,
        price     => 5,
        date_row  => 2,
        date_col  => 2,
    },
);

# public methods

sub _importLines
{
    my $self = shift;
    my %args = @_;

    my $fileObj = $args{file};
    my $version = $fileObj->VersionNum;
    ##my $version = $args{version}; # for cmd-line testing
    my $offsets = $field_map{$version};

    my $lines = $args{sheets}->[1];
    return 0 unless ($lines);

    my ($dateBegin, $dateEnd) = _getDates($lines->[$offsets->{date_row}][$offsets->{date_col}]);
    unless ($dateBegin && $dateEnd) {
        $self->errstr("couldn't get dates");
        print STDERR "date: ".$lines->[$offsets->{date_row}][$offsets->{date_col}]."\n";
        return undef;
    }

    my $linenum = 1;
    my $prodtype = RPS::File::Sale::TYPE_TRACK;
    my $format = RPS::File::Sale::FORMAT_DUALDOWNLOAD;
    my $priceType = '';

    # !!! This doesn't seem like the right constant to use.
    # Shouldn't we use Client::Client::kWMG ?
    #
    if ($self->{clientID} == RPS::Import::Importer::WMG) # warner
    {
        my $fmt = 'dual download';
        # check for warner specific stuff
        require RPS::Import::WMG::Util;

        my @billTo = RPS::Import::WMG::Util::getWirelessBillto($self->{fileServiceID});
        if ($billTo[0])
        {
            unless (RPS::Import::WMG::Util::getWirelessSellto($self->{fileServiceID}, $billTo[0]))
            {
                $self->warning();
                print STDERR "unknown sellto mapping: $billTo[0]\n";
            }
        }
        else
        {
            $self->warning();
            print STDERR "unknown billto mapping: $self->{fileServiceID}\n";
        }

        unless ($priceType = RPS::Import::WMG::Util::getWirelessPriceType($fmt))
        {
            $self->warning();
            print STDERR "unknown format mapping: $fmt\n";
        }

        $fileObj->Atomic(1);
        $fileObj->Save();
    }

    foreach my $line(@$lines)
    {
        my $isrc           = normalize_isrc($line->[$offsets->{isrc}]);
        my $artist         = $line->[$offsets->{artist}];
        my $track          = $line->[$offsets->{track}];
        my ($units)        = $line->[$offsets->{units}] =~ /^(\d+)$/;
        my ($retail)         = $line->[$offsets->{retail}];
        my ($price)          = $line->[$offsets->{price}];
        my $ppdRate = (defined $retail && $retail != 0)?($price / $retail):'';

        if ($units && $retail && ($artist || $track)) {
            my $sale = RPS::Import::SaleRec->new();

            $sale->productType($prodtype);
            $sale->formatType($format);
            $sale->dateBegin($dateBegin);
            $sale->dateEnd($dateEnd);
            $sale->isrc($isrc);
            $sale->artistName($artist);
            $sale->trackName($track);
            $sale->units($units);
            $sale->price($price);
            $sale->retail($retail);
            $sale->lineNum($linenum);
            $sale->priceType($priceType);
            $sale->wholesaleRate($ppdRate);

            #$args{dumper}($sale);  ## for cmd-line testing
            $self->_insertSale(sale => $sale);
        }# else { print STDERR "skip: u: $units r: $retail a: $artist t: $track ($linenum)\n"; }
        $linenum++;
    }
    return $linenum;
}

#
# Private methods
#

sub _getDates {
    my $date = shift;

    if ($date =~ m/^(\d\d\d\d)-(\d\d)-\d\d$/) {
        return (
            sprintf("%d-%02d-01", $1, $2),
            sprintf("%d-%02d-%d", $1, $2, Days_in_Month($1, $2))
        );
    }

    return undef;
}

###
1;# Play nicely.
###