package RPS::Import::Merlin::v9;

use strict;

use lib '/app/tools/common/lib';
use Common::Date;

use lib '/app/tools/rps/lib';
use RPS::Import::ServiceMap;

use base 'RPS::Import::Importer';

use Data::Dumper;
use Date::Calc qw(Days_in_Month Decode_Month);

sub _headerIdentifier { ( upc => 'EAN UPC' ) }

sub _fieldMap {
    {
        # From header
        dateBegin        => 'A', # optional

        # Data
        labelName        => 'H',
        serviceID        => 'A',
        countryCode      => 'B',
        formatType       => 'O',
        artistName       => 'E',
        upc              => 'D',
        albumName        => 'G',
        isrc             => 'C',
        trackName        => 'F',
        units            => 'J',
        currencyCode     => 'M',
        price            => 'L',
        mediaType        => 'N',
    }
}

sub _unverifiedFieldMap {{
        # Footer
        distFee      => 'M',
}}

# saleDates - return the start/end date information for the file.
# This info will come from the header (if present) _or_ from the
# filename itself if no header is provided.
#
sub saleDates {
    my $self = shift;

    return ($self->{_startDate}, $self->{_endDate}) if( $self->{_startDate} );

    $self->fail( "Unknown filename" ) unless( $self->filename );

    unless( $self->filename =~ /(\d{4})(\d{2})/ ) {
        $self->fail( "Could not determine period from filename '" . $self->filename . "'" );
    }

    my $startDate = sprintf( "%04d-%02d-%02d", $1, $2, 1 );

    ($self->{_startDate}, $self->{_endDate}) = $self->_getDates( date_begin => $startDate );

    return ($self->{_startDate}, $self->{_endDate});
}

sub serviceID {
    my $self = shift;
    my $service = $self->_getByFieldName('serviceID');

    $self->fail( "Service name not defined" ) unless( $service );

    my $serviceID = $self->getServiceID(lc ($service)) || $RPS::Import::ServiceMap::SERVICE_ALIASES{ lc $service };

    $self->fail( "Unable to determine service id from '$service'" ) unless( $serviceID );

    return $serviceID;
}

sub productType {
    my $self = shift;
    return RPS::File::Sale::TYPE_TRACK;
}

sub formatType  {
    my $self = shift;
    my $format = $self->_getByFieldName('formatType') || return;

    if( $format =~ /^(premium|plus|basic|basic-(?:stream|cached|plus-od))$/i ||
        $format =~ /^top33-franchise$/i )
    {
        return RPS::File::Sale::FORMAT_STREAM;
    }

    $self->fail( "Unknown format type '$format'" );
}

sub mediaType {
    my $self = shift;
    my $type = $self->_getByFieldName('mediaType') || return;

    if( lc $type eq 'audio' ) {
        return RPS::DB::Item::MediaType::kMediaTypeAudio;
    }

    $self->fail( "Unknown media type '$type'" );
}

sub price {
    my $self = shift;

    my $price = $self->_getByFieldName('price');
    
    # Apply the distribution only if it was found in the footer;
    # Otherwise the user will have to enter it on the UI.
    #
    if( $self->{_distFee} )
    {
        my $distFee = $self->{_distFee};
        $distFee = (100 - $distFee) * .01;
        $price *= $distFee;
    }

    return $price;
}

sub _preProcess {
    my $self = shift;
    my %args = @_;

    Log->info( "Starting _preProcess" );
    $self->SUPER::_preProcess(%args);

    my $distFee;


    my $getDateFlag; # set if we find a date header

    foreach my $line(@{ $args{lines} }) {

        $self->{line} = $line;

        # Get the date from the header if this file has a header
        #
        if( !$getDateFlag && $self->_getByFieldName('dateBegin') =~ /accounted period/i )
        {
            $getDateFlag = 1;
        }
        elsif( !$self->{_startDate} && $getDateFlag )
        {
            my $dt = $self->_getByFieldName('dateBegin');

            # For dates extracted from the header, we want to report one month before
            # the provided date.
            #
            if( $dt =~/^(\d{4})[- ]?(\d{2})/ ) # YYYY MM or YYYY-MM
            {
                my($year, $month) = ($1, $2);
                if( $month == 1 )
                {
                    $month = 12;
                    $year -= 1;
                }
                else
                {
                    $month--;
                }
                $self->{_startDate} = sprintf( "%04d-%02d-%02d", $year, $month, 1 );
                $self->{_endDate}   = sprintf( "%04d-%02d-%02d", $year, $month, Days_in_Month($year, $month) );
            }
            else
            {
                $self->fail("Unexpected date format found in header");
            }
        }

        # Get the distribution fee from the footer
        #
        $distFee = $self->_getByFieldName('distFee');
        
        if ($distFee =~ /LESS Merlin ADMIN FEE \((.+?)%\)/)
        {    
            $self->{_distFee} = $1;
            last;
        }
    }
}

###
1;# Play nicely.
###