#---------------------------------------------------------------
# ____                   _ _         ____  _
#|  _ \ ___  _   _  __ _| | |_ _   _/ ___|| |__   __ _ _ __ ___
#| |_) / _ \| | | |/ _` | | __| | | \___ \| '_ \ / _` | '__/ _ \
#|  _ < (_) | |_| | (_| | | |_| |_| |___) | | | | (_| | | |  __/
#|_| \_\___/ \__, |\__,_|_|\__|\__, |____/|_| |_|\__,_|_|  \___|
#            |___/             |___/
#
# Copyright (C) 2010 RoyaltyShare, Inc.   All Rights Reserved
#---------------------------------------------------------------
package RPS::Import::Universal::v17;

use strict;

use Date::Calc qw(Days_in_Month Decode_Month);

use lib '/app/tools/rps/lib';
use base 'RPS::Import::Importer';

sub _fieldMap {
    my $self = shift;
    my $version = $self->_version;

    my %field_map = (
        17 => {
            dateBegin        => 'BC', # header row

            serviceProductID => 'R',
            albumName        => 'O',
            artistName       => 'N',
            labelName        => 'K',
            productType      => 'AK',
            priceLevel       => 'AQ',
            wholesalePrice   => 'AS',
            totalRevenue     => 'BC', # Net revenue
            upc              => 'S',
        },
        18 => {
            dateBegin        => 'AY', # header row

            serviceProductID => 'Q',
            albumName        => 'O',
            artistName       => 'N',
            labelName        => 'K',
            productType      => 'AG', # Configuration Code
            priceLevel       => 'AM',
            totalRevenue     => 'AY', # Net revenue
            upc              => 'R',
        },
        29 => {
            dateBegin        => 'AZ', # header row

            serviceProductID => 'R',
            albumName        => 'P',
            artistName       => 'O',
            labelName        => 'L',
            productType      => 'AH', # Configuration Code
            priceLevel       => 'AN',
            totalRevenue     => 'AZ', # Net revenue
            upc              => 'S',
        },
        30 => {
            dateBegin        => 'AY', # header row

            serviceProductID => 'R',
            albumName        => 'P',
            artistName       => 'O',
            labelName        => 'L',
            productType      => 'AH', # Configuration Code
            priceLevel       => 'AN',
            totalRevenue     => 'AY', # Net revenue
            upc              => 'S',
        },
        31 => {
            dateBegin        => 'AX', # header row

            serviceProductID => 'Q',
            albumName        => 'O',
            artistName       => 'N',
            labelName        => 'K',
            productType      => 'AG',
            priceLevel       => 'AM',
            wholesalePrice   => 'AO',
            totalRevenue     => 'AX', # Net revenue
            upc              => 'R',
        },
        47 => {
            dateBegin        => 'A4', # header row

            albumName        => 'AF',
            artistName       => 'G',
            productType      => 'V',
            priceLevel       => 'Z',
            sales            => 'AM',
            salesRevenue     => 'AL',
            returns          => 'AO',
            returnsRevenue   => 'AN',
            totalRevenue     => 'AP', # Net revenue
            upc              => 'J',
        },
        48 => {
            dateBegin        => 'A4', # header row

            labelName        => 'K',
            albumName        => 'N',
            artistName       => 'M',
            productType      => 'AB',
            priceLevel       => 'AE',
            wholesalePrice   => 'AG',
            sales            => 'AK',
            salesRevenue     => 'AJ',
            returns          => 'AM',
            returnsRevenue   => 'AL',
            totalRevenue     => 'AN', # Net revenue
            upc              => 'P',
        },
        49 => {
            dateBegin        => 'A4', # header row

            labelName        => 'K',
            albumName        => 'N',
            artistName       => 'M',
            productType      => 'AE',
            priceLevel       => 'AI',
            wholesalePrice   => 'AL',
            sales            => 'AR',
            salesRevenue     => 'AQ',
            returns          => 'AT',
            returnsRevenue   => 'AS',
            totalRevenue     => 'AO', # Net revenue
            upc              => 'P',
        },
    );
    return $field_map{$version};
}

sub _unverifiedFieldMap {
    my $self = shift;
    my $version = $self->_version;

    my %field_map = (
        17 => {
            netUnits  => 'AX',
        },
        18 => {
            netUnits  => 'AT',
        },
        29 => {
            netUnits  => 'AU',
        },
        30 => {
            netUnits  => 'AV',
        },
        31 => {
            netUnits  => 'AU',
        },
        47 => {
# netUnits not used for this version, but need an entry to avoid a hash error
        },
        48 => {
# netUnits not used for this version, but need an entry to avoid a hash error
        },
        49 => {
# netUnits not used for this version, but need an entry to avoid a hash error
        },
    );
    return $field_map{$version};
}

sub _headerIdentifier { ( upc => qr/UPC( ID)?/ ) }

sub currencyCode { 'USD' }

sub countryCode { 'US' }

sub physical { 1 };

sub productType {
    my $self = shift;
    my $type = $self->_getByFieldName('productType');

    return RPS::File::Sale::TYPE_CD         if( $type =~ /^cd$/i );
    return RPS::File::Sale::TYPE_DVD        if( $type =~ /^dm$/i );
    return RPS::File::Sale::TYPE_DVD_CD_SET if( $type =~ /^dx$/i );
    return RPS::File::Sale::TYPE_LP         if( $type =~ /^lp$/i );
    return RPS::File::Sale::TYPE_BLURAY     if( $type =~ /^bd$/i );

    $self->fail( "Could not parse product type from '$type'" );
}

sub channel { RPS::File::Sale::CHANNEL_RETAIL }

sub priceLevel {
    my $self = shift;
    my $level = $self->_getByFieldName('priceLevel');

    return RPS::File::Sale::PLEVEL_FULL   if( $level =~ /^f$/i );
    return RPS::File::Sale::PLEVEL_MID    if( $level =~ /^m$/i );
    return RPS::File::Sale::PLEVEL_BUDGET if( $level =~ /^b$/i );

    $self->fail( "Could not parse price level from '$level'" );
}

sub upc {
    my $self = shift;
    my $upc = $self->_getByFieldName('upc');
    return Common::Util::normalize_upc($upc);
}

sub artistName {
    my $self = shift;
    my $name = $self->_getByFieldName('artistName');
    if( $name =~ /(\w*),\s*(\w*)/ )  # Lastname, Firstname
    {
        $name = $2 . ' ' . $1; # Firstname Lastname
    }
    return $name;
}

sub sales {
    my $self = shift;
    if( exists $self->_unverifiedFieldMap->{'netUnits'} )
    {
        my $sales = $self->_getByFieldName('netUnits');
        my $revenue = $self->_getByFieldName('totalRevenue');
        return ($revenue > 0) ? abs($sales) : 0;
    }
    return $self->_getByFieldName('sales');
}

sub salesRevenue {
    my $self = shift;
    if( exists $self->_fieldMap->{'salesRevenue'} )
    {
        return $self->_getByFieldName('salesRevenue');
    }
    else
    {
        my $revenue = $self->_getByFieldName('totalRevenue');
        return ($revenue > 0) ? $revenue : 0;
    }
}

sub returns {
    my $self = shift;
    if( exists $self->_unverifiedFieldMap->{'netUnits'} )
    {
        my $sales = $self->_getByFieldName('netUnits');
        my $revenue = $self->_getByFieldName('totalRevenue');
        return ($revenue < 0) ? abs($sales) : 0;
    }
    return abs($self->_getByFieldName('returns'));
}

sub returnsRevenue {
    my $self = shift;
    if( exists $self->_fieldMap->{'returnsRevenue'} )
    {
        return abs($self->_getByFieldName('returnsRevenue'));
    }
    else
    {
        my $revenue = $self->_getByFieldName('totalRevenue');
        return ($revenue < 0) ? abs($revenue) : 0;
    }
}

sub _isValidSaleRecord {
    my $self = shift;

    # Error out on lines with revenue and no units
    #
    if( $self->albumName && $self->sales == 0 && $self->returns == 0 && ($self->totalRevenue != 0 ) )
    {
        $self->fail("Revenue without units");
    }

    # The line is valid if it has sales or returns, and has an album title
    #
    return ( ($self->sales != 0 || $self->returns != 0) && $self->albumName );
}

sub saleDates {
    my $self = shift;

    return( $self->{_startDate}, $self->{_endDate} );
}

sub _processSheet {
    my $self     = shift;
    my $sheet    = shift;
    my $sheetnum = shift;

    # Get the date information from the header area of the current sheet
    #
    foreach my $line (@$sheet)
    {
        $self->{line} = $line;

        my $dt = $self->_getByFieldName('dateBegin');
        if( $dt =~ /^Financial Net Sales UMG \w{2,3} \d{2} \((\w{3})\s*(\d{2})\)$/i )
        {
            my $_month = lc $1;
            my $year   = $2;
            my %months = (jan => 1, feb => 2, mar => 3, apr => 4, may => 5, jun => 6,
                          jul => 7, aug => 8, sep => 9, oct => 10, nov => 11, dec => 12);
            my $month = $months{$_month};
            $year += 2000;

            my $sdate = sprintf("%04d-%02d-01", $year, $month);
            my $edate = sprintf("%04d-%02d-%02d", $year, $month, Days_in_Month($year, $month));

            $self->{_startDate} = $sdate;
            $self->{_endDate}   = $edate;
            last;
        }
        elsif( $dt =~ /\(Period \(ID\) Between (\d{4})(\d{2}) and (\d{4})(\d{2})\)/i )
        {
            my( $sYear, $sMonth, $eYear, $eMonth ) = ($1, $2, $3, $4);
            my $sdate = sprintf("%04d-%02d-01", $sYear, $sMonth);
            my $edate = sprintf("%04d-%02d-%02d", $eYear, $eMonth, Days_in_Month($eYear, $eMonth));
            $self->{_startDate} = $sdate;
            $self->{_endDate}   = $edate;
            last;
        }

        $self->{linenum}++;
    }

    return $self->SUPER::_processSheet( $sheet, $sheetnum );

}

###
1;# Play nicely.
###