#---------------------------------------------------------------
# ____                   _ _         ____  _
#|  _ \ ___  _   _  __ _| | |_ _   _/ ___|| |__   __ _ _ __ ___
#| |_) / _ \| | | |/ _` | | __| | | \___ \| '_ \ / _` | '__/ _ \
#|  _ < (_) | |_| | (_| | | |_| |_| |___) | | | | (_| | | |  __/
#|_| \_\___/ \__, |\__,_|_|\__|\__, |____/|_| |_|\__,_|_|  \___|
#            |___/             |___/
#
# Copyright (C) 2015 RoyaltyShare, Inc.   All Rights Reserved
#---------------------------------------------------------------

package RPS::Import::Sony::v25;

use strict;

use Date::Calc qw(Days_in_Month);

use lib '/app/tools/common/lib';
use Common::Assert;
use Common::UTF8;
use Common::Country;

use lib '/app/tools/rps/lib';
use base 'RPS::Import::Importer';

sub _fieldMap {
    {
        # header
        #
        labelName        => 'A6',
        dateBegin        => 'E3',
        dateEnd          => 'F3',

        # detail
        #
        countryCode      => 'J',
        configuration    => 'D',
        artistName       => 'C',
        serviceProductID => 'A',
        upc              => 'I',
        albumName        => 'B',
        priceLevel       => 'L',
        currencyCode     => 'U',
        wholesalePrice   => 'O',
        units            => 'P',
        totalRevenue     => 'U',
    }
}

sub _unverifiedFieldMap {
    {
        altDateBegin => 'F',
        altDateEnd   => 'G',
    }
}

sub physical { 1 }

sub _headerIdentifier {
    ( 'upc' => 'Barcode (UPC)' )
}

sub channel { RPS::File::Sale::CHANNEL_RETAIL }

sub sales {
    my $self = shift;
    my $sales = $self->_getByFieldName( 'units' );

    return ( $sales > 0 ) ? $sales : 0;
}

sub salesRevenue {
    my $self = shift;
    my $salesRevenue = $self->_getByFieldName( 'totalRevenue' );

    return ( $salesRevenue > 0 ) ? $salesRevenue : 0;
}

sub returns {
    my $self = shift;
    my $sales = $self->_getByFieldName( 'units' );
    my $salesRevenue = $self->_getByFieldName( 'totalRevenue' );

    return ( $sales < 0 && $salesRevenue < 0 ) ? abs($sales) : 0;
}

sub returnsRevenue {
    my $self = shift;
    my $sales = $self->_getByFieldName( 'units' );
    my $salesRevenue = $self->_getByFieldName( 'totalRevenue' );

    return ( $sales < 0 && $salesRevenue < 0 ) ? abs($salesRevenue) : 0;
}

sub totalRevenue {
    my $self = shift;
    my $revenue = $self->_getByFieldName( 'totalRevenue' );
    $revenue = $self->_formatRevenue($revenue);

    return $revenue;
}

sub _formatRevenue {
    my ($self, $revenue) = @_;
    
    if ($revenue =~ /^- (\d+),(\d{2})$/) {
        $revenue = $1 . "." . $2;
        $revenue *= -1;
    } elsif ($revenue =~ /^(\d+),(\d{2})$/) {
        $revenue = $1 . "." . $2;
    }
    
    return $revenue;
}

sub albumName {
    my $self = shift;
    my $albumName = $self->_getByFieldName('albumName');

    return $albumName;
}

sub _isValidSaleRecord {
    my $self = shift;

    # The line is valid if it has sales or returns, and has an album title
    return ( ($self->sales != 0 || $self->returns != 0) && $self->albumName );
}

sub currencyCode { 'AUD' }

sub countryCode {
    my $self = shift;
    my $name = $self->_getByFieldName('countryCode');
    
    if( $name )
    {
        my $obj = Common::Country->Get( $name );
        return $obj->alpha2() if( $obj );
    }

    return $name;  # Return original name and let MapFace deal with it
}

sub productType {
    my $self = shift;
    my $config = $self->_getByFieldName( 'configuration' );

    if( $config =~ /^cd longplay$/i || $config =~ /^enhanced cd longplay$/i )
    {
        return RPS::File::Sale::TYPE_CD;
    }
    elsif( $config =~ /^vinyl longplay 33 1\/3$/i )
    {
        return RPS::File::Sale::TYPE_LP;
    }
    elsif( $config =~ /^dvd video longplay$/i )
    {
        return RPS::File::Sale::TYPE_DVD;
    }

    $self->fail("Unable to determine config from format($config)");
}

sub priceLevel {
    my $self = shift;
    my $priceLevel = $self->_getByFieldName( 'priceLevel' );
    if( $priceLevel =~ /^full$/i )
    {
        return RPS::File::Sale::PLEVEL_FULL;
    }
    elsif( $priceLevel =~ /^mid$/i )
    {
        return RPS::File::Sale::PLEVEL_MID;
    }
    elsif( $priceLevel =~ /^budget$/i )
    {
        return RPS::File::Sale::PLEVEL_BUDGET;
    }
    $self->fail("Unable to determine price level from ($priceLevel)");
}

sub saleDates {
    my $self = shift;
    return ($self->{_startDate}, $self->{_endDate}) if( $self->{_startDate} ); # from header of current sheet; see _processSheet
}

# _processSheet is used to process a tab from the spreadsheet.
# Here, we're extracting the sale date and label information
# from the cells called out in the template.
#
sub _processSheet {
    my $self     = shift;
    my $sheet    = shift;
    my $sheetnum = shift;

    # Try to find the date information by examining the header area
    # at the top of the sheet.  The date information can be in one of
    # two places, even though the main header (the one we use for file
    # identification) is the same.
    #
    my $foundAlternateDate;
    foreach my $line(@$sheet) {
        $self->{line} = $line;

        my $labelName = $self->_getByFieldName('labelName');
        $self->{_labelName} = $labelName;

        # Check for alternate date location first
        if( !$foundAlternateDate )
        {
            my $sd = $self->_getByFieldName('altDateBegin');
            my $ed = $self->_getByFieldName('altDateEnd');

            $foundAlternateDate = 1 if( $sd =~ /Period Start Date/i );
        }
        else
        {
            my $startDate = $self->_getByFieldName('altDateBegin');
            my $endDate = $self->_getByFieldName('altDateEnd');

            $startDate = Spreadsheet::ParseExcel::Utility::ExcelFmt( "yyyy-mm-dd", $startDate ) if( $startDate =~ /^\d{5}$/ );
            $endDate = Spreadsheet::ParseExcel::Utility::ExcelFmt( "yyyy-mm-dd", $endDate ) if( $endDate =~ /^\d{5}$/ );

            my($dateBegin, $dateEnd) = $self->_getDates( date_begin => $startDate, date_end => $endDate );
            $self->{_startDate} = $dateBegin;
            $self->{_endDate}   = $dateEnd;
            last;
        }
    }

    if( !$foundAlternateDate )
    {
        foreach my $line(@$sheet) {
            $self->{line} = $line;


            my $labelName = $self->_getByFieldName('labelName');
            $self->{_labelName} = $labelName;

            my $startDate = $self->_getByFieldName('dateBegin');
            my $endDate   = $self->_getByFieldName('dateEnd');

            my($dateBegin, $dateEnd) = $self->_getDates( date_begin => $startDate, date_end => $endDate );

            $self->{_startDate} = $dateBegin;
            $self->{_endDate}   = $dateEnd;
        }
    }

    # Now process the detail lines
    #
    return $self->RPS::Import::Importer::_processSheet( $sheet, $sheetnum );
}

###
1;# Play nicely.
###