package RPS::Import::GoogleMusic::v10;

use strict;

use lib '/app/tools/rps/lib';
use RPS::File::Sale;
use base 'RPS::Import::Importer';

sub _fieldMap {
    {
        # header
        price       =>  'J2',
        currencyCode => 'C2',

        # detail
        dateBegin   =>  'A',
        dateEnd     =>  'B',
        countryCode =>  'P',
        upc         =>  'C',
        isrc        =>  'E',
        artistName  =>  'K',
        trackName   =>  'L',
        albumName   =>  'M',
        labelName   =>  'O',
        formatType  =>  'S',
        units       =>  'T',
    }
}

sub _headerIdentifier { ( upc => 'UPC' ) }

sub productType { RPS::File::Sale::TYPE_TRACK }

sub formatType {
    my $self = shift;
    my $type  = $self->_getByFieldName('formatType');
    if( $type =~ /^play$/i )
    {
        return RPS::File::Sale::FORMAT_STREAM;
    }
    $self->errstr("Unable to get format from '$type'");
}

sub mediaType { RPS::DB::Item::MediaType::kMediaTypeAudio }

sub currencyCode {
    my $self = shift;
    $self->{_currencyCode} = $self->_getByFieldName('currencyCode') if( !defined $self->{_currencyCode} );
    return $self->{_currencyCode};
}

sub price {
    my $self = shift;
    my $units  = $self->_getByFieldName('units');

    return $self->{_price} * $units;  # see _preProcess
}

sub saleDates {
    my $self = shift;
    my $sdate  = $self->_getByFieldName('dateBegin');
    my $edate  = $self->_getByFieldName('dateEnd');
    return $self->_getDates( date_begin => $sdate, date_end => $edate );
}

sub _preProcess {
    my $self = shift;
    my %args = @_;

    Log->info( "Starting _preProcess" );
    $self->SUPER::_preProcess(%args);


    my $revenue;
    my $currencyCode;

    my $totalUnits=0;

    foreach my $line(@{ $args{lines} })
    {
        $self->{line} = $line;

        if( !defined $revenue )
        {
            $revenue = $self->_getByFieldName('price');
            $revenue =~ s/,//;
        }

        my $_units = $self->_getByFieldName('units');

        $totalUnits += $_units if( $_units );
    }

    $self->{_price} = $revenue / $totalUnits; # unit price

}

###
1;# Play nicely.
###