#---------------------------------------------------------------
# ____                   _ _         ____  _
#|  _ \ ___  _   _  __ _| | |_ _   _/ ___|| |__   __ _ _ __ ___
#| |_) / _ \| | | |/ _` | | __| | | \___ \| '_ \ / _` | '__/ _ \
#|  _ < (_) | |_| | (_| | | |_| |_| |___) | | | | (_| | | |  __/
#|_| \_\___/ \__, |\__,_|_|\__|\__, |____/|_| |_|\__,_|_|  \___|
#            |___/             |___/
#
# Copyright (C) 2013 RoyaltyShare, Inc.   All Rights Reserved
#---------------------------------------------------------------

package RPS::Import::Caroline::v7;

use strict;

use Date::Calc qw(Days_in_Month Decode_Month);

use lib '/app/tools/common/lib';
use Common::Assert;

use lib '/app/tools/rps/lib';
use RPS::Import::ServiceMap;

use base 'RPS::Import::Importer';

sub _fieldMap {
    {
        # header
        currencyCode     => 'Q',

        # detail
        upc              => 'G',
        artistName       => 'F',
        albumName        => 'H',
        totalRevenue     => 'Q',
    }
}

sub _unverifiedFieldMap {
    {
        calYear          => 'B',
        calMonth         => 'C',
        netQuantity      => 'T',
        netSales         => 'Q',
    }
}

sub _headerIdentifier { ( upc => 'CPRS new UPC code' ) }

sub countryCode {
    my $self = shift;
    $self->{_countryCode}; # From filename -- see _preProcess()
}

sub currencyCode {
    my $self = shift;
    $self->{_currencyCode}; # From header -- see _processSheet()
}

sub physical { 1 }

sub channel { RPS::File::Sale::CHANNEL_RETAIL }

sub priceLevel { RPS::File::Sale::PLEVEL_UNKNOWN }

sub productType { RPS::File::Sale::TYPE_CD }

sub saleDates {
    my $self  = shift;
    my $year  = $self->_getByFieldName('calYear');
    my $month = $self->_getByFieldName('calMonth');
    my $dateBegin = sprintf("%04d-%02d-%02d", $year, $month, 1);
    my $dateEnd   = sprintf("%04d-%02d-%02d", $year, $month, Days_in_Month($year, $month) );
    return ($dateBegin, $dateEnd);
}

sub sales {
    my $self = shift;
    my $sales   = $self->_getByFieldName('netQuantity');
    my $revenue  = $self->_getByFieldName('netSales');
    return ($sales >= 0 && $revenue > 0 ) ? $sales : 0;
}

sub salesRevenue {
    my $self = shift;
    my $revenue  = $self->_getByFieldName('netSales');
    return ($revenue >= 0 ) ? $revenue : 0;
}

sub returns {
    my $self = shift;
    my $sales   = $self->_getByFieldName('netQuantity');
    my $revenue  = $self->_getByFieldName('netSales');
    return ($revenue < 0 ) ? abs($sales) : 0; # Follow the sign of the revenue
}

sub returnsRevenue {
    my $self = shift;
    my $revenue  = $self->_getByFieldName('netSales');
    return ($revenue < 0) ? abs($revenue) : 0;
}

sub free {
    my $self = shift;
    my $totalRevenue  = $self->_getByFieldName('netSales');
    my $sales   = $self->_getByFieldName('netQuantity');
    return 1 if( $totalRevenue == 0 && $sales != 0 );
}

sub _preProcess {
    my $self = shift;
    my %args = @_;
    $self->SUPER::_preProcess( %args );

    $self->{_countryCode} = 'CA' if( $self->filename =~ /[_ ]CA[_ ]/i );
}

sub _processSheet {
    my $self     = shift;
    my $sheet    = shift;
    my $sheetnum = shift;

    if( $self->{sheetname} =~ /physical/i )
    {
        my $foundHeader;
        foreach my $line (@$sheet)
        {
            $self->{line} = $line;

            my $cheader = $self->_getByFieldName('currencyCode');

            if( !$foundHeader )
            {
                $foundHeader = 1 if( $cheader =~ /^Net Sales$/i );
            }
            else
            {
                $self->{_currencyCode} = $cheader;
                last;
            }
        }

        return $self->SUPER::_processSheet( $sheet, $sheetnum );
    }
}

sub _isValidSaleRecord {
    my $self = shift;

    # The line is valid if it has sales or returns, and has an album title
    #
    return ( ($self->sales != 0 || $self->returns != 0) && $self->albumName );
}

###
1;# Play nicely.
###