#---------------------------------------------------------------
# ____                   _ _         ____  _
#|  _ \ ___  _   _  __ _| | |_ _   _/ ___|| |__   __ _ _ __ ___
#| |_) / _ \| | | |/ _` | | __| | | \___ \| '_ \ / _` | '__/ _ \
#|  _ < (_) | |_| | (_| | | |_| |_| |___) | | | | (_| | | |  __/
#|_| \_\___/ \__, |\__,_|_|\__|\__, |____/|_| |_|\__,_|_|  \___|
#            |___/             |___/
#
# Copyright (c) 2013-2014 RoyaltyShare, Inc. All Rights Reserved
#---------------------------------------------------------------

package RPS::Import::Sony::v23;

use strict;

use Date::Calc qw(Days_in_Month);

use lib '/app/tools/common/lib';
use Common::Assert;
use Data::Dumper;

use lib '/app/tools/rps/lib';
use RPS::Import::ServiceMap;
use base 'RPS::Import::Importer';

sub _fieldMap {
    my $self = shift;
    my $version = $self->_version;
    my %field_map = (
        23 =>{
            dateBegin         => 'I',
            dateEnd           => 'I',
            labelName         => 'H',
            artistName        => 'F',
            serviceID         => 'J',
            serviceProductID  => 'C',
            units             => 'L',
            price             => 'M',
        },
        27 =>{
            dateBegin         => 'I',
            dateEnd           => 'I',
            labelName         => 'H',
            artistName        => 'F',
            serviceID         => 'J',
            serviceProductID  => 'C',
            units             => 'M',
            price             => 'N',
        },
        28 =>{
            dateBegin         => 'D',
            dateEnd           => 'D',
            labelName         => 'H',
            artistName        => 'F',
            serviceID         => 'I',
            serviceProductID  => 'C',
            units             => 'K',
            price             => 'L',
        },
        30 =>{
            dateBegin         => 'D',
            dateEnd           => 'D',
            labelName         => 'I',
            artistName        => 'E',
            serviceID         => 'J',
            serviceProductID  => 'C',
            units             => 'L',
            price             => 'M',
        },        
    );
    return $field_map{$version};
}

sub _unverifiedFieldMap {
    my $self = shift;
    my $version = $self->_version;
    my %field_map = (
        23 => {
            config        => 'E',
            downloadFlag  => 'K',
            title         => 'G',
        },
        27 => {
            config        => 'E',
            downloadFlag  => 'K',
            title         => 'G',
        },
        28 => {
            config        => 'E',
            downloadFlag  => 'J',  # Note: col J is sales channel (see _getMappings)
            title         => 'G',
        },
        30 => {
            config        => 'H',
            downloadFlag  => 'K',  # Note: col K is sales channel (see _getMappings)
            title         => 'F',
        },        
    );
    return $field_map{$version};
}

sub _headerIdentifier { ( 'title' => 'Title' ) }

sub countryCode  { 'AU' }

sub currencyCode { 'AUD' }

sub saleDates {
    my $self = shift;
    my $startDate = $self->_getByFieldName('dateBegin');
    my $endDate = $self->_getByFieldName('dateEnd');

    my $dateBegin;
    my $dateEnd;
    if( $startDate =~ /(\d{4})(\d{2})/ ) {
        $dateBegin = sprintf("%04d-%02d-%02d", $1, $2, 1 );
        $dateEnd   = sprintf("%04d-%02d-%02d", $1, $2, Days_in_Month($1, $2) );
    }
    return ( $dateBegin, $dateEnd );
}

sub serviceID {
    my $self = shift;
    my $service = $self->_getByFieldName('serviceID');

    # Some of the service names have an "_AU" suffix
    #
    $service =~ s/(.*)_AU$/$1/;
    
    # And some just have some extra text at the end.
    $service =~ s/(.*) \(SUBSCRIPTION$/$1/;
    $service =~ s/(.*) \(MULTIPLE DEA$/$1/;
    $service =~ s/(.*) \(PLAY SUBSCRI$/$1/;
    $service =~ s/(.*) \(NON DM$/$1/;
    $service =~ s/(.*), AUSTRALIA$/$1/;
    $service =~ s/(.*), UK$/$1/;
    
    $self->fail( "Service name not defined" ) unless( $service );

    my $serviceID = $self->getServiceID(lc ($service)) || $RPS::Import::ServiceMap::SERVICE_ALIASES{ lc $service };

    $self->fail( "Unable to determine service id from '$service'" ) unless( $serviceID );

    return $serviceID;
}

sub productType {
    my $self = shift;
    my $config = $self->_getByFieldName('config') || return;

    if( $config =~ /^digital audio bundle$/i        ||
        $config =~ /^digital audio extended play$/i ||
        $config =~ /^digital audio longplay$/i      ||
        $config =~ /^digital (combo|video) longform$/i )
    {
            return RPS::File::Sale::TYPE_ALBUM;
    }
    elsif( $config =~ /^digital\s+(audio|video) track$/i ||
           $config =~ /^mastertone$/i                    ||
           $config =~ /^ringback tone$/i                 ||
           $config =~ /^#n\/a$/i )
    {
        return RPS::File::Sale::TYPE_TRACK;
    }
    else
    {
        $self->fail("Unable to determine product type from config($config)");
    }
}

my %gFormatMediaMap = (
    'Digital Audio Bundle' => {
        '(Y|Download|Digital Download)' => {
            format       => RPS::File::Sale::FORMAT_DOWNLOAD,
            media        => RPS::DB::Item::MediaType::kMediaTypeAudio,
        },
    },
    'Digital Audio Extended Play' => {
        '(Y|Download|Digital Download)' => {
            format       => RPS::File::Sale::FORMAT_DOWNLOAD,
            media        => RPS::DB::Item::MediaType::kMediaTypeAudio,
        },
        'Digital Breakage' => {
            format       => RPS::File::Sale::FORMAT_STREAM,
            media        => RPS::DB::Item::MediaType::kMediaTypeAudio,
        },
    },
    'Digital Audio Longplay' => {
        '(Y|Download|Digital Download)' => {
            format       => RPS::File::Sale::FORMAT_DOWNLOAD,
            media        => RPS::DB::Item::MediaType::kMediaTypeAudio,
        },
        '(N|Breakage|Digital Breakage)' => {
            format       => RPS::File::Sale::FORMAT_STREAM,
            media        => RPS::DB::Item::MediaType::kMediaTypeAudio,
        },
    },
    'Digital Audio Track' => {
        '(N|Breakage|Locker Play|Locker Stream|Stream Ad Supp|Stream Subscription|Digital Breakage|Digital Locker Play|Digital Locker Stream|Digital Stream Ad Supp|Digital Stream Subscription|Digital Ephemeral|Digital Settlement)' => {
            format       => RPS::File::Sale::FORMAT_STREAM,
            media        => RPS::DB::Item::MediaType::kMediaTypeAudio,
        },
        '(Y|Download|Digital Download)' => {
            format       => RPS::File::Sale::FORMAT_DOWNLOAD,
            media        => RPS::DB::Item::MediaType::kMediaTypeAudio,
        },
    },
    'Digital Combo Longform' => {
        '(Y|Download|Digital Download)' => {
            format       => RPS::File::Sale::FORMAT_DOWNLOAD,
            media        => RPS::DB::Item::MediaType::kMediaTypeAudio,
        },
    },
    'Digital Video Longform' => {
        '(N|Digital Stream Subscription)' => {
            format       => RPS::File::Sale::FORMAT_STREAM,
            media        => RPS::DB::Item::MediaType::kMediaTypeVideo,
        },
        '(Y|Download|Digital Download)' => {
            format       => RPS::File::Sale::FORMAT_DOWNLOAD,
            media        => RPS::DB::Item::MediaType::kMediaTypeVideo,
        },
    },
    'Digital Video Track' => {
        '(N|Breakage|Locker Play|Stream Ad Supp|Stream Subscription|Digital Breakage|Digital Locker Play|Digital Stream Ad Supp|Digital Stream Subscription)' => {
            format       => RPS::File::Sale::FORMAT_STREAM,
            media        => RPS::DB::Item::MediaType::kMediaTypeVideo,
        },
        '(Y|Download|Digital Download)' => {
            format       => RPS::File::Sale::FORMAT_DOWNLOAD,
            media        => RPS::DB::Item::MediaType::kMediaTypeVideo,
        },
    },
    'Mastertone' => {
        'Y' => {
            format       => RPS::File::Sale::FORMAT_RINGTONE,
            media        => RPS::DB::Item::MediaType::kMediaTypeAudio,
        },
        '(Download|Digital Download)' => {
            format       => RPS::File::Sale::FORMAT_DOWNLOAD,
            media        => RPS::DB::Item::MediaType::kMediaTypeAudio,
        },
    },
    'Ringback Tone' => {
        'Y' => {
            format       => RPS::File::Sale::FORMAT_RINGTONE,
            media        => RPS::DB::Item::MediaType::kMediaTypeAudio,
        },
        'Digital Download' => {
            format       => RPS::File::Sale::FORMAT_TETHERED,
            media        => RPS::DB::Item::MediaType::kMediaTypeAudio,
        },
    },
    '#N\/A' => {
        '(Stream Ad Supp|Digital Stream Ad Supp)' => {
            format       => RPS::File::Sale::FORMAT_STREAM,
            media        => RPS::DB::Item::MediaType::kMediaTypeAudio,
        },
    },
);

sub _getMappings {
    my $self = shift;
    my $config = $self->_getByFieldName('config');
    my $dflag  = $self->_getByFieldName('downloadFlag');

    my $_formatType;
    my $_mediaType;

    foreach my $_cType (keys %gFormatMediaMap)
    {
        if( $config =~ /^$_cType$/i )
        {
            foreach my $_dType (keys %{$gFormatMediaMap{$_cType}})
            {
                if( $dflag =~ /^$_dType$/i )
                {
                    $_formatType  = $gFormatMediaMap{$_cType}{$_dType}{format};
                    $_mediaType   = $gFormatMediaMap{$_cType}{$_dType}{media};
                    last;
                }
            }
        }
    }
    return( $_formatType, $_mediaType );
}

sub formatType {
    my $self = shift;
    my( $formatType, $mediaType ) = $self->_getMappings();

    return $formatType if( $formatType );

    my $config = $self->_getByFieldName('config');
    my $dflag  = $self->_getByFieldName('downloadFlag');
    $self->fail("Unable to determine format type from config($config) downloadFlag($dflag)");
}

sub mediaType {
    my $self = shift;
    my( $formatType, $mediaType ) = $self->_getMappings();

    return $mediaType if( $mediaType );

    my $config = $self->_getByFieldName('config');
    my $dflag  = $self->_getByFieldName('downloadFlag');
    $self->fail("Unable to determine media type from config($config) downloadFlag($dflag)");
}

# Note: adjusting offsets only works for column notation.  It does _not_
# work if the field is specified using cell notation (e.g., "C10").
#
sub _getOffset {
    my $self = shift;
    my $field = shift;

    my $offset = $self->SUPER::_getOffset($field) || return;
    if( $self->{_shiftedColumns} )
    {
        return $offset - 1;
    }
    return $offset;
}

sub _processSheet {
    my $self = shift;
    my $sheet = shift;
    my $sheetnum = shift;
    my $version = $self->_version;

    delete $self->{_shiftedColumns} if( exists $self->{_shiftedColumns} );

    # Check for shifted columns
    #
    foreach my $line (@$sheet)
    {
        $self->{line} = $line;

        # Check for header line and adjust offset if label name is in the wrong spot
        #
        my $labelName = $self->_getByFieldName('labelName');
        if( (23 == $version && $labelName =~ /Digital Sales Month/i ) ||
            (27 == $version && $labelName =~ /Sales Month/i ) ||
            (28 == $version && $labelName =~ /DSP/i ) ||
            (30 == $version && $labelName =~ /Provider Name/i ) )
        {
            $self->{_shiftedColumns} = 1;
            last;
        }
    }

    # process the sheet
    #
    $self->SUPER::_processSheet($sheet, $sheetnum);

}

sub units {
    my $self = shift;
    my $units  = $self->_getByFieldName('units') || return;
    my $price  = $self->_getByFieldName('price') || return;

    return $price < 0 ? abs($units) * -1 : abs($units);
}

sub albumName {
    my $self = shift;
    my $name = $self->_getByFieldName( 'title' );

    if( $self->productType() eq RPS::File::Sale::TYPE_ALBUM )
    {
        return $name;
    }
    else
    {
        return '';
    }
}

sub trackName {
    my $self = shift;
    my $name = $self->_getByFieldName( 'title' );

    if( $self->productType() eq RPS::File::Sale::TYPE_TRACK )
    {
        return $name;
    }
    else
    {
        return '';
    }
}

sub _isValidSaleRecord {
    my $self = shift;

    # The line is valid if it has units and an album/track title
    #
    return (( $self->units() != 0 || ($self->units == 0 && $self->price != 0)) && 
             ($self->albumName() || $self->trackName()) );
}

###
1;# Play nicely.
###