package RPS::Import::DestraMusic;

use strict;
use warnings;

use Date::Calc qw(Decode_Month Days_in_Month);

use lib '/app/tools/common/lib';
use Common::Util;
use Common::Consts;

use lib '/app/tools/data_classes/lib';

use lib '/app/tools/rps/lib';
use RPS::File::Sale;
use RPS::Import::Importer;
use base 'RPS::Import::Importer';

use constant FIELD_SERVICE   => 0;
use constant FIELD_COUNTRY   => 2;
use constant FIELD_UPC       => 3;
use constant FIELD_ISRC      => 4;
use constant FIELD_ARTIST    => 5;
use constant FIELD_TRACK     => 6;
use constant FIELD_ALBUM     => 7;
use constant FIELD_UNITS     => 8;
use constant FIELD_PRODUCTID => 12;
use constant FIELD_PRICE     => 17;
use constant FIELD_CURRENCY  => 18;
use constant FIELD_LABEL     => 28;

my %service_map = (
    'ChannelGo'   => Client::Service::DSP_CHANNELGO,
    'JbHifiMusic' => Client::Service::DSP_JBHIFIMUSIC,
);


sub _importLines {
    my $self = shift;
    my %args = @_;

    my $fileObj  = $args{file};
    my $filename = $fileObj->OrigFileName;
    ##my $filename = $args{OrigFileName};     ## for cmd-line testing

    my $lines  = $args{lines};
    return undef unless ($lines);

    my ($dateBegin, $dateEnd) = $self->_getDates($filename);
    unless ($dateBegin && $dateEnd) {
        $self->errstr("couldn't get dates from $filename");
        return undef;
    }

    shift @$lines;
    my $linenum = 2;

    foreach my $line (@$lines) {

        next unless $line->[FIELD_SERVICE];

        my $service    = $line->[FIELD_SERVICE];
        my $upc        = $line->[FIELD_UPC];
        my $isrc       = $line->[FIELD_ISRC];
        my $productid  = $line->[FIELD_PRODUCTID];
        my $artist     = $line->[FIELD_ARTIST];
        my $track      = $line->[FIELD_TRACK];
        my $album      = $line->[FIELD_ALBUM];
        my $label      = $line->[FIELD_LABEL];
        my $country    = $line->[FIELD_COUNTRY];
        my $currency   = $line->[FIELD_CURRENCY];
        my ($units)    = $line->[FIELD_UNITS] =~ m/^(\d+)$/;
        my ($price)    = $line->[FIELD_PRICE] =~ m/^(\d+(\.\d+)?)$/;


        my $format = RPS::File::Sale::FORMAT_DOWNLOAD;

        if (exists $service_map{$service}) {
            $service = $service_map{$service};
        } else {
            $self->errstr("unknown service '$service'");
            return undef;
        }

        my $prodtype;
        if ($album && !$track) {
            $prodtype = RPS::File::Sale::TYPE_ALBUM;
        } else {
            $prodtype = RPS::File::Sale::TYPE_TRACK;
        }

        if ($price && $units && $artist && ($track || $album)) {
            my $sale = RPS::Import::SaleRec->new();

            $sale->productType($prodtype);
            $sale->formatType($format);
            $sale->serviceID($service);
            $sale->serviceProductID($productid);
            $sale->artistName($artist);
            $sale->trackName($track);
            $sale->albumName($album);
            $sale->isrc($isrc);
            $sale->upc($upc);
            $sale->labelName($label);
            $sale->dateBegin($dateBegin);
            $sale->dateEnd($dateEnd);
            $sale->price($price);
            $sale->units($units);
            $sale->countryCode($country);
            $sale->currencyCode($currency);
            $sale->lineNum($linenum);

            $self->_insertSale(sale => $sale);
            ##$args{dumper}($sale);           ## for cmd-line testing
        }
        $linenum++;
    }

    return $linenum;
}

#
# Private methods
#

sub _getDates {
    my $self  = shift;
    my $fname = shift;

    if ($fname =~ m/\d\d?(\w{3})(\d{4})_\d\d?\w{3}\d{4}/) {
        my $month = Decode_Month($1);
        my $year  = $2;
        my $dateBegin = sprintf("%d-%02d-01", $year, $month);
        my $dateEnd   = sprintf("%d-%02d-%02d", $year, $month, Days_in_Month($year, $month));
        return ($dateBegin, $dateEnd);
    }

    return undef;
}

###
1;# Play nicely.
###