package RPS::Import::KochEntCanada;

use strict;


use Date::Calc qw(Days_in_Month Decode_Month);

use lib '/app/tools/common/lib';
use Common::Util;
use Common::Consts;

use lib '/app/tools/data_classes/lib';

use lib '/app/tools/rps/lib';
use RPS::File::Sale;
use RPS::Import::Importer;
use base 'RPS::Import::Importer';

use constant DATE_ROW => 2;
use constant DATE_COL => 2;

use constant SUMM_CODE   => 0;
use constant SUMM_FORMAT => 1;
use constant SUMM_PRICE  => 4;

use constant FIELD_CATNO   => 0;
use constant FIELD_TITLE   => 1;
use constant FIELD_SALES   => 2;
use constant FIELD_RETURNS => 3;

#public methods

sub _importLines
{
	my $self = shift;
	my %args = @_;

	my $retval = undef;
    my $sheets = $args{sheets};

    my $summary = $sheets->[0];
    my $prices;
    foreach my $line (@$summary) {
        my $code    = $line->[SUMM_CODE];
        my $format  = $line->[SUMM_FORMAT];
        my ($price) = $line->[SUMM_PRICE] =~ m/^(-?\d*\.?\d*)$/;
        if ($code && $format && $price) {
            $prices->{$code}->{$format} = $price;
        }
    }

    my $linenum;

    my ($dateBegin, $dateEnd) = $self->_getDates($summary->[DATE_ROW]->[DATE_COL]);
    
    unless ($dateBegin && $dateEnd) {
        $self->errstr("couldn't get dates from ".$summary->[DATE_ROW]->[DATE_COL]);
        print STDERR "couldn't get dates from ".$summary->[DATE_ROW]->[DATE_COL]."\n";
        return undef;
    }

    my $lines = $sheets->[1];

    $linenum = 1;
    my $code;
    foreach my $line (@$lines)
    {
        if ($line->[FIELD_CATNO] =~ m/^\s*Price Code\s*\:\s+(.+)\s*$/) {
            $code = $1;
            $linenum++;
        }
        my $prodtype    = RPS::File::Sale::TYPE_PHYSICAL;
        my $price_level = RPS::File::Sale::PLEVEL_FULL;
        my $channel     = RPS::File::Sale::CHANNEL_RETAIL;
        my $catno       = $line->[FIELD_CATNO];
        my $title       = $line->[FIELD_TITLE];

        my ($artist, $album);
        if ($title =~ m/^(.+)\s*\:\s+(.+)$/) {
            $artist = $1;
            $album  = $2;
        } else {
            $album = $title;
        }

        my ($sales)   	= $line->[FIELD_SALES] =~ m/^(-?\d+)$/;
        my ($returns)  	= $line->[FIELD_RETURNS] =~ m/^(-?\d+)$/;

        ## get price
        my $price;

        if ($catno =~ m/^[^\-]+\-([^\-]+)\-[^\-]+$/) {
            $price = $prices->{$code}->{$1};
        }

        my $sales_price   = $sales * $price;
        my $returns_price = $returns * $price;
        my $total_price   = $sales_price - $returns_price;

        if ($prodtype && ($sales || $returns) && $total_price && $album)
        {
            my $sale = RPS::Import::SaleRec->new();
 
            $sale->productType($prodtype);
            $sale->dateBegin($dateBegin);
            $sale->dateEnd($dateEnd);
            $sale->clientProductID($catno);
            $sale->albumName($album);
            $sale->artistName($artist);
            $sale->sales($sales);
            $sale->salesRevenue($sales_price);
            $sale->returns($returns);
            $sale->returnsRevenue($returns_price);
            $sale->totalRevenue($total_price);
            $sale->priceLevel($price_level);
            $sale->channel($channel);
            $sale->countryCode('CA');
            $sale->currencyCode('USD');
            $sale->lineNum($linenum);
 
            ##$args{dumper}($sale);  ## for cmd-line testing
            $self->_insertSale(sale => $sale);
        }
        $linenum++;
    }

	return $linenum;
}

#
# Private methods
#


sub _getDates
{
	my $self = shift;
	my $date = shift;

    if ($date =~ m/^Sales period \: from (\w+) (\d\d) *to *(\w+) (\d\d)$/) {
        my $month1 = Decode_Month($1);
        my $year1  = $2 + 2000;
        my $month2 = Decode_Month($3);
        my $year2  = $4 + 2000;
        my $dateBegin = sprintf("%04d-%02d-%02d", $year1, $month1, 1);
        my $dateEnd   = sprintf("%04d-%02d-%02d", $year2, $month2, Days_in_Month($year2, $month2));
        return ($dateBegin, $dateEnd);
    } else {
        return undef;
    }
}

###
1;# Play nicely.
###