#---------------------------------------------------------------
# ____                   _ _         ____  _
#|  _ \ ___  _   _  __ _| | |_ _   _/ ___|| |__   __ _ _ __ ___
#| |_) / _ \| | | |/ _` | | __| | | \___ \| '_ \ / _` | '__/ _ \
#|  _ < (_) | |_| | (_| | | |_| |_| |___) | | | | (_| | | |  __/
#|_| \_\___/ \__, |\__,_|_|\__|\__, |____/|_| |_|\__,_|_|  \___|
#            |___/             |___/
#
# Copyright (C) 2010 RoyaltyShare, Inc.   All Rights Reserved
#---------------------------------------------------------------

package RPS::Import::SelectDigitalIdol::v1;

use strict;

use Date::Calc qw(Days_in_Month);

use lib '/app/tools/rps/lib';
use RPS::Import::ServiceMap;

use base 'RPS::Import::Importer';

sub _fieldMap {
    my $self = shift;
    my %field_map = (
        1 => {
            labelName        => 'A',
            serviceID        => 'E',
            dateBegin        => 'B',
            dateEnd          => 'B',
            productType      => 'M',
            formatType       => 'L',
            artistName       => 'G',
            upc              => 'I',
            albumName        => 'H',
            isrc             => 'K',
            trackName        => 'J',
            units            => 'P',
            price            => 'T',
            countryCode      => 'C',
        },
        2 => {
            labelName        => 'A',
            dateBegin        => 'B',
            serviceID        => 'E',
            countryCode      => 'C',
            productType      => 'M',
            formatType       => 'L',
            artistName       => 'G',
            upc              => 'I',
            albumName        => 'H',
            isrc             => 'K',
            trackName        => 'J',
            units            => 'P',
            price            => 'S'
        },
    );
    return $field_map{$self->_version};
}

sub _headerIdentifier { ( dateBegin => 'Period' ) }

sub _preProcess {
    my $self = shift;
    my %args = @_;
    $self->SUPER::_preProcess(%args);
    my $fileName = $args{file}->OrigFileName();
    if( $fileName =~ /_(\w{3})\.\w+$/i )
    {
        my $cc = uc $1;
        $cc =~ s/CAN/CAD/;
        $self->{_currencyCode} = $cc;
    }
    else
    {
        $self->fail("Couldn't get currency code from filename");
    }
}

sub currencyCode { shift->{_currencyCode} }

sub saleDates {
    my $self = shift;

    my $dt = $self->_getDateBegin();

    my $dateBegin;
    my $dateEnd;

    if( $dt =~ /^(\d{4})-(\d{2})$/ ) # YYYY-MM
    {
        my $year = $1;
        my $month = $2;
        $dateBegin = sprintf("%04d-%02d-%02d", $year, $month, 1);
        $dateEnd = sprintf("%04d-%02d-%02d", $year, $month, Days_in_Month($year, $month));
    }

    return ($dateBegin, $dateEnd);
}

sub serviceID {
    my $self = shift;
    my $service = $self->_getByFieldName('serviceID');
    my $serviceID = $self->getServiceID(lc ($service)) || $RPS::Import::ServiceMap::SERVICE_ALIASES{ lc $service };
    return $serviceID if( $serviceID );
    $self->fail("Unknown service '$service'");
}

sub countryCode {
    my $self = shift;
    my $name = $self->_getByFieldName('countryCode');
    my $o = Common::Country->Get( $name );
    if( $o )
    {
        return $o->alpha2;
    }
    $self->fail("Unrecognized country '$name'");
}

sub productType {
    my $self = shift;
    my $type = $self->_getByFieldName( 'productType' ) || return;

    if( $type =~ /^album$/i )
    {
        return RPS::File::Sale::TYPE_ALBUM;
    } 
    elsif( $type =~ /^(free|motion audio|motion video|premium|radio|track|trial|upgrade|video)$/i )
    {
        return RPS::File::Sale::TYPE_TRACK;
    } 
    else
    {
        $self->fail( "Could not parse product type from '$type'" );
    }
}

sub mediaType {
    my $self = shift;
    my $type = $self->_getByFieldName( 'productType' ) || return;

    if( $type =~ /video/i )
    {
        return RPS::DB::Item::MediaType::kMediaTypeVideo;
    }
    else
    {
        return RPS::DB::Item::MediaType::kMediaTypeAudio;
    }
}

sub albumName {
    my $self = shift;
    my $name = $self->_getByFieldName( 'albumName' );
    return $name if( $self->productType eq RPS::File::Sale::TYPE_ALBUM );
}

sub trackName {
    my $self = shift;
    my $name = $self->_getByFieldName( 'trackName' );
    return $name if( $self->productType eq RPS::File::Sale::TYPE_TRACK );
}

sub formatType  {
    my $self = shift;
    my $fmt = $self->_getByFieldName( 'formatType' );

    if( $fmt =~ /^download$/i )
    {
        return RPS::File::Sale::FORMAT_DOWNLOAD;
    }
    elsif( $fmt =~ /^(stream|other)$/i )
    {
        return RPS::File::Sale::FORMAT_STREAM;
    }
    $self->fail( "Could not parse format type from '$fmt'" );
}

sub units {
    my $self = shift;
    my $units = $self->_getByFieldName('units') || return;
    my $price = $self->_getByFieldName('price');

    # If the price is negative, we'll store negative units,
    # regardless of whether the units were positive or negative
    # in the sale file.  Accordingly, the price is always
    # positive.  This ensures that returns are recorded correctly.
    #
    if( defined($price) ) {
        return $price < 0 ? abs($units) * -1 : $units;
    }
    else {
        return $units;
    }
}

sub unitPrice {
    return abs( shift->SUPER::unitPrice() );
}

###
1;# Play nicely.
###