package RPS::Import::Loudeye;

use strict;


use Date::Calc qw(Days_in_Month);

use lib '/app/tools/common/lib';
use Common::Util;
use Common::Consts;

use lib '/app/tools/data_classes/lib';

#private constants
use constant FIELD_UPC			=> 1;
use constant FIELD_ISRC			=> 2;
use constant FIELD_TRACKNUM		=> 4;
use constant FIELD_ARTIST		=> 5;
use constant FIELD_ALBUM		=> 6;
use constant FIELD_TRACK		=> 7;
use constant FIELD_PRODTYPE		=> 8;
use constant FIELD_UNITS		=> 9;
use constant FIELD_PRICE		=> 10;

use lib '/app/tools/rps/lib';
use RPS::File::Sale;
use RPS::Import::Importer;
use base 'RPS::Import::Importer';

#public methods

sub _importLines
{
	my $self = shift;
	my %args = @_;

	my $retval = undef;
	my $lines = $args{lines};
	my $fileObj = $args{file};
	my $fileName = $fileObj->OrigFileName;

	if ($lines && $fileName)
	{
		my ($dateBegin, $dateEnd) = $self->_getDates($fileName);

		if ($dateBegin && $dateEnd)
		{
			my $linenum = 1;
			foreach my $line(@$lines)
			{
				if ($linenum > 1)
				{
					my $prodtype;
					if ($line->[FIELD_PRODTYPE] =~ m/^track$/i)
					{
						$prodtype = RPS::File::Sale::TYPE_TRACK;
					}
					elsif ($line->[FIELD_PRODTYPE] =~ m/^album$/i)
					{
						$prodtype = RPS::File::Sale::TYPE_ALBUM;
					}

					my $format		= RPS::File::Sale::FORMAT_DOWNLOAD;
					my $isrc		= Common::Util::normalize_isrc($line->[FIELD_ISRC]);
					my $upc			= Common::Util::normalize_upc($line->[FIELD_UPC]);
					my $artist		= $line->[FIELD_ARTIST];
					my $album		= $line->[FIELD_ALBUM];
					my $track		= $line->[FIELD_TRACK];
					my ($trackNum)	= $line->[FIELD_TRACKNUM] =~ m/^(\d+)$/;
					my ($units)		= $line->[FIELD_UNITS] =~ m/^(-?\d+)$/;
					my ($price)		= $line->[FIELD_PRICE] =~ m/^(\d*\.\d*)$/;

					if ($units && $price && $artist && ($album || $track))
					{
						my $sale = RPS::Import::SaleRec->new();

						$sale->productType($prodtype);
						$sale->formatType($format);
						$sale->dateBegin($dateBegin);
						$sale->dateEnd($dateEnd);
						$sale->isrc($isrc);
						$sale->upc($upc);
						$sale->artistName($artist);
						$sale->albumName($album);
						$sale->trackName($track);
						$sale->trackNum($trackNum);
						$sale->units($units);
						$sale->price($price);
						$sale->lineNum($linenum);

						$self->_insertSale(sale => $sale);
					}
				}
				$linenum++;
			}
			$retval = $linenum;
		}
	}

	return $retval;
}

#
# Private methods
#

sub _getDates
{
	my $self = shift;
	my $fileName = shift;

	my $dateBegin;
	my $dateEnd;

	my ($month, $year) = $fileName =~ m/(\d\d?)-(20\d\d)/;

	if ($year && $month)
	{
		$dateBegin = sprintf("%04d-%02d-%02d", $year, $month, 1);
		$dateEnd = sprintf("%04d-%02d-%02d", $year, $month, Days_in_Month($year, $month));
	}

	return ($dateBegin, $dateEnd);
}

###
1;# Play nicely.
###