package RPS::Import::Merlin::v12;

use strict;

use lib '/app/tools/common/lib';
use Common::Date;
use Common::Country;

use lib '/app/tools/rps/lib';
use base 'RPS::Import::Importer';

use Data::Dumper;
use Date::Calc qw(Days_in_Month Decode_Month);

sub _headerIdentifier { ( upc => 'UPC' ) }

sub _fieldMap {
    {
        # header
        dateBegin        => 'C',
        dateEnd          => 'D',
        countryCode      => 'B',

        # detail
        labelName        => 'M',
        productType      => 'D',
        artistName       => 'I',
        upc              => 'G',
        albumName        => 'K',
        isrc             => 'H',
        trackName        => 'J',
        currencyCode     => 'S',
        price            => 'R',
    }
}

sub _unverifiedFieldMap {
    {
        # detail
        quantityPurchased => 'E',
        quantityReturned  => 'F',

        # footer
        distFee      => 'S',
    }
}

sub serviceID {
    my $self = shift;
    return $self->{_serviceID} if ( $self->{_serviceID} );

    # Note: We assume that the service name contains only alphanumeric
    # characters, without any underscores or punctuation.
    # E.g., "STATEMENT_${serviceName}_rest_of_filename.xls"
    #
    unless( $self->filename =~ /STATEMENT_([0-9a-zA-Z]+)_/ ) {
        $self->fail( "Could not determine service from filename '" . $self->filename . "'" );
    }

    my $serviceName = $1;
    my $_serviceID  = $self->getServiceID($serviceName);
    if( $_serviceID )
    {
        $self->{_serviceID} = $_serviceID;
        return $self->{_serviceID};
    }

    $self->fail( "Unknown service '$serviceName'" );
}

sub saleDates {
    my $self = shift;
    return ($self->{_startDate}, $self->{_endDate}) if( $self->{_startDate} ); # from header; see _preProcess
}

sub countryCode {
    my $self = shift;
    return $self->{_countryCode} if( $self->{_countryCode} ); # from header; see _preProcess
}

sub formatType { return RPS::File::Sale::FORMAT_DOWNLOAD; }

sub productType {
    my $self = shift;
    my $type = $self->_getByFieldName('productType');
    if( $type =~ /^t$/i )
    {
        return RPS::File::Sale::TYPE_TRACK;
    }
    elsif( $type =~ /^a$/i )
    {
        return RPS::File::Sale::TYPE_ALBUM;
    }

    $self->fail( "Unknown product type '$type'" );
}

sub mediaType { return RPS::DB::Item::MediaType::kMediaTypeAudio; }

sub units {
    my $self = shift;
    my $quantityPurchased = $self->_getByFieldName('quantityPurchased');
    my $quantityReturned  = $self->_getByFieldName('quantityReturned');
    return ($quantityPurchased - $quantityReturned);
}

sub price {
    my $self = shift;

    my $price = $self->_getByFieldName('price');
    
    $self->fail( "Unable to determine distribution fee" ) unless( $self->{_distFee} );
    
    my $distFee = $self->{_distFee};
    $distFee = (100 - $distFee) * .01;
    $price *= $distFee;

    return $price;
}

sub _preProcess {
    my $self = shift;
    my %args = @_;

    Log->info( "Starting _preProcess" );
    $self->SUPER::_preProcess(%args);

    my $distFee;

    my $getDateFlag;    # set if we find a date header
    my $getCountryFlag; # set if we find a country header

    foreach my $line(@{ $args{lines} }) {

        $self->{line} = $line;

        # Get the date from the header
        #
        if( !$getDateFlag && $self->_getByFieldName('dateBegin') =~ /start_date/i )
        {
            $getDateFlag = 1;
        }
        elsif( !$self->{_startDate} && $getDateFlag )
        {
            my $dt = $self->_getByFieldName('dateBegin');

            if( $dt =~/^(\d{4})-(\d{2})-(\d{2})$/ ) # YYYY-MM-DD
            {
                $self->{_startDate} = sprintf( "%04d-%02d-%02d", $1, $2, 1 );

                my $endDate = $self->_getByFieldName('dateEnd');
                my($y, $m, $d) = split("-", $endDate);
                $self->{_endDate}  = sprintf( "%04d-%02d-%02d", $y, $m, $d);
            }
            else
            {
                print STDERR "_preProcess: WARNING: Unable to decode date '$dt'\n";
                $self->errstr("Unable to decode date '$dt' in header");
                return undef;
            }
        }

        # Get the country from the header
        #
        if( !$getCountryFlag && $self->_getByFieldName('countryCode') =~ /reporting_region/i )
        {
            $getCountryFlag = 1;
        }
        elsif( !$self->{_countryCode} && $getCountryFlag )
        {
            my $countryName = $self->_getByFieldName('countryCode');
            my $o = Common::Country->Get( $countryName );
            if ( $o )
            {
                $self->{_countryCode} = $o->alpha2();
            }
            else
            {
                $self->errstr("Unknown country '$countryName' in header");
                return undef;
            }

        }

        # Get the distribution fee from the footer
        #
        $distFee = $self->_getByFieldName('distFee');

        if ($distFee =~ /LESS Merlin ADMIN FEE \((.+?)%\)/)
        {    
            $self->{_distFee} = $1;
            last;
        }
    }
}

###
1;# Play nicely.
###