#---------------------------------------------------------------
# ____                   _ _         ____  _
#|  _ \ ___  _   _  __ _| | |_ _   _/ ___|| |__   __ _ _ __ ___
#| |_) / _ \| | | |/ _` | | __| | | \___ \| '_ \ / _` | '__/ _ \
#|  _ < (_) | |_| | (_| | | |_| |_| |___) | | | | (_| | | |  __/
#|_| \_\___/ \__, |\__,_|_|\__|\__, |____/|_| |_|\__,_|_|  \___|
#            |___/             |___/
#
# Copyright (C) 2014 RoyaltyShare, Inc.   All Rights Reserved
#---------------------------------------------------------------

package RPS::Import::Juke;

use strict;

use lib '/app/tools/common/lib';
use Common::Assert;

use lib '/app/tools/rps/lib';
use RPS::Import::ServiceMap;

use base 'RPS::Import::Importer';

sub _fieldMap {
    my $self = shift;
    my $version = $self->_version;
    my %fieldmap = (
        1 => {
            labelName     => 'H',
            serviceID     => 'D',
            countryCode   => 'G',
            dateBegin     => 'B',
            dateEnd       => 'C',
            productType   => 'M',
            formatType    => 'E',
            serviceProductID => 'A',
            artistName    => 'I',
            upc           => 'L',
            isrc          => 'K',
            trackName     => 'J',
            units         => 'N',
        },
        2 => {
            labelName     => 'H',
            serviceID     => 'D',
            countryCode   => 'G',
            dateBegin     => 'B',
            dateEnd       => 'C',
            productType   => 'M',
            formatType    => 'E',
            serviceProductID => 'A',
            artistName    => 'I',
            upc           => 'L',
            isrc          => 'K',
            trackName     => 'J',
            units         => 'N',
            price         => 'O',
            currencyCode  => 'P',
        },
    );
    return $fieldmap{$version};
}


sub _headerIdentifier { ( labelName => 'Label Name' ) }


sub currencyCode {
    my $self = shift;
    if( exists $self->_fieldMap->{'currencyCode'} )
    {
        return $self->_getByFieldName('currencyCode');
    }
    return 'EUR';
}

sub price {
    my $self = shift;
    if( exists $self->_fieldMap->{'price'} )
    {
        my $p = $self->_getByFieldName('price');
        $p =~ s/,/./;
        return $p;
    }
}


sub mediaType { RPS::DB::Item::MediaType::kMediaTypeAudio; }


sub saleDates {
    my $self = shift;
    my $dateBegin = $self->_getByFieldName('dateBegin');
    my $dateEnd = $self->_getByFieldName('dateEnd');
    return $self->_getDates(date_begin => $dateBegin, date_end => $dateEnd);
}


sub serviceID {
    my $self = shift;
    my $service = $self->_getByFieldName('serviceID');
    my $serviceID = $self->getServiceID(lc ($service)) || $RPS::Import::ServiceMap::SERVICE_ALIASES{ lc $service };
    return $serviceID if( $serviceID );
    $self->fail("Unknown service '$service'");
}


sub productType {
    my $self = shift;
    my $type = $self->_getByFieldName('productType');
    if ($type =~ /^track$/i)
    {
        return RPS::File::Sale::TYPE_TRACK;
    }
    $self->fail("Unknown product type '$type'");
}


sub formatType {
    my $self = shift;
    my $format = $self->_getByFieldName('formatType');
    if ($format =~ /^(ps|sb|ts|hb)$/i)
    {
        return RPS::File::Sale::FORMAT_STREAM;
    }
    else
    {
        $self->fail("Unable to determine format type from '$format'");
    }
}


sub countryCode {
    my $self  = shift;
    my $country = $self->_getByFieldName('countryCode');
    my $obj = Common::Country->Get($country);
    return $obj ? $obj->alpha2 : undef;
}

###
1;# Play nicely.
###