package RPS::Import::Boost;

use strict;


use Date::Calc qw(Decode_Month Days_in_Month);

use lib '/app/tools/common/lib';
use Common::Util qw(normalize_upc normalize_isrc);
use Common::Consts;

use lib '/app/tools/data_classes/lib';

use lib '/app/tools/rps/lib';
use RPS::File::Sale;
use RPS::Import::Importer;
use base 'RPS::Import::Importer';

my %field_map = (
    1 => {
        sheet       => 0,
        format      => 1,
        vendor_id   => 3,
        artist      => 4,
        upc         => 5,
        isrc        => 6,
        track       => 14,
        trans_type  => 15,
        units       => 16,
        retail      => 19,
        price       => 20,
    },
);
# version 2 has same mapping, but on a different sheet
$field_map{2} = { %{ $field_map{1} } };
$field_map{2}->{sheet} = 2;

#public methods

sub _importLines
{
    my $self = shift;
    my %args = @_;

    my $fileObj = $args{file};
    my $version = $fileObj->VersionNum;
    my $fileName = $fileObj->OrigFileName;
    # for cmd-line testing
    #my $version = $args{version};
    #my $fileName = $args{OrigFileName};

    my $priceType = '';
    if ($self->{clientID} == RPS::Import::Importer::WMG) # warner
    {
        # check for warner specific stuff
        require RPS::Import::WMG::Util;

        my @billTo = RPS::Import::WMG::Util::getWirelessBillto($self->{fileServiceID});
        if ($billTo[0])
        {
            unless (RPS::Import::WMG::Util::getWirelessSellto($self->{fileServiceID}, $billTo[0]))
            {
                $self->warning();
                print STDERR "unknown sellto mapping: $billTo[0]\n";
            }
        }
        else
        {
            $self->warning();
            print STDERR "unknown billto mapping: $self->{fileServiceID}\n";
        }

        $fileObj->Atomic(1);
        $fileObj->Save();
    }

    my $offsets = $field_map{$version};
    my $lines = $args{sheets}->[$offsets->{sheet}];

    return 0 unless ($lines);

    my ($dateBegin, $dateEnd) = $self->_getDates($fileName);
    unless ($dateBegin && $dateEnd)
    {
        $self->errstr("couldn't get dates");
        print STDERR "fileName: $fileName\n";
        return undef;
    }

    my %errors = ();
    my $linenum = 1;  ## starting off after header

    foreach my $line(@$lines)
    {
        my $prodtype = RPS::File::Sale::TYPE_TRACK;
        my $priceType = '';
        my $format =
            $line->[$offsets->{format}] =~ /ringtone/i ? RPS::File::Sale::FORMAT_RINGTONE : # was FORMAT_MASTERTONE (FB1324)
            '';
        unless ($format)
        {
            #print STDERR "unknown format: $line->[$offsets->{format}] ($linenum)\n";
            $linenum++;
            next;
        }

        my $vendorID    = $line->[$offsets->{vendor_id}];
        my $artist      = $line->[$offsets->{artist}];
        my $upc         = normalize_upc($line->[$offsets->{upc}]);
        $upc            = '' unless ($upc =~ /\d+/);
        my $isrc        = normalize_isrc($line->[$offsets->{isrc}]);
        my $track       = $line->[$offsets->{track}];
        my ($units)     = $line->[$offsets->{units}] =~ /^(\d+)$/;
        my $price       = $line->[$offsets->{price}];
        my $retail      = $line->[$offsets->{retail}];
        my $transType   = lc($line->[$offsets->{trans_type}]);

        if ($transType  ne 'purchase')
        {
            $price = abs($price);
            $retail = abs($retail);
            $units *= -1 unless ($units < 0);
        }

        if ($units && $price && $artist && $track) {
            my $wholesaleRate = $retail ? $price / $retail : '';
            my $sale = RPS::Import::SaleRec->new();

            if ($self->{clientID} == RPS::Import::Importer::WMG) # warner
            {
                my $fmt = $line->[$offsets->{format}];
                unless ($priceType = RPS::Import::WMG::Util::getWirelessPriceType($fmt))
                {
                    $self->warning();
                    print STDERR "unknown format mapping: $fmt ($linenum)\n" unless ($errors{$fmt});
                    $errors{$fmt} = 1;
                }
            }

            $sale->productType($prodtype);
            $sale->formatType($format);
            $sale->dateBegin($dateBegin);
            $sale->dateEnd($dateEnd);
            $sale->serviceProductID($vendorID);
            $sale->upc($upc);
            $sale->isrc($isrc);
            $sale->artistName($artist);
            $sale->trackName($track);
            $sale->units($units);
            $sale->price($price);
            $sale->wholesaleRate($wholesaleRate);
            $sale->retail($retail);
            $sale->lineNum($linenum);
            $sale->priceType($priceType);

            #$args{dumper}($sale);  ## for cmd-line testing
            $self->_insertSale(sale => $sale);
        } #else { print STDERR "skip: u: $units p: $price a: $artist t: $track ($linenum)\n"; }
        $linenum++;
    }

    $self->warning() if (keys %errors);

    return $linenum;
}

#
# Private methods
#

sub _getDates {
    my $self = shift;
    my $fileName = shift;
    $fileName =~ /Boost.(\w+).(\d\d)/;
    my $year = 2000 + $2;
    my $month = Decode_Month($1);
    return unless ($month);

    return (
        sprintf("%d-%02d-01", $year, $month),
        sprintf("%d-%02d-%d", $year, $month, Days_in_Month($year, $month))
    );
}


###
1;# Play nicely.
###