#---------------------------------------------------------------
# ____                   _ _         ____  _
#|  _ \ ___  _   _  __ _| | |_ _   _/ ___|| |__   __ _ _ __ ___
#| |_) / _ \| | | |/ _` | | __| | | \___ \| '_ \ / _` | '__/ _ \
#|  _ < (_) | |_| | (_| | | |_| |_| |___) | | | | (_| | | |  __/
#|_| \_\___/ \__, |\__,_|_|\__|\__, |____/|_| |_|\__,_|_|  \___|
#            |___/             |___/
#
# Copyright (C) 2013 RoyaltyShare, Inc.   All Rights Reserved
#---------------------------------------------------------------

package RPS::Import::Merlin::v24;

use strict;

use Date::Calc qw(Days_in_Month Decode_Month);

use lib '/app/tools/common/lib';
use Common::Assert;

use lib '/app/tools/rps/lib';
use RPS::Import::ServiceMap;

use base 'RPS::Import::Importer';

sub _fieldMap {
    {
        labelName     => 'B',
        countryCode   => 'C',
        dateBegin     => 'G',
        dateEnd       => 'H',
        formatType    => 'F',
        artistName    => 'J',
        upc           => 'L',
        albumName     => 'N',
        isrc          => 'I',
        trackName     => 'K',
        units         => 'P',
        price         => 'S',
    }
}

sub _unverifiedFieldMap {
    {
        serviceName      => 'B',
    }
}

sub _headerIdentifier { ( labelName => 'Application' ) }

sub productType { RPS::File::Sale::TYPE_TRACK }
sub mediaType   { RPS::DB::Item::MediaType::kMediaTypeAudio }
sub formatType  { RPS::File::Sale::FORMAT_STREAM; }

sub saleDates {
    my $self = shift;
    my $sdate = $self->_getByFieldName('dateBegin');
    my $edate = $self->_getByFieldName('dateEnd');
    my $dateBegin;
    my $dateEnd;

    if( $self->{_hasEuroDates} )
    {
        ($dateBegin, $dateEnd) = $self->_getDates( date_begin => $sdate, date_end => $edate, type => 'eur' );
    }
    else
    {
        ($dateBegin, $dateEnd) = $self->_getDates( date_begin => $sdate, date_end => $edate );
    }

    return( $dateBegin, $dateEnd );
}

sub serviceID {
    my $self = shift;
    my $serviceName = $self->_getByFieldName('serviceName');
    my $serviceID = $self->getServiceID( $serviceName ) || 
                    $RPS::Import::ServiceMap::SERVICE_ALIASES{ lc $serviceName };

    return $serviceID if( $serviceID );

    $self->fail("Unknown service '$serviceName'");
}

sub units {
    my $self = shift;
    my $units = $self->_getByFieldName('units');
    my $price = $self->_getByFieldName('price');
    if (($price < 0 && $units > 0) || ($price > 0 && $units < 0)) {
        $units *= -1;
    }
    return $units;
}



sub currencyCode {
    my $self = shift;

    return $self->{_currencyCode} if( $self->{_currencyCode} );

    $self->fail("Unable to find currency code in header");
}


sub _isEuroDate
{
    my($self, $date) = @_;

    # Check for dates in the form DD-MM-YYYY.
    #
    # If a date has the form a/b/c, if the 'a' part is greater
    # than 13, then we assume that the date is DD/MM/YYYY.
    # Otherwise we assume the date is MM/DD/YYYY.
    #
    my($d, $m, $y);

    if ( $date =~ m/\d{1,2}-\d{1,2}-\d{4}/ ) # check for DD-MM-YYYY
    {
        ($d, $m, $y) = split("-", $date);
    }
    elsif ( $date =~ m/\d{1,2}\/\d{1,2}\/\d{4}/ ) # check for DD-MM-YYYY
    {
        ($d, $m, $y) = split("/", $date);
    }

    return 1 if ( $d > 13 );
}

sub _preProcess {
    my $self = shift;
    my %args = @_;

    Log->info( "Starting _preProcess" );
    $self->SUPER::_preProcess(%args);

    my $priceColumn;
    my $currencyCode;

    my $linenum = 0;

    foreach my $line(@{ $args{lines} })
    {
        $self->{line} = $line;

        if( !$currencyCode )
        {
            $priceColumn = $self->_getByFieldName('price');
            if( $priceColumn =~ /^Royalty \((\w{3})\)/i )
            {
                # Note: this really isn't needed; by definition the header will contain USD
                # (see the headers for Merlin versions 19 and 24 in RPS/Sale/File.pm).
                #
                $currencyCode = $1;
            }
        }
        else
        {
            my $dt = $self->_getByFieldName('dateEnd');
            if( $self->_isEuroDate($dt) )
            {
                $self->{_hasEuroDates} = 1;
                last;
            }
        }

        $linenum++;
    }
    $self->{_currencyCode} = $currencyCode if( $currencyCode );
}



###
1;# Play nicely.
###