package RPS::Import::Merlin::v35;

use strict;

use lib '/app/tools/rps/lib';

use RPS::Import::ServiceMap;
use base 'RPS::Import::Importer';

sub _headerIdentifier { ( upc => 'ICPN (UPC)' ) }
sub _fieldMap {
    {
        labelName        => 'C',
        countryCode      => 'P',
        productType      => 'K',
        formatType       => 'O',
        artistName       => 'I',
        serviceProductID => 'E',
        upc              => 'F',
        trackName        => 'J',
        isrc             => 'H',
        units            => 'Q',
        currencyCode     => 'U1',
        price            => 'U',
    }
}

sub _unverifiedFieldMap {
    {
        altCurrencyCode  => 'U2',
    }
}

sub productType {
    my $self = shift;
    my $type = $self->_getByFieldName('productType');
    if( $type =~ /^track$/i )
    {
        return RPS::File::Sale::TYPE_TRACK;
    }
    $self->fail("Unable to get product type from '$type'");
}

sub formatType {
    my $self = shift;
    my $type = $self->_getByFieldName('formatType');
    if( $type =~ /^ondemandstream$/i )
    {
        return RPS::File::Sale::FORMAT_STREAM;
    }
    $self->fail("Unable to get format type from '$type'");
}

sub mediaType { RPS::DB::Item::MediaType::kMediaTypeAudio }

sub serviceID { Client::Service::DSP_AKAZOO }

sub countryCode {
    my $self = shift;
    my $cname = $self->_getByFieldName('countryCode');
    my $o = Common::Country->Get( $cname );
    return (defined $o) ? $o->alpha2() : $cname;
}

sub currencyCode {
    my $self = shift;
    my $hdr = $self->_getByFieldName('currencyCode');
    return $self->{_currencyCode} if( $self->{_currencyCode} );

    # Assume last word of header is the currency code.  E.g., "Total Euro"
    # If blank due to header row being shifted, try alternate location.
    #
    $hdr = $self->_getByFieldName('altCurrencyCode') if( '' eq $hdr );
    if( $hdr =~ /Euro$/i )
    {
        $self->{_currencyCode} = 'EUR';
    }
    else
    {
        $self->fail("Unable to get currency code from '$hdr'");
    }
}

sub saleDates {
    my $self = shift;

    return ($self->{_startDate}, $self->{_endDate}) if( $self->{_startDate} );

    $self->fail( "Unknown filename" ) unless( $self->filename );

    unless( $self->filename =~ /(\d{4})-(\d{2})-(\d{2})_(\d{4})-(\d{2})-(\d{2})/ ) {  # YYYY-MM-DD_YYYY-MM-DD
        $self->fail( "Could not determine period from filename '" . $self->filename . "'" );
    }

    my $startDate = sprintf( "%04d-%02d-%02d", $1, $2, $3 );
    my $endDate   = sprintf( "%04d-%02d-%02d", $4, $5, $6 );

    ($self->{_startDate}, $self->{_endDate}) = $self->_getDates( date_begin => $startDate, date_end => $endDate );

    return ($self->{_startDate}, $self->{_endDate});

}

###
1;# Play nicely.
###