package RPS::Import::Redeye::v5;

use strict;

use lib '/app/tools/rps/lib';
use RPS::File::Sale;
use RPS::Import::ServiceMap;
use RPS::Import::Importer;

use base 'RPS::Import::Importer';

sub _fieldMap {
    {
        dateBegin        => 'H',
        productType      => 'A',
        artistName       => 'C',
        upc              => 'B',
        albumName        => 'D',

        sales            => 'E',
        salesRevenue     => 'L',
        totalRevenue     => 'L',
    }
};

sub currencyCode { 'USD' }

sub _headerIdentifier { ( upc => 'UPC' ) }

sub physical { 1 }

sub channel { RPS::File::Sale::CHANNEL_RETAIL; }

sub priceLevel { RPS::File::Sale::PLEVEL_UNKNOWN; }

sub saleDates {
    my $self = shift;
    my $startDate = $self->_getByFieldName('dateBegin');
    if( $startDate =~ /^\d{5}$/ )
    {
        $startDate = Spreadsheet::ParseExcel::Utility::ExcelFmt( "yyyy-mm-dd", $startDate );
    }

    return $self->_getDates( date_begin => $startDate );
}

sub countryCode {
    my $self = shift;
    return $self->{_countryCode};
}

sub _preProcess {
    my $self = shift;
    my %args = @_;
    my $fileName = $args{file}->OrigFileName();

    if( !defined $self->{_countryCode} )
    {
        # Country code can be surrounded by space, underscore or period
        #
        if ( $fileName =~ /(?:\s+|_|\.)([a-z]{2})(?:\s+|_|\.)/i )
        {
            $self->{_countryCode} = $1;
        }
        else
        {
            $self->fail( "Could not get territory from '$fileName'" );
        }
    }
}

sub productType {
    my $self = shift;
    my $type = $self->_getByFieldName('productType') || return;

    if( $type =~ /^(?:P)?CD-/i )
    {
        return RPS::File::Sale::TYPE_CD;
    }
    elsif( $type =~ /^LP-/i || $type =~ /^BOX-/i )
    {
        return RPS::File::Sale::TYPE_LP;
    }
    elsif( $type =~ /^SI-/i )
    {
        return RPS::File::Sale::TYPE_LP5;
    }
    elsif( $type =~ /^DVD-/i )
    {
        return RPS::File::Sale::TYPE_DVD;
    }
    elsif( $type =~ /^CS-/i )
    {
        return RPS::File::Sale::TYPE_CASS;
    }
    else
    {
        $self->fail( "Could not get product type from '$type'" );
    }
}

sub sales {
    my $self = shift;
    my $sales = $self->_getByFieldName( 'sales' );
    my $salesRevenue = $self->_getByFieldName( 'salesRevenue' );

    return 1 if( $sales == 0 && $salesRevenue > 0 ); # force a unit if revenue without units

    return ( $sales > 0 ) ? $sales : 0;
}

sub salesRevenue {
    my $self = shift;
    my $salesRevenue = $self->_getByFieldName( 'salesRevenue' );

    return ( $salesRevenue >= 0 ) ? $salesRevenue : 0;
}

sub returns {
    my $self = shift;
    my $sales = $self->_getByFieldName( 'sales' );
    my $salesRevenue = $self->_getByFieldName( 'salesRevenue' );

    return 1 if( $sales == 0 && $salesRevenue < 0 ); # force a unit if revenue without units

    return ( $sales < 0 && $salesRevenue < 0 ) ? abs($sales) : 0;
}

sub returnsRevenue {
    my $self = shift;
    my $sales = $self->_getByFieldName( 'sales' );
    my $salesRevenue = $self->_getByFieldName( 'salesRevenue' );

    return ( $sales <= 0 && $salesRevenue < 0 ) ? abs($salesRevenue) : 0;
}

sub _isValidSaleRecord {
    my $self = shift;

    # The line is valid if it has sales or returns, or has revenue without units,
    # and has an album title
    #
    return ( ( ($self->sales != 0 || $self->returns != 0) ||
               ($self->sales == 0 && $self->returns == 0 &&  $self->totalRevenue != 0 ) ) && $self->albumName );
}

###
1;# Play nicely.
###