#---------------------------------------------------------------
# ____                   _ _         ____  _
#|  _ \ ___  _   _  __ _| | |_ _   _/ ___|| |__   __ _ _ __ ___
#| |_) / _ \| | | |/ _` | | __| | | \___ \| '_ \ / _` | '__/ _ \
#|  _ < (_) | |_| | (_| | | |_| |_| |___) | | | | (_| | | |  __/
#|_| \_\___/ \__, |\__,_|_|\__|\__, |____/|_| |_|\__,_|_|  \___|
#            |___/             |___/
#
# Copyright (C) 2010 RoyaltyShare, Inc.   All Rights Reserved
#---------------------------------------------------------------

package RPS::Import::Sony::v10;

use strict;

use Date::Calc qw(Days_in_Month);

use lib '/app/tools/common/lib';
use Common::Assert;
use Common::UTF8;
use Common::Country;

use lib '/app/tools/rps/lib';
use base 'RPS::Import::Importer';

sub _fieldMap {
    {
        # header
        #
        labelName        => 'A',  # A6
        dateBegin        => 'F',  # F3

        # detail
        #
        artistName       => 'C',
        upc              => 'A',
        albumName        => 'B',
        configuration    => 'D',
        countryCode      => 'H',
        totalRevenue     => 'Q',
        wholesalePrice   => 'K',

    }
}

sub _unverifiedFieldMap {
    {
        priceLine        => 'J',
        unitsSold        => 'L',
        royaltyAmount    => 'Q',
    }
};

 
sub _headerIdentifier {
    ( 'upc' => 'Product Number' )
}

sub currencyCode { 'AUD' }

sub channel { RPS::File::Sale::CHANNEL_RETAIL }

sub priceLevel {
    my $self = shift;
    my $priceLine = $self->_getByFieldName( 'priceLine' );
    if( $priceLine =~ /^budget$/i )
    {
        return RPS::File::Sale::PLEVEL_BUDGET;
    }
    elsif( $priceLine =~ /^mid$/i )
    {
        return RPS::File::Sale::PLEVEL_MID;
    }
    elsif( $priceLine =~ /^full$/i )
    {
        return RPS::File::Sale::PLEVEL_FULL;
    }
    $self->fail("Unable to determine price level from ($priceLine)");
}

sub saleDates {
    my $self = shift;
    return ($self->{_startDate}, $self->{_endDate}) if( $self->{_startDate} ); # from header of current sheet; see _processSheet
}

sub labelName {
    my $self = shift;
    return $self->{_labelName} if( $self->{_labelName} ); # from header of current sheet; see _processSheet
}

sub countryCode {
    my $self = shift;
    my $country = $self->_getByFieldName('countryCode');
    my $o = Common::Country->Get( $country );
    return (defined $o) ? $o->alpha2() : $country;
}

sub productType {
    my $self = shift;
    my $config = $self->_getByFieldName( 'configuration' );

    if( $config =~ /^cd longplay$/i || $config =~ /^enhanced cd longplay$/i )
    {
        return RPS::File::Sale::TYPE_CD;
    }
    elsif( $config =~ /^vinyl longplay 33 1\/3$/i )
    {
        return RPS::File::Sale::TYPE_LP;
    }
    elsif( $config =~ /^dvd video longplay$/i )
    {
        return RPS::File::Sale::TYPE_DVD;
    }

    $self->fail("Unable to determine config from format($config)");
}

sub sales {
    my $self = shift;
    my $sales = $self->_getByFieldName( 'unitsSold' );

    return ( $sales > 0 ) ? $sales : 0;
}

sub salesRevenue {
    my $self = shift;
    my $salesRevenue = $self->_getByFieldName( 'royaltyAmount' );

    return ( $salesRevenue > 0 ) ? $salesRevenue : 0;
}

sub returns {
    my $self = shift;
    my $sales = $self->_getByFieldName( 'unitsSold' );
    my $salesRevenue = $self->_getByFieldName( 'royaltyAmount' );

    return ( $sales < 0 && $salesRevenue < 0 ) ? abs($sales) : 0;
}

sub returnsRevenue {
    my $self = shift;
    my $sales = $self->_getByFieldName( 'unitsSold' );
    my $salesRevenue = $self->_getByFieldName( 'royaltyAmount' );

    return ( $sales < 0 && $salesRevenue < 0 ) ? abs($salesRevenue) : 0;
}

sub _isValidSaleRecord {
    my $self = shift;

    # The line is valid if it has sales or returns, and has an album title
    #
    return ( ($self->sales != 0 || $self->returns != 0) && $self->albumName );
}

# _processSheet is used to process a tab from the spreadsheet.
# Here, we're extracting the sale date and label information
# from the cells called out in the template.
#
sub _processSheet {
    my $self     = shift;
    my $sheet    = shift;
    my $sheetnum = shift;

    my $startDate = $sheet->[2][5];  # F3 (row 2, col 5)

    my($dateBegin, $dateEnd) = $self->_getDates( date_begin => $startDate );
    $self->{_startDate} = $dateBegin;
    $self->{_endDate}   = $dateEnd;


    my $labelName = $sheet->[5][0];  # A6 (row 5, col 0)
    $self->{_labelName} = $labelName;

    return $self->SUPER::_processSheet( $sheet, $sheetnum );
}

sub physical { 1 }

###
1;# Play nicely.
###