#---------------------------------------------------------------
# ____                   _ _         ____  _
#|  _ \ ___  _   _  __ _| | |_ _   _/ ___|| |__   __ _ _ __ ___
#| |_) / _ \| | | |/ _` | | __| | | \___ \| '_ \ / _` | '__/ _ \
#|  _ < (_) | |_| | (_| | | |_| |_| |___) | | | | (_| | | |  __/
#|_| \_\___/ \__, |\__,_|_|\__|\__, |____/|_| |_|\__,_|_|  \___|
#            |___/             |___/
#
# Copyright (C) 2010 RoyaltyShare, Inc.   All Rights Reserved
#---------------------------------------------------------------

package RPS::Import::Redeye::v3;

use strict;

use Date::Calc qw(Days_in_Month);

use lib '/app/tools/common/lib';
use Common::Assert;
use Common::UTF8;

use lib '/app/tools/rps/lib';
use base 'RPS::Import::Importer';

sub _fieldMap {
    {
        dateEnd       => 'A',
        countryCode   => 'B',
        upc           => 'C',
        isrc          => 'D',
        albumName     => 'G',
        artistName    => 'H',
        trackName     => 'I',
        formatType    => 'J',
        productType   => 'K',
        price         => 'Q',
    }
}

sub currencyCode { 'GBP' }

sub _headerIdentifier { ( dateBegin => 'Transaction Date' ) }

sub units { 1 }

sub price {
    my $self = shift;
    my $price = $self->_getByFieldName( 'price' ) || return;
    $price =~ s/^\xA3//;  # strip off pound symbol
    return $price;
}

sub productType {
    my $self = shift;
    my $type = $self->_getByFieldName( 'productType' ) || return;

    if( $type =~ m/^track sale$/i )
    {
        return RPS::File::Sale::TYPE_TRACK;
    } 
    elsif( $type =~ /^full release$/i )
    {
        return RPS::File::Sale::TYPE_ALBUM;
    }

    $self->fail( "Unknown product type $type" );
}

sub isrc {
    my $self = shift;
    my $isrc = $self->_getByFieldName( 'isrc' );

    if( $self->productType eq RPS::File::Sale::TYPE_TRACK )
    {
        return $isrc;
    }
    else
    {
        return undef;
    }
}

sub trackName {
    my $self = shift;
    my $name = $self->_getByFieldName( 'trackName' ) || "";

    if( $self->productType eq RPS::File::Sale::TYPE_TRACK )
    {
        return $name;
    }
    else
    {
        return undef;
    }
}

sub formatType  {
    my $self = shift;
    my $fmt  = $self->_getByFieldName( 'formatType' );

    if ( $fmt =~ m/^mp3 320$/i || $fmt =~ /^mp3 192$/i )
    {
        return RPS::File::Sale::FORMAT_DOWNLOAD;
    }
    elsif( $fmt =~ /^wav$/i )
    {
        return RPS::File::Sale::FORMAT_DOWNLOADPREMIUM;
    }

    $self->fail( "Unable to determine format from '$fmt'" );
}

sub mediaType {
    my $self = shift;
    my $fmt = $self->_getByFieldName( 'formatType' );

    if ( $fmt =~ m/^mp3 320$/i || $fmt =~ /^mp3 192$/i || $fmt =~ /^wav$/i )
    {
        return RPS::DB::Item::MediaType::kMediaTypeAudio;
    }
    $self->fail( "Unable to determine media type from '$fmt'" );
}


sub saleDates {
    my $self = shift;

    my $date = $self->_getByFieldName( 'dateEnd' ) || return;

    my($year, $month, $day);

    if ( $date =~ m/(\d{2})\/(\d{2})\/(\d{4})/ ) # DD/MM/YYYY
    {
        $year  = $3;
        $month = $2;
        $day   = $1;
    }
    else
    {
        $self->fail( "Could not parse date from '$date'" );
    }

    return undef unless ($year && $month);

    return (
        sprintf("%04d-%02d-01", $year, $month),
        sprintf("%04d-%02d-%02d", $year, $month, Days_in_Month($year,$month))
    );
}

###
1;# Play nicely.
###