package RPS::Import::MobileStreams;

use strict;

use Date::Calc qw(Days_in_Month Decode_Month);

use lib '/app/tools/common/lib';
use Common::Util;

use lib '/app/tools/data_classes/lib';

use lib '/app/tools/rps/lib';
use RPS::File::Sale;
use RPS::Import::Importer;
use base 'RPS::Import::Importer';

use constant DATE_COL => 0;
use constant DATE_ROW => 1;

use constant FIELD_ARTIST   => 0;
use constant FIELD_TRACK    => 1;
use constant FIELD_VENDORID => 2;
use constant FIELD_UNITS    => 4;
use constant FIELD_PRICE    => 8;

#
# public methods
#

sub _importLines
{
    my $self = shift;
    my %args = @_;
    my $lines = $args{lines};

    return undef unless ($lines);

    my ($dateBegin, $dateEnd) = _get_dates($lines->[DATE_ROW][DATE_COL]);

    unless ($dateBegin && $dateEnd)
    {
        $self->errstr("couldn't get dates from ".$lines->[DATE_ROW][DATE_COL]);
        return undef;
    }

    my $linenum = 1;

    foreach my $line (@$lines)
    {
        my $prodtype    = RPS::File::Sale::TYPE_TRACK;
        my $format      = RPS::File::Sale::FORMAT_RINGTONE;

        my $vendor_id   = $line->[FIELD_VENDORID];
        my $artist      = $line->[FIELD_ARTIST];
        my $track       = $line->[FIELD_TRACK];
        my ($units)     = $line->[FIELD_UNITS] =~ m/^(\d+)$/;
        my ($price)     = $line->[FIELD_PRICE] =~ m/^(\d+\.?\d*)$/;
        $price = ($units != 0)?($price / $units):0;

        if ($artist && $track && $units && $price)
        {
            my $sale = RPS::Import::SaleRec->new();

            $sale->productType($prodtype);
            $sale->formatType($format);
            $sale->serviceProductID($vendor_id);
            $sale->dateBegin($dateBegin);
            $sale->dateEnd($dateEnd);
            $sale->artistName($artist);
            $sale->trackName($track);
            $sale->units($units);
            $sale->price($price);
            $sale->lineNum($linenum);

            #$args{dumper}($sale); ## for cmd-line testing
            $self->_insertSale(sale => $sale);
        }
        #else { print "skip ". join(',', @$line) . "\n"; }
        $linenum++;
    }
    return $linenum;
}

#
# Private methods
#

sub _get_dates
{
    my $date = shift;

    if ($date =~ m/^(\d{4})$/) {
        ## year long... ugly!
        return ($1."-01-01",$1."-12-31");
    } elsif ($date =~ m/^Q[1234] \d{4} - (\d\d)\/(\d\d)\/(\d\d\d\d)-(\d\d)\/(\d\d)\/(\d\d\d\d)$/) {
        return ($3."-".$1."-".$2, $6."-".$4."-".$5);
    }
    return undef;
}

###
1;# Play nicely.
###