package RPS::Import::InfoSpace;

use strict;

use Date::Calc qw(Days_in_Month Decode_Month);

use lib '/app/tools/data_classes/lib';

use lib '/app/tools/rps/lib';
use RPS::File::Sale;
use RPS::Import::Importer;
use base 'RPS::Import::Importer';

use constant DATE_ROW       => 23;
use constant DATE_COL       => 2;

use constant FIELD_SERVICE  => 0;
use constant FIELD_ISRC     => 1;
use constant FIELD_TRACK    => 2;
use constant FIELD_ARTIST   => 3;
use constant FIELD_UNITS    => 4;
use constant FIELD_RETAIL   => 5;
use constant FIELD_PRICE    => 6;
use constant FIELD_FORMAT   => 8;

sub _importLines
{
    my $self = shift;
    my %args = @_;

    my $lines = $args{lines};
    my $sheets = $args{sheets};
    my $fileObj = $args{file};
    my $fileName = $fileObj->OrigFileName;
    #my $fileName = $args{OrigFileName}; # for cmd-line testing
    return 0 unless $lines;

    my ($dateBegin, $dateEnd) = $self->_getDates($lines->[DATE_ROW][DATE_COL]);

    unless ($dateBegin && $dateEnd)
    {
        $self->errstr("couldn't get dates");
        print STDERR "date: $lines->[DATE_ROW][DATE_COL]\n";
        return 0;
    }

    # only used for WMG
    my $priceType = '';

    if ($self->is_wmg) # warner
    {
        $priceType = 'Standard/Bundle'; # intentionally hard-coded
        # check for warner specific stuff
        require RPS::Import::WMG::Util;

        my ($billTo, $sellTo) = RPS::Import::WMG::Util::getWirelessInfo($self->{fileServiceID});
        unless ($billTo && $sellTo)
        {
            $self->warning();
            print STDERR "unknown billto/sellto mapping: $self->{fileServiceID}\n";
        }

        $fileObj->Atomic(1);
        $fileObj->Save();
    }

    my $prodType = RPS::File::Sale::TYPE_TRACK;

    my %errors = ();
    my $linenum = 1;

    foreach my $line(@$lines)
    {
        my $artist  = $line->[FIELD_ARTIST];
        my $track   = $line->[FIELD_TRACK];
        my $isrc    = $line->[FIELD_ISRC];
        my ($units) = $line->[FIELD_UNITS] =~ /^(\d+)$/;
        my $price   = $line->[FIELD_PRICE];
        my $retail  = $line->[FIELD_RETAIL];

        if ($units && $artist && $track)
        {
            my ($formatType, $wholesaleRate);
            if ($self->is_wmg())
            {
                my $fmt = $line->[FIELD_FORMAT];
                unless ($formatType = RPS::Import::WMG::Util::getWirelessFormatTypeID($fmt))
                {
                    unless ($errors{$fmt})
                    {
                        $self->warning();
                        print STDERR "unknown format: $fmt\n";
                        $errors{$fmt} = 1;
                    }
                    $linenum++;
                    next;
                }

                $wholesaleRate = $retail > 0 ? $price / $retail : undef;
            }
            else # all other clients default to ringtone
            {
                $formatType = RPS::File::Sale::FORMAT_RINGTONE;
            }

            my $sale = RPS::Import::SaleRec->new();

            $sale->productType($prodType);
            $sale->formatType($formatType);
            $sale->dateBegin($dateBegin);
            $sale->dateEnd($dateEnd);
            $sale->isrc($isrc);
            $sale->artistName($artist);
            $sale->trackName($track);
            $sale->units($units);
            $sale->price($price);
            $sale->wholesaleRate($wholesaleRate);
            $sale->retail($retail);
            $sale->priceType($priceType);
            $sale->lineNum($linenum);

            #$args{dumper}($sale); # for cmd-line testing
            $self->_insertSale(sale => $sale);
        }#else { print STDERR "skip: u: $units r: $artist t: $track ($linenum)\n" }
        $linenum++;
    }

    return $linenum;
}

#
# Private methods
#

sub _getDates
{
    my $self = shift;
    my $dateCell = shift; # Royalty Statement For Quarter Ending: September 2006

    $dateCell =~ m/ending:\s*(\w+)\W*(\d{4})/i;
    my ($month, $year) = ($1, $2);
    $month =~ s/_//g;
    $month = Decode_Month($month);
    return unless ($month && $year);

    return (
        sprintf("%d-%02d-01", $year, $month-2),
        sprintf("%d-%02d-%02d", $year, $month, Days_in_Month($year, $month))
    );
}

###
1;# Play nicely.
###