#---------------------------------------------------------------
# ____                   _ _         ____  _
#|  _ \ ___  _   _  __ _| | |_ _   _/ ___|| |__   __ _ _ __ ___
#| |_) / _ \| | | |/ _` | | __| | | \___ \| '_ \ / _` | '__/ _ \
#|  _ < (_) | |_| | (_| | | |_| |_| |___) | | | | (_| | | |  __/
#|_| \_\___/ \__, |\__,_|_|\__|\__, |____/|_| |_|\__,_|_|  \___|
#            |___/             |___/
#
# Copyright (C) 2013 RoyaltyShare, Inc.   All Rights Reserved
#---------------------------------------------------------------

package RPS::Import::CDBaby::v1;

use strict;

use Date::Calc qw(Days_in_Month Decode_Month);
use Spreadsheet::ParseExcel;

use lib '/app/tools/common/lib';
use Common::Assert;

use lib '/app/tools/rps/lib';
use RPS::Import::ServiceMap;

use base 'RPS::Import::MapFaceBase';
use base 'RPS::Import::Importer';


sub _fieldMap {
    {
        dateBegin        => 'B',
        serviceID        => 'L',
        countryCode      => 'N',
        formatType       => 'M',
        artistName       => 'J',
        upc              => 'G',
        albumName        => 'I',
        serviceProductID => 'H',
        isrc             => 'F',
        trackName        => 'K',
        units            => 'C',
        price            => 'E',
    }
}

sub _headerIdentifier { ( upc => 'Barcode' ) }

sub currencyCode { 'USD' }

sub productType {
    my $self = shift;
    my $isrc = $self->_getByFieldName('isrc');
    return $isrc ?  RPS::File::Sale::TYPE_TRACK : RPS::File::Sale::TYPE_ALBUM;
}

sub mediaType { RPS::DB::Item::MediaType::kMediaTypeAudio }

sub saleDates {
    my $self = shift;

    my $startDate = $self->_getByFieldName('dateBegin');

    $startDate = Spreadsheet::ParseExcel::Utility::ExcelFmt( "yyyy-mm-dd", $startDate ) if( $startDate =~ /^\d{5}$/ );

    return $self->_getDates( date_begin => $startDate );
}

sub formatType {
    my $self = shift;
    my $fmt = $self->_getByFieldName('formatType');
    if( $fmt =~ /^stream$/i )
    {
        return RPS::File::Sale::FORMAT_STREAM;
    }
    elsif( $fmt =~ /^download$/i )
    {
        return RPS::File::Sale::FORMAT_DOWNLOAD;
    }

    return $self->handleError("Unknown format: $fmt", RPS::DB::Item::SaleImportError::kErrorFormatType);
}

sub serviceID {
    my $self = shift;
    my $service   = $self->_getByFieldName('serviceID');
    my $serviceID = $self->getServiceID(lc ($service)) || $RPS::Import::ServiceMap::SERVICE_ALIASES{ lc $service };

    return $serviceID if ($serviceID);

    return $self->handleError("Unknown service: $service", RPS::DB::Item::SaleImportError::kErrorService);
}

sub countryCode {
    my $self = shift;
    my $name = $self->_getByFieldName('countryCode');
    
    if ($name)
    {
        my $o = Common::Country->Get( $name );
        if( $o )
        {
            return $o->alpha2;
        }
    }
    else
    {
        return 'US';
    }

    return $self->handleError("Unknown country: $name", RPS::DB::Item::SaleImportError::kErrorCountry);
}

sub units {
    my $self = shift;

    my $units = $self->SUPER::units();
    my $price = $self->SUPER::price();

    if ($price < 0 && $units > 0)
    {
        $units = -$units;
    }

    return $units;
}

sub free {
    my $self = shift;
    my $units = $self->_getByFieldName('units');
    my $price = $self->_getByFieldName('price');

    return 1 if( $units > 0 && 0 == $price );
}

## MapFace Stuff

sub _mapFaceServiceID {
	return ('serviceID');
}

sub _mapFaceCountryCode {
	return ('serviceID', 'countryCode');
}

sub _mapFaceProductType {
    return ('productType');
}

sub _mapFaceFormatType {
	return ('formatType');
}

sub _mapFaceMediaType {
    return ('mediaType');
}


###
1;# Play nicely.
###