#---------------------------------------------------------------
# ____                   _ _         ____  _
#|  _ \ ___  _   _  __ _| | |_ _   _/ ___|| |__   __ _ _ __ ___
#| |_) / _ \| | | |/ _` | | __| | | \___ \| '_ \ / _` | '__/ _ \
#|  _ < (_) | |_| | (_| | | |_| |_| |___) | | | | (_| | | |  __/
#|_| \_\___/ \__, |\__,_|_|\__|\__, |____/|_| |_|\__,_|_|  \___|
#            |___/             |___/
#
# Copyright (C) 2010 RoyaltyShare, Inc.   All Rights Reserved
#---------------------------------------------------------------
package RPS::Import::Universal::v16;

use strict;

use lib '/app/tools/rps/lib';
use base 'RPS::Import::Importer';

# The sales file has a blank column on the left which causes the column
# labels to be off by one (hence the # _getOffset method, below).
# Notice that the field_map is indexed using the tab name, so we're ready
# if/when we start looking at more than one tab for the physical file.
# 
sub _fieldMap {
    my $self = shift;
    my $version = $self->_version;
    my $sheetname = lc $self->sheetname;

    my %field_map = (
        'australian sales'  => {
            dateBegin        => 'B', # QUARTER ENDING
            clientProductID  => 'C', # CATALOGUE NO.
            albumName        => 'D', # RECORDING
            totalRevenue     => 'J', # ROYALTY EARNINGS ($)
            sales            => 'F', # ROYALTY SALES
        },
    );
    return $field_map{$sheetname};
}

sub _getOffset {
    my $self = shift;
    my $field = shift;

    my $offset = $self->SUPER::_getOffset( $field );

    return undef if( !defined $offset );

    return $offset - 1;
}

sub _headerIdentifier { ( dateBegin => 'ENDING' ) }

sub currencyCode { 'AUD' }

sub countryCode { 'AU' }

sub productType { RPS::File::Sale::TYPE_CD }

sub channel { RPS::File::Sale::CHANNEL_RETAIL }

sub priceLevel { RPS::File::Sale::PLEVEL_UNKNOWN }

sub physical{ 1 };

sub sales {
    my $self = shift;
    my $sales = $self->_getByFieldName('sales');
    my $revenue = $self->_getByFieldName('totalRevenue');
    return ($revenue > 0) ? abs($sales) : 0;
}

sub salesRevenue {
    my $self = shift;
    my $revenue = $self->_getByFieldName('totalRevenue');
    return ($revenue > 0) ? $revenue : 0;
}

sub returns {
    my $self = shift;
    my $sales = $self->_getByFieldName('sales');
    my $revenue = $self->_getByFieldName('totalRevenue');
    return ($revenue < 0) ? abs($sales) : 0;
}

sub returnsRevenue {
    my $self = shift;
    my $revenue = $self->_getByFieldName('totalRevenue');
    return ($revenue < 0) ? abs($revenue) : 0;
}

sub _isValidSaleRecord {
    my $self = shift;

    # The line is valid if it has sales or returns, and has an album title
    #
    return ( ($self->sales != 0 || $self->returns != 0) && $self->albumName );
}

sub saleDates {
    my $self = shift;

    my $date = $self->_getByFieldName('dateBegin') || return;

    my $dateBegin;
    my $dateEnd;

    if( $date =~ /\d{5}/ ) # Excel
    {
        ($dateBegin, $dateEnd) = $self->_getDates( date_begin => $date, type => "msft" );

    }
    return ($dateBegin, $dateEnd);
}

sub _processSheet {
    my $self     = shift;
    my $sheet    = shift;
    my $sheetnum = shift;

    if( $self->{sheetname} =~ /^AUSTRALIAN SALES$/i )
    {
        return $self->SUPER::_processSheet( $sheet, $sheetnum );
    }
}

###
1;# Play nicely.
###